Timer offline laufen

[DeddyH]

Im Groben ja. Aber FormActivate ist nicht so geschickt, und erzeugte Objekte (TIniFile) solltest Du auch wieder freigeben, das wurde bereits mehrfach gesagt und auch gezeigt. Außerdem: wenn Du mit WriteDateTime schreibst kannst Du doch genausogut mit ReadDateTime wieder auslesen, wozu das String-Gehampel?

[chiller4fun1990]

Ok mein Aktueller Code:

Delphi-Quellcode:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, IniFiles, ExtCtrls, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Label1: TLabel;
    Timer1: TTimer;
    procedure Button1Click(Sender: TObject);
    procedure Timer1Timer(Sender: TObject);
    procedure FormPaint(Sender: TObject);
      private
    Zielzeit: TTime;
    { Private declarations }
  public                        
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.Button1Click(Sender: TObject);
var
  ini: TIniFile;
  filename: String;
begin
  filename := ExtractFilePath(ParamStr(0)) + 'zeit.ini';
  ini := TIniFile.Create(filename);


  Zielzeit := now + 1;


  try

    ini.WriteTime('Daten','Zielzeit',Zielzeit);
         finally
      ini.Free;
  end;



  Timer1.Enabled:=true;

end;

procedure TForm1.Timer1Timer(Sender: TObject);
var
  ini: TIniFile;
  filename: String;
begin
  filename := ExtractFilePath(ParamStr(0)) + 'zeit.ini';
  ini := TIniFile.Create(filename);

   Label1.Caption:= TimeToStr(zielzeit - now);


  
  if now >= Zielzeit then

  begin
  Timer1.enabled:=false;
     end;


end;



procedure TForm1.FormPaint(Sender: TObject);
var
  ini: TIniFile;
  filename: String;
begin
  filename := ExtractFilePath(ParamStr(0)) + 'zeit.ini';
  ini := TIniFile.Create(filename);
 try
 if
ini.ReadDateTime('Daten','Zielzeit',Zielzeit) < now then
  finally
      ini.Free;
begin
timer1.Enabled:=true;
  end;
end;

end;
end.

Allerdings wenn ich das Programm starte läuft der Countdown irgendwie nicht runter sondern hoch

[DeddyH]

*Boah Alter* . Wieso denn jetzt OnPaint, das ist ja noch schlimmer. Pack das Auslesen ins FormCreate, das muss doch nur ein einziges Mal gemacht werden. Und formatier Deinen Code mal ordentlich, dann siehst Du (hoffentlich), was Du da alles durcheinander gewürfelt hast. Und dass der hochzählt, hast Du ja auch geschrieben: zukünftige Zeitwerte sind ja wohl größer als die aktuelle Zeit und nicht kleiner, oder?

[Jasocul]

Delphi-Quellcode:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, IniFiles, ExtCtrls, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Label1: TLabel;
    Timer1: TTimer;
    procedure Button1Click(Sender: TObject);
    procedure Timer1Timer(Sender: TObject);
    procedure FormCreate(Sender: TObject); // FormCreate ist die Lösung
  private
    { Private declarations }
    Zielzeit: TTime;
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.Button1Click(Sender: TObject);
var
  ini: TIniFile;
  filename: String;
begin
  filename := ExtractFilePath(ParamStr(0)) + 'zeit.ini';
  ini := TIniFile.Create(filename);

  Zielzeit := now + 1;

  try
    ini.WriteTime('Daten','Zielzeit',Zielzeit);
  finally
    ini.Free;
  end;

  Timer1.Enabled:=true;
end;

procedure TForm1.Timer1Timer(Sender: TObject);
begin
  Label1.Caption:= TimeToStr(zielzeit - now);
  
  if now >= Zielzeit then
  begin
    Timer1.enabled:=false;
  end;
end;


procedure TForm1.FormCreate(Sender: TObject); // FormCreate verwenden
var
  ini: TIniFile;
  filename: String;
begin
  filename := ExtractFilePath(ParamStr(0)) + 'zeit.ini';
  ini := TIniFile.Create(filename);
  try
    if ini.ReadDateTime('Daten','Zielzeit',Zielzeit) < now then
    begin
      timer1.Enabled:=true;
    end;
  finally
    ini.Free;
  end;
end;

end.

Da jetzt ein paar Ansätze zu sehen sind, gibts nochmal Hilfe von mir.

Bitte korrigiere dein Timer-Event und nimm statt FormPaint das FormCreate.
Ich habe den Source ein wenig angepasst, da auch dein Konstrukt mit der If-Abfrage und dem Try durcheinander war.

[chiller4fun1990]

Da du geschrieben hast ich soll mein Timer Event Korrigieren was is da dran falsch?
kann den fehler grad nicht finden.
Und jetzt wenn ich das Programm starte wird eig. nur die Aktuelle Uhrzeit ausgegeben ohne runterzählen ect.
Habs vorhin schon in OnCreate reingepackt.

