Formatierte Ausgabe nach Vorgabe zur Laufzeit

[StTüff]

Hallo!

Ich möchte einen ganzzahligen Wert der als String (aus einem XML-File) vorliegt in einem (ich nenne es mal) "Sonderformat" ausgeben. Da diese Ausgabe konfigurierbar ausgelegt werden muss, muss die Formatierung zur Laufzeit beeinflussbar sein. Zunächst habe ich an Format() gedacht. Leider kommen aber auch sehr seltsame Formate vor, die ich so nicht abdecken kann.

Beispiel: Eine Uhrzeit

Zahlenwert: 123135 soll 12.31.35 werden.

Natürlich kann ich locker ein Programm schreiben, das diese spezielle Umwandlung vornimmt. Es soll aber möglich sein, diese Formatvorgabe im Feld (also ohne Update der Software) zu konfigurieren.
Es könnte also jemand auf die Idee kommen eine andere Darstellung zu bevorzugen:

123135 => 12h31m35s,00ms

So eine "mächtige" Format-Funktion (die auch Zahlenwerte nach Vorgabe "zerstückeln" kann) gibt es noch nicht, oder? Wenn jemand was fertiges kennt, wäre es schön, wenn er sich melden würde, bevor ich mich selbst daran mache.... :coder:

Gruß,

StTüff

[dataspider]

Hi,

ich hatte so was mal für einen Import geschrieben:

Delphi-Quellcode:

function rwReFormat(const AString, InputMask, OutPutMask: string): string;
Const
  BlankChar = #0;
Var
  i : Integer;
  MaskChar: Char;
  LastmaskChar: Char;
  PosInputMask: Byte;
  OffSet: Byte;
  AddChar: Char;
begin
  LastmaskChar := BlankChar;
  PosInputMask := 1;
  Result := '';
  for i := 1 to length(OutPutMask) do
  begin
    AddChar := BlankChar;
    // nächstes Zeichen
    MaskChar := OutPutMask[i];
    // wenn gleiches Zeichen noch mal
    if MaskChar <> LastmaskChar then
      OffSet := 1
    else
      OffSet := Succ(PosInputMask);
    LastmaskChar := MaskChar;
    PosInputMask := PosEx(MaskChar, InputMask, OffSet);
    if PosInputMask = 0 then
      AddChar := MaskChar
    else
    begin
      if PosInputMask <= Length(AString) then
        AddChar := AString[PosInputMask];
      case
        MaskChar of
          '9':
            if not (AddChar in ['0'..'9']) then
              AddChar := BlankChar;
          'x': AddChar := Char(CharLower(PChar(AddChar)));
          'X': AddChar := Char(CharUpper(PChar(AddChar)));
      end
    end;
    if AddChar <> BlankChar then
      Result := Result + AddChar;
  end;
end;

Beispiel:

Delphi-Quellcode:

  rwReFormat('120106', '999999', '99.99.2099');
  // ergibt '12.01.2006'

Vielleicht kannst du es an deine Bedürfnisse anpassen. Jede Stelle des Inputformates entspricht einem Zeichen. Probier einfach mal aus.

Cu, Frank
[EDIT]
noch ein Beispiel:

Delphi-Quellcode:

rwReFormat('2006-12-01', 'JJJJ-MM-TT', 'TT.MM.JJJJ');
// ergibt '01.12.2006'

[StTüff]

Tolle Sache! Ich glaube, das geht in die richtige Richtung.
Vielen Dank für das Beispiel!

Gruß,

StTüff

[dataspider]

Hi,

mit einer kleinen Änderung funktioniert auch dein zweites Beispiel:

Delphi-Quellcode:

    ...
    if AddChar <> BlankChar then
      Result := Result + AddChar
    else
      // wenn kein Zeichen entsprechend Inputmask da ist...
      Result := Result + '0';

  end;
end;

rwReFormat('123135', 'HHMMSSTT', 'HHhMMmSSs,TTms');
// ergibt 12h31m35s,00ms

Cu, Frank

[StTüff]

Sehr schön, noch mal vielen Dank!

StTüff