Interface Problem, implementation von mehreren Interfaces

[stoxx]

Ich möchte Interfaces als reines Sprachfeature für den Zugriff auf Klassen benutzen, also ohne Referenzzählung.
Das klappt soweit ganz gut, aber ich komme nicht von dem einen Interface auf das andere ...
Wie geht das korrekt? Siehe Button1Click procedure ...

Delphi-Quellcode:

unit frmMain;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;



type


  IBaseInterface = Interface
    procedure free;
  End;



  ISomeInterface = interface(IBaseInterface)
    procedure ShowZahl;
    function Get_Zahl: Integer;
    procedure Set_Zahl(const Value: Integer);
    property Zahl : Integer read Get_Zahl write Set_Zahl;
  end;


  INameInterface = interface(IBaseInterface)
    function Get_Name: String;
    procedure Set_Name(const Value: String);
    property Name : String read Get_Name write Set_Name;
  end;

//==============================================================================
type



  TSomeClass = class(TPersistent, ISomeInterface, INameInterface )
  private
    FName  : String;
    FZahl : Integer;
    function Get_Name: String;
    procedure Set_Name(const Value: String);
    function Get_Zahl: Integer;
    procedure Set_Zahl(const Value: Integer);
  protected
    // leere Code Implementierungen, die von IInterface implementiert sein müssen
    // Referenzzählung ausgeschaltet ....
    function QueryInterface(const IID: TGUID; out Obj): HResult; stdcall;
    function _AddRef: Integer; stdcall;
    function _Release: Integer; stdcall;

  public
    property Name : String read Get_Name write Set_Name;
    procedure ShowZahl;
    constructor create;
    destructor destroy; override;
  end;

//==============================================================================

type
  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;


//==============================================================================
implementation
//==============================================================================

{$R *.dfm}


//==============================================================================
function TSomeClass.QueryInterface(const IID: TGUID; out Obj): HResult; begin end;
function TSomeClass._AddRef: Integer; begin end;
function TSomeClass._Release: Integer; begin end;
//==============================================================================



//==============================================================================

constructor TSomeClass.create;
begin

end;
//==============================================================================
destructor TSomeClass.destroy;
begin
  showmessage('Destroy klappt auch');
  inherited;
end;
//==============================================================================
function TSomeClass.Get_Name: String;
begin
 result := FName;
end;
//==============================================================================
function TSomeClass.Get_Zahl: Integer;
begin
 result := FZahl;
end;
//==============================================================================
procedure TSomeClass.ShowZahl;
begin
    showmessage('Test Method ShowZahl - Zahl: ' + inttostr(FZahl));
end;

//==============================================================================

procedure TSomeClass.Set_Name(const Value: String);
begin
  FName := Value;
end;
//==============================================================================
procedure TSomeClass.Set_Zahl(const Value: Integer);
begin
  FZAhl := Value;
end;




//==============================================================================



procedure TForm1.Button1Click(Sender: TObject);
var
  SomeInt : ISomeInterface;
  NameInt : INameInterface;

  SomeObj  : TSomeClass;


begin
   SomeInt := TSomeClass.create;
   SomeInt.Zahl := 5;
   SomeInt.ShowZahl;



   // folgender Code macht nicht das, was er soll ....
   NameInt := INameInterface(SomeInt);
   NameInt.Name := 'Testname';
   showmessage(NameInt.Name);

   // das funktioniert wieder ...
   SomeInt.free;

end;






end.

[mkinzler]

Kommt ein Fehler?
Warum der Cast auf das Interface?

[Apollonius]

Interfaces müssen mit as umgewandelt werden! Dabei wird implizit QueryInterface aufgerufen. Das ist nötig, da ein Interface nur ein Zeiger auf eine virtual method table (VMT) ist, die Zeiger auf alle von dem entsprechenden Interface geforderten Methoden enthält. Und deshalb kann nicht mit dem gecasteten Interfacezeiger (=zeigt immer noch auf eine ISomeinterface-VMT) die Methode set_name aufgerufen werden, die nicht in ISomeinterface enthalten ist.

[stoxx]

Zitat:

Zitat von mkinzler

Kommt ein Fehler?
Warum der Cast auf das Interface?

es wird anstatt der Methode TSomeClass.Get_Name

function TSomeClass.Get_Zahl: Integer; aufgerufen ...
Da scheint irgendwas zu verrutschen ! Die Casts deswegen, weil ich nur das Interface rumreichen möchte ...
In .Net soll das angeblich sogar mit dem AS Operator gehen ... Suche aber eine Möglichkeit für Win32 ...

[mkinzler]

Dort geht es genauso:

Delphi-Quellcode:

NameInt := (SomeInt as INameInterface);

[stoxx]

Zitat:

Zitat von mkinzler

Dort geht es genauso:

Delphi-Quellcode:

NameInt := (SomeInt as INameInterface);

das geht ja gerade nicht:

"Operator ist auf diesen Operantentyp nicht anwendbar ...."

[mkinzler]

Delphi-Quellcode:

NameInt := SomeInt;

?

[stoxx]

Zitat:

Zitat von mkinzler

Delphi-Quellcode:

NameInt := SomeInt;

?

.. inkompatible Typen ....

[Apollonius]

Da bin ich auch schon drüber gestolpert. Gib INameInterface eine GUID (Die wird schließlich zum Aufruf von QueryInterface gebraucht). Drücke dazu in der ersten Zeile nach dem Interfacekopf STR+SHIFT+G. Dann funktioniert as.

[stoxx]

Zitat:

Zitat von Apollonius

Da bin ich auch schon drüber gestolpert. Gib INameInterface eine GUID (Die wird schließlich zum Aufruf von QueryInterface gebraucht). Drücke dazu in der ersten Zeile nach dem Interfacekopf STR+SHIFT+G. Dann funktioniert as.

hmm ... das geht zwar jetzt, mit ein paar NAchteilen.
QueryInterface wollte ich ja nicht haben, scheint aber nicht ohne zu gehen...
Wenn ich von TPersistent oder anderen Klassen, die nicht von TInterfacedObject abgeleited sind, muss man den Code von QueryInterface selber implementieren .. naja .. sind zwar nur 3 Zeilen .. aber nicht schön ..
Aber vielen Dank ! ...
Mit 15 schon so viele Interfaces benutzt .. Respekt :-)