Statusbar mit getrennten hints?

[easteregg]

Heyho,

ich möchte meine mehrgeteilte Statusbar mit unterschiedlichen hints ausstatten.
allerdings bekomme ich das nicht hin, habs bis dato nur geschafft, einen globalen hint für die ganze bar zu setzen.

bei mir sieht das so aus

Delphi-Quellcode:

-------------------------------
| zeit | was passierte? | kb  |
-------------------------------

und bei dem "kb" würde ich gerne als hint "bytes send" erstellen, für die anderen zwei soll es allerdings kein hint geben.
wie bekpomm ich sowas hin?


Danke schonmal für eure hilfe ;)

[sirius]

Ich würd ja im Ereignis onHint die Mausposition abfragen.

(Allerdings dürfte dann noch ein Problem übrig bleiben)

[easteregg]

welches problem bleibt da übrig?
und hast du vlt. ne idee wie man das macht? ;) weil wenn du das weist, bist du schneller im erklären, als ich im googlen ;)

[marabu]

Hallo Richi,

so oder ähnlich sollte es funktionieren:

Delphi-Quellcode:

function GetPanelAt(sb: TStatusBar; x, y: Integer; var index: Integer): Boolean;
var
  r: TRect;
  pt: TPoint;
begin
  Result := not sb.SimplePanel;
  if Result then
  begin
    pt := Point(x, y);
    index := sb.Panels.Count;
    Result := False;
    repeat
      Dec(index);
      if index < 0 then
        Exit;
      sb.Perform(SB_GETRECT, index, Integer(@r));
      Result := PtInRect(r, pt);
    until Result;
  end;
end;

procedure TDemoForm.AppShowHint(var HintStr: string; var CanShow: boolean;
  var HintInfo: THintInfo);
var
  index: integer;
  sb: TStatusBar;
  pt: TPoint;
begin
  if (HintInfo.HintControl is TStatusBar) then
  begin
    sb := TStatusBar(HintInfo.HintControl);
    pt := sb.ScreenToClient(Mouse.CursorPos);
    if GetPanelAt(sb, pt.X, pt.Y, index) then
    begin
      HintStr := IntToStr(index);
      HintInfo.ReshowTimeout := 50;
    end;
  end;
end;

procedure TDemoForm.FormCreate(Sender: TObject);
begin
  Application.OnShowHint := AppShowHint;
end;

Grüße vom marabu