[TFileStream]-Speichern/Auslesen funktioniert nicht richtig

[xZise]

Ich wollte ein Datei Container schreiben... Gesagt getan... Allerdings hackt es schon beim Header xD
Und zwar wollte ich folgenden Header haben:

Delphi-Quellcode:

TXFCHeader = packed record
  XFCSignature : string[3]; // XCF
  UserSignature : string[5];
  Version : Word;
  FileCount : Word;
  Sizes : array of Cardinal;
end;

Dann speichere ich das folgendermaßen:

Delphi-Quellcode:

procedure TXFCMain.SaveContainer(const AFileName: string);
var
  container : TFileStream;
  b : string;
  i : Word;
begin
  FFileName := AFileName;

  container := TFileStream.Create(AFileName, fmCreate);
  try
    // Write Header
    b := FHeader.XFCSignature + FHeader.UserSignature;
    container.Write(Pointer(b)^, 8);
    container.Write(FHeader.Version, SizeOf(FHeader.Version));
    container.Write(FHeader.FileCount, SizeOf(FHeader.FileCount));
    i := 0;
    while i < FHeader.FileCount do
    begin
      container.Write(FHeader.Sizes[i], SizeOf(FHeader.Sizes[i]));
      inc(i);
    end;
    // Header written
  finally
    container.Free;
  end;
end;

Und lade es folgendermaßen:

Delphi-Quellcode:

procedure TXFCMain.LoadContainer(const AFileName: string);
var
   container : TFileStream;
  b : string;
  i : Integer;
begin
   if FileExists(AFileName) then
  begin
     container := TFileStream.Create(AFileName, fmOpenRead or fmShareDenyWrite);
    try
       // Read Header
      b := '';
      container.Read(Pointer(b)^, 3);
      if (b <> 'XFC') and (not FDisableNoContainerException) then // Wrong Signature
         raise ENoContainerException.CreateFmt(NO_XFC_SIGNATURE, [AFileName, b]);

      container.Read(Pointer(b)^, 5);
      FHeader.UserSignature := b;
      container.Read(FHeader.Version, SizeOf(FHeader.Version));
      container.Read(FHeader.FileCount, SizeOf(FHeader.FileCount));
      i := 0;
      while i < FHeader.FileCount do
      begin
        container.Read(FHeader.Sizes[i], SizeOf(FHeader.Sizes[i]));
        inc(i);
      end;
      // Header read;
    finally
      container.Free;
    end;
  end else
  begin
    raise ENoContainerException.CreateFmt(DOES_NOT_EXISTS, [AFileName]);
  end;
end;

Problem ist, dass "b" beim laden nicht XFC sondern nichts enthält. Jedenfalls zeigt die Fehlermeldung nichts an...
Aber ich weis nicht, was da schief gelaufen sein könnte...

[mkinzler]

Das Problem wird der dynamsiche Array in TXFCHeader sein

[xZise]

Warum?
Weil es wird ja erst gar nicht abgespeichert... (filecount = 0)

[Hawkeye219]

Hallo Fabian,

auch Strings sind dynamische Strukturen. Wenn du keinen Speicher für den Inhalt anforderst, wirst du auch nichts laden können, sondern riskierst nur eine Schutzverletzung:

Delphi-Quellcode:

// b := '';
SetLength (b, 3);
container.Read(b[1], 3);
[...]
SetLength (b, 5);
container.Read(b[1], 5);
[...]
container.Read(FHeader.FileCount, SizeOf(FHeader.FileCount));
SetLength (FHeader.Sizes, FHeader.FileCount);

Den Inhalt von Sizes könntest du sogar "in einem Rutsch" laden. Warum verwendest du für die Signaturen keine ShortStrings?

Gruß Hawkeye

[xZise]

Zitat:

Zitat von Hawkeye219

Hallo Fabian,

auch Strings sind dynamische Strukturen. Wenn du keinen Speicher für den Inhalt anforderst, wirst du auch nichts laden können, sondern riskierst nur eine Schutzverletzung:

Delphi-Quellcode:

// b := '';
SetLength (b, 3);
container.Read(b[1], 3);
[...]
SetLength (b, 5);
container.Read(b[1], 5);
[...]
container.Read(FHeader.FileCount, SizeOf(FHeader.FileCount));
SetLength (FHeader.Sizes, FHeader.FileCount);

Ah... Danke ;) Ich dachte, dass hätte sich mit der Längenangabe (string[3]) getan :D

Zitat:

Zitat von Hawkeye219

Den Inhalt von Sizes könntest du sogar "in einem Rutsch" laden.

Und wie geht das? Indem ich das array und nicht die Einträge speichere?

Zitat:

Zitat von Hawkeye219

Warum verwendest du für die Signaturen keine ShortStrings?

Weiss ich auch nicht ;) Kann man da den auch längen festsetzen?
[edit]Nein => Länge immer 256 Byte ;) Und da sind die anderen Strings kleiner ;) (4 und 6 Byte)[/edit]

PS: Jetzt funktionierts :D Danke Hawkeye!

[Hawkeye219]

Sorry, ich habe ganz übersehen, daß du in deinem Record ja bereits ShortStrings verwendest. Diese sind nicht immer 256 Bytes lang, ihre Länge wird durch die Definition festgelegt (max. 255 Zeichen). Hinzu kommt dann noch ein Längenbyte (das "Zeichen" mit dem Index 0).

ShortStrings kannst du direkt (ohne Hilfsvariable) speichern und laden:

Delphi-Quellcode:

// Speichern
container.Write(XFCSignature[0], SizeOf(XFCSignature));

// Laden
container.Read(XFCSignature[0], SizeOf(XFCSignature));

Das Speichern und Laden des Cardinal-Arrays könntest du so durchführen:

Delphi-Quellcode:

// Speichern
container.Write(FHeader.FileCount, SizeOf(FHeader.FileCount));
if (FHeader.FileCount > 0) then
  container.Write(FHeader.Sizes[0], FHeader.FileCount * SizeOf(FHeader.Sizes[0]));

// Laden
container.Read(FHeader.FileCount, SizeOf(FHeader.FileCount));
SetLength (FHeader.Sizes, FHeader.FileCount);
if (FHeader.FileCount > 0) then
  container.Read(FHeader.Sizes[0], FHeader.FileCount * SizeOf(FHeader.Sizes[0]));

Gruß Hawkeye