Delphi-Quellcode:

procedure TForm1.FormCreate(Sender: TObject); // FormCreate verwenden
var
  ini: TIniFile;
  filename: String;
begin
  filename := ExtractFilePath(ParamStr(0)) + 'zeit.ini';
  ini := TIniFile.Create(filename);
  try
    if ini.ReadDateTime('Daten','Zielzeit',Zielzeit) < now then
    begin
      timer1.Enabled:=true;
    end;
  finally
    ini.Free;
  end;
end;

[DeddyH]

Wenn man jetzt noch auf größer statt kleiner vergleicht und für den Ininamen eine Konstante vergibt (und verwendet), dann könnte es langsam rund werden. Wobei TimeToStr ggf. immer noch nicht für die richtige Darstellung sorgt, aber bevor man sich um die Darstellung kümmert muss ja erstmal der Rest stimmen

[Jasocul]

@Detlef:
Das geht nur wenn du den Code reinschreibst. Wird sonst zu schwierig. Nicht, dass noch der Vergleich in der anderen Methode geändert wird. Ich hatte den Vergleich allerdings auch übersehen.

Delphi-Quellcode:

procedure TForm1.FormCreate(Sender: TObject);
var
  ini: TIniFile;
  filename: String;
begin
  filename := ExtractFilePath(ParamStr(0)) + 'zeit.ini';
  ini := TIniFile.Create(filename);
  try
    if ini.ReadDateTime('Daten','Zielzeit',Zielzeit) > now then // Hier musste noch das "<" in ">" geändert werden
    begin
      timer1.Enabled:=true;
    end;
  finally
    ini.Free;
  end;
end;

Und dies muss auch noch korrigiert werden:

Delphi-Quellcode:

procedure TForm1.Button1Click(Sender: TObject);
var
  ini: TIniFile;
  filename: String;
begin
  filename := ExtractFilePath(ParamStr(0)) + 'zeit.ini';
  ini := TIniFile.Create(filename);

  Zielzeit := now + 1;

  try
    ini.WriteDateTime('Daten','Zielzeit',Zielzeit); // WriteTime durch WriteDateTime ersetzt
  finally
    ini.Free;
  end;

  Timer1.Enabled:=true;
end;

[DeddyH]

Wenn es danach Ruhe hat (ungetestet, da in PSPad getippselt):

Delphi-Quellcode:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, IniFiles, ExtCtrls, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Label1: TLabel;
    Timer1: TTimer;
    procedure Button1Click(Sender: TObject);
    procedure Timer1Timer(Sender: TObject);
    procedure FormCreate(Sender: TObject); // FormCreate ist die Lösung
  private
    { Private declarations }
    Zielzeit: TTime;
    function GetIniFilename: string;
    function ReadZeitwert: TDateTime;
    procedure WriteZeitwert(Zeit: TDateTime);
  public
    { Public declarations }
    property IniFilename: string read GetIniFilename;
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

const
  SECTION = 'Daten';
  IDENT   = 'Zielzeit';

function TForm1.GetIniFilename: string;
begin
  Result := ExtractFilePath(ParamStr(0)) + 'zeit.ini';
end;

function TForm1.ReadZeitwert: TDateTime;
var
  ini: TIniFile;
begin
  ini := TIniFile.Create(IniFilename);
  try
    Result := ini.ReadDateTime(SECTION, IDENT, 0);
  finally
    ini.Free;
  end;
end;

procedure TForm1.WriteZeitwert(Zeit: TDateTime);
var
  ini: TIniFile;
begin
  ini := TIniFile.Create(IniFilename);
  try
    ini.WriteDateTime(SECTION, IDENT, Zeit);
  finally
    ini.Free;
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  Zielzeit := now + 1;
  WriteZeitwert(Zielzeit);
  Timer1.Enabled:=true;
end;

procedure TForm1.Timer1Timer(Sender: TObject);
begin
  Label1.Caption:= TimeToStr(zielzeit - now);
  if now >= Zielzeit then
  begin
    Timer1.enabled:=false;
  end;
end;

procedure TForm1.FormCreate(Sender: TObject); // FormCreate verwenden
begin
  Zielzeit := ReadZeitwert;  
  Timer1.Enabled := Zielzeit > now; 
end;

end.

[chiller4fun1990]

Erstmal danke für die bisherige Hilfe.
Dann @ DeddyH

Kannst du mir vllt. sagen welche zwei Speicherlecks das waren und ob die gravierend waren?

Wegen den Timer.
Es besteht immer noch das Problem das der Timer sobald er auf 0 kommt wieder bei 24Std anfängt runter zu zählen

[chiller4fun1990]

*push*

kann mir den keiner sagen wieso der Timer nach ablauf der Zeit wieder neustartet?
lg