Auch Records...kann man CopyOnWrite deaktivieren?

[QuickAndDirty]

Delphi-Quellcode:

Function RecordAusListe(aName:String) : TMyRecord
Begin
  Result := MyRecordLIST.Items[IndexOfName(aname)];
end;

Procedure Tuwas;
var myRec:TMyRecord;
Begin
  myrec := RecordAusListe('Peter');
  myRec.Hitpoints := 5;

// oder
  RecordAusListe('Peter').Hitpoints := 5;

end;

Das ändert nur Kopien des Records.
Gibts ne Möglichkeit sowas ohne CopyOnWrite zu machen , also direkt in den Record zu schreiben?

Geht es ohne ^ ?

[Der schöne Günther]

Records sind immer "pass-by-value", das ist ihre Natur.

Du hast aktuell nur einen Getter, dir fehlt ein Setter wie

Delphi-Quellcode:

refreshThings('Peter', myRrec)

Fände ich 100 mal sinnvoller und einfacher als mit Gewalt jetzt auf Referenztypen wie Klassen umzustellen.

[Uwe Raabe]

Ob das geht, hängt stark von dem ab was Items tut. Wenn das schon eine Kopie liefert wird es schwierig.

[Uwe Raabe]

Hier mal ein Beispiel mit einer bordeigenen TList<T>. Man beachte die Verwendung von List anstatt Items:

Delphi-Quellcode:

type
  PMyRecord = ^TMyRecord;

Function RecordAusListe(aName:String) : PMyRecord;
Begin
  Result := @MyRecordLIST.List[IndexOfName(aname)];
end;

Procedure Tuwas;
var myRec:PMyRecord;
Begin
  myrec := RecordAusListe('Peter');
  myRec.Hitpoints := 5;

// oder
  RecordAusListe('Peter').Hitpoints := 5; // das compiliert im ursprünglichen Code gar nicht

end;

[jaenicke]

Wenn man nur eine Referenz auf ein und das gleiche Element haben möchte, kann man doch einfach Klassen und diese ggf. mit Interfaces nutzen. Das ist ja nun genau einer der Unterschiede zu Records...

Ansonsten muss man immer aufpassen, dass man es richtig macht, Pointer nutzt, usw., was dann später auf die Füße fallen kann.

[Uwe Raabe]

Das ist prinzipiell schon richtig. Es kommt aber immer auf den konkreten Fall an, ob eine Umstellung von Record nach Class unproblematischer ist oder nicht. Dabei muss man eben auch immer überprüfen, ob das implizite Kopieren von Records an manchen Stellen nicht durchaus erwartet wird und bei Klassen dort anders agiert werden muss. Ebenso muss man sich Gedanken um Erzeugung und Ownership der Klassen-Instanzen machen. Sind bei den Records Operatoren im Spiel fällt das sowieso aus. In allen Fällen ist so eine Umstellung nicht mal eben mit dem Ändern des Keywords getan.

[himitsu]

Lösungen:
* keinen Record benutzen (Objekt/Interface)
* Items[] gibt nicht den Record, sondern einen Zeiger auf den Record zurück
* einen Wrapper-Record, der intern einen Zeiger auf den Record, oder besser einen Callback in die Klasse besitzt, um statt den Feldern mit Property versehen wurde, welche die Zuweisungen an die Quelle (OriginalRecord) übertragen

Was ist eigentlich MyRecordLIST?

Zitat:

Delphi-Quellcode:

  myrec := RecordAusListe('Peter');
  myRec.Hitpoints := 5;

bei dir kann nur der Getter aufgerufen werden,
aber auch beim

Delphi-Quellcode:

MyRecordLIST.Items[IndexOfName(aname)].Hitpoints := 5;

Joar, das Problem ist hier, dass nur der Getter des Items aufgerufen wird,
aber anschließend eben nicht "automatisch" der Setter, um die Änderungen zurückzuschreiben.

[Uwe Raabe]

Wobei

Delphi-Quellcode:

MyRecordLIST.List[IndexOfName(aname)].Hitpoints := 5;

funktionieren würde.

[QuickAndDirty]

Zitat:

Zitat von Uwe Raabe (Beitrag 1528969)

Ob das geht, hängt stark von dem ab was Items tut. Wenn das schon eine Kopie liefert wird es schwierig.

Items ist TArray<T>
:(

[QuickAndDirty]

Zitat:

Zitat von himitsu (Beitrag 1528979)

Was ist eigentlich MyRecordLIST?

Items ist TArray<TMyRecord>

TArray<PMyRrecord>
wäre besser ?

[QuickAndDirty]

Zitat:

Zitat von jaenicke (Beitrag 1528974)

Wenn man nur eine Referenz auf ein und das gleiche Element haben möchte, kann man doch einfach Klassen und diese ggf. mit Interfaces nutzen. Das ist ja nun genau einer der Unterschiede zu Records...

Ansonsten muss man immer aufpassen, dass man es richtig macht, Pointer nutzt, usw., was dann später auf die Füße fallen kann.

Ich weiß....Ich wünschte nur es gäbe einen Umschalter....so um einfach umszustellen.
Von Records auf TInterfacedObject(für ARC-Lazyness) oder TComponent(für Aufräum-lazyness)...
Ich werde jetzt wohl an den Stellen wo es kritisch ist nicht mehr die Records übergeben sondern die Indexe die sie in den Tarray<T> dingern haben.
Ich bin so traurig.

[himitsu]

Also nicht nur eine Kopie des einen angefragten Items, sondern gleich von ALLEN. :stupid:
(das Speichermanagement und die CPU freuen sich etwas tuen zu dürfen)

[QuickAndDirty]

Zitat:

Zitat von Uwe Raabe (Beitrag 1528970)

Hier mal ein Beispiel mit einer bordeigenen TList<T>. Man beachte die Verwendung von List anstatt Items:

Delphi-Quellcode:

type
  PMyRecord = ^TMyRecord;

Function RecordAusListe(aName:String) : PMyRecord;
Begin
  Result := @MyRecordLIST.List[IndexOfName(aname)];
end;

Procedure Tuwas;
var myRec:PMyRecord;
Begin
  myrec := RecordAusListe('Peter');
  myRec.Hitpoints := 5;

// oder
  RecordAusListe('Peter').Hitpoints := 5; // das compiliert im ursprünglichen Code gar nicht

end;

geht dein beispiel so

Delphi-Quellcode:

RecordAusListe('Peter').Hitpoints := 5;

oder so

Delphi-Quellcode:

RecordAusListe('Peter')^.Hitpoints := 5;

??????

[QuickAndDirty]

Zitat:

Zitat von himitsu (Beitrag 1528991)

Also nicht nur eine Kopie des einen angefragten Items, sondern gleich von ALLEN. :stupid:
(das Speichermanagement und die CPU freuen sich etwas tuen zu dürfen)

:(
Es ist sooo traurig.
Vielleicht stelle ich auf TObjectlist<T> mit ownership um und alle Records zu normalen DatenObjekten....

[Uwe Raabe]

Zitat:

Zitat von QuickAndDirty (Beitrag 1528994)

geht dein beispiel so

Delphi-Quellcode:

RecordAusListe('Peter').Hitpoints := 5;

oder so

Delphi-Quellcode:

RecordAusListe('Peter')^.Hitpoints := 5;

??????

Es geht beides.

[Uwe Raabe]

Zitat:

Zitat von QuickAndDirty (Beitrag 1528986)

Items ist TArray<TMyRecord>

Damit müsste es gehen. Beim Zugriff euf ein Array-Element bekommt man den originalen Record und keine Kopie. Erst der Rückgabewert von RecordAusListe ist dann eine Kopie. Mein Beispiel könnte dann so aussehen:

Delphi-Quellcode:

type
  PMyRecord = ^TMyRecord;

Function RecordAusListe(aName:String) : PMyRecord;
Begin
  Result := @MyRecordLIST.Items[IndexOfName(aname)];
end;

Procedure Tuwas;
var myRec:PMyRecord;
Begin
  myrec := RecordAusListe('Peter');
  myRec.Hitpoints := 5;

// oder
  RecordAusListe('Peter').Hitpoints := 5; // das ^ ist nicht notwendig, das denkt sich der Compiler dann.

end;

[QuickAndDirty]

Danke euch allen.

[himitsu]

Zitat:

^

Jupp, beim Zugriff via

Delphi-Quellcode:

.

werdem RecordPointer automatisch implizit dereferenziert.
Es kann aber natürlich dennoch explizit mit ^ dereferenziert werden.
(nur bei Objekt-Zeigern, ist das Explizite nicht erlaubt, bzw. hier wird alles immer nur implizit vom Compiler erledigt)

Da hier der Zugriff eigentlich über einen Name, anstatt via Index ... TDictionary<string,TMyRecord> bzw. TObjectDictionary<string,TMyObject>