TPanel

[MichaelC]

Hi Leuts, hab mal wieder ein Problem:

ich habe ein Menuepanel erstellt, auf diesem Panel befinden sich n weitere Panels, ich möchte nun die Mausbewegungen auf dem unteren Panel erkennen, soll heißen: Ich erkenne zwar die Bewegungen der Maus auf den einzelnen obigen Panels, brauche aber die gesamten Maus events für das Haupbpanel ( MenuePanel ).

Wer kann mir dabei helfen??

Gruß

Michael :D

[sakura]

Da l'sst sich imho nicht viel machen, da Windows ausschließlich das oberste sichtbare Fenster (Objekt!) informiert. Du kannst höchstens in den einzelnen Panels die Bewegung abfangen und diese dann an das Parent-Panel weiterreichen.

Aber warum so umständlich. Was willst Du erreichen?

...:cat:...

[MichaelC]

Danke erst einmal für deine Antwort. Nun zum Thema, ich möchte erreichen, dass das zuletzt aktive Panel beim Verlassen des Menues ( Mausbewegung ) farbig markiert wird, dazu muß ich wissen, ob der Mauszeiger den Bereich des Hauptpanels verlassen hat, wäre nett wenn Du einen Vorschlag hast.

Gruß

Michael

[Jens Schumann]

Hallo,
dafür habe ich mir mal einen Nachfahren von TPanel erzeugt.
Für Dich sind hier die Event's OnMouseEnter und OnMouseLeave interessant.

Delphi-Quellcode:

unit CanvasPanel;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  ExtCtrls;

type
  TCanvasPanel = class(TPanel)
  private
    { Private-Deklarationen}
    fOnEraseBkgnd : TNotifyEvent;
    fOnPaint      : TNotifyEvent;
    fMouseEnter   : TNotifyEvent;
    fMouseLeave   : TNotifyEvent;
  protected
    { Protected-Deklarationen}
  protected
  procedure WMEraseBkgnd (var Message : TMessage); message WM_ERASEBKGND;
  procedure WndProc(var Message : TMessage); override;
  procedure CMMouseEnter(Var Message : TMessage); message CM_MOUSEENTER;
  procedure CMMouseLeave(Var Message : TMessage); message CM_MOUSELEAVE;
 public
    { Public-Deklarationen}
    constructor Create(AOwner : TComponent); override;
    property Canvas;
  published
    { Published-Deklarationen }
    property OnEraseBkgnd : TNotifyEvent read fOnEraseBkgnd write fOnEraseBkgnd;
    property OnPaint : TNotifyEvent read fOnPaint write fOnPaint;
    property OnMouseEnter : TNotifyEvent read fMouseEnter write fMouseEnter;
    property OnMouseLeave : TNotifyEvent read fMouseLeave write fMouseLeave;
  end;

procedure Register;

implementation

procedure Register;
begin
  RegisterComponents('Beispiele', [TCanvasPanel]);
end;

procedure TCanvasPanel.CMMouseEnter(var Message: TMessage);
begin
 If Enabled then
   If Assigned(fMouseEnter) then fMouseEnter(Self);
end;

procedure TCanvasPanel.CMMouseLeave(var Message: TMessage);
begin
 If Enabled then
   If Assigned(fMouseLeave) then fMouseLeave(Self);
end;

constructor TCanvasPanel.Create(AOwner : TComponent);
begin
  inherited Create(AOwner);
  fOnEraseBkgnd:=Nil;
  fOnPaint:=Nil;
end;

procedure TCanvasPanel.WMEraseBkgnd (var Message : TMessage);
begin
  If Assigned(fOnEraseBkgnd) then
    fOnEraseBkgnd(Self);
end;

procedure TCanvasPanel.WndProc(var Message : TMessage);
begin
  Inherited;
  If Message.Msg=WM_Paint then
    begin
    If Assigned(fOnPaint) then
      fOnPaint(Self);
    end;
end;

end.

[MichaelC]

Danke Dir, ich werds gleich mal ausprobieren, falls noch probs. auftauchen melde ich mich wieder.

Gruß

Michael :hello: