VirtualStringTree

[StefanG]

ok dann hier nochmal die Fragen zu diesem Thread :

http://www.delphipraxis.net/internal...4daf6f889cf78d


ok ich habs mir nochmal runtergeladen.

Mein erstes Problem war, wie adde ich ein node -.-

Geht das Wirklich nur, indem man den RootNodeCount erhöht? (ich brauche ja quasi nur roots)

zweites Problem : wie weise ich den Nodes einen Text zu? Ich habe gesehen, dass es ein OnGetText event gibt.
Ich habe versucht dort etwas zu machen wie :

Delphi-Quellcode:

procedure TForm1.VirtualStringTreeGetText(Sender: TBaseVirtualTree;
  Node: PVirtualNode; Column: TColumnIndex; TextType: TVSTTextType;
  var CellText: WideString);
begin
if i <= processes.ItemCount - 1 then
begin
  celltext := ExtractFileName(arrProcesses[i]);  // <-- arrProcesses ist ein Array, in dem die Namen aller laufenden Prozesse stehen
  inc(i);
end;

geht aber nicht wirklich gut, da die Funktion scheinbar auch bei jedem scrollen aufgerufen wird. Dabei erhöht sich I ständig und gibt irgendwann nur noch leerstrings zurück.

drittes Problem :

wie füge ich jedem Node ein spezifisches Icon hinzu? Ich habe ein zweites array mit den dazugehörigen icons für die Programme,
die indizes von Programm und Icon sind also die gleichen in beiden Arrays?


hui ganz schön viele Fragen fürs erste, ich hoffe mir kann geholfen werden :)



EDIT : hab schon rausgefunden, dass es in dem Event geht, wenn ich Celltext := ExtractFileName(arrProcesses[nodes.index]);
mache. Bleibt noch das Problem mit den Bildern

[chaosben]

Ein wenig Grundsätzliches zum VST (aka VirtualStringTree):
Viele Sachen werden hier mit Pointern erledigt. Nicht gleich erschrecken. Es ist einfacher als man denkt.

Der erste Schritt auf dem Weg zum VST-Glück beginnt im Kopf. Wir fragen uns: Welche Daten soll ein Knoten kennen? Oft soll ein Knoten eine Caption, einen Hint und einen ImageIndex haben.
Ok, wenn wir das wissen können, wir mit dem Coden beginnen. Alle Daten die ein Knoten halten soll, merken wir uns hier mal in einem Record (später wirst du wahrscheinlich auf Objekte ausweichen).

Delphi-Quellcode:

TNodeData = record
  Caption,
  Hint : String;
  ImageIndex : Integer;
end;

PNodeData = ^TNodeData; //unser Pointertyp

So, nun haben wir die benötigten Typen.
Jetzt muss der VST noch wissen, wie groß unsere Daten im Speicher sind, denn die Speicherverwaltung übernimmt der VST.
Dafür gibts das "OnGetNodeDataSize"-Ereignis. Dieses sieht für unser Beispiel so aus:

Delphi-Quellcode:

procedure TVGetNodeDataSize(Sender: TBaseVirtualTree; var NodeDataSize: Integer);
begin
  NodeDataSize:=sizeOf(TNodeData);
end;

Jetzt fügen wir einen Knoten hinzu.

Delphi-Quellcode:

var
  Node : PVirtualNode;
  NData : PNodeData; //Unser selbstdefinierter Typ
begin
  Node:=TV.AddChild(nil); //Hier bekommen wir unseren Knoten
  //Jetzt hat der VST schon Speicher reserviert, wo wir unsere Daten ablegen können
  //Nur wo?
  NData:=Tv.GetNodeData(Node); //Na hier! ;) ... und diese Zeile merken, die brauchen wir oft
  //Und los geht das fröhliche Datenablegen
  Ndata.Caption:='Ich bin ein Knoten, geboren um '+TimeToStr(Now);
  Ndata.Hint:='Wow, du hast mich mit der Maus getroffen :)';
  Ndata.ImageIndex:=4;
end;

So weit so gut. Jetzt müssen wir die Wissenslücken des VST stopfen.
1. Lücke: Welche Caption soll ich malen?

Delphi-Quellcode:

procedure TVGetText(Sender: TBaseVirtualTree; Node: PVirtualNode; Column: TColumnIndex; TextType: TVSTTextType; var CellText: WideString);
var
  NData : PNodeData;
begin
  //Erstmal holen wir uns die Daten zu diesem Knoten
  NData:=TV.GetNodeData(Node); //Hab ichs nicht gesagt ;)
  CellText:=NData.Caption;
end;

2. Lücke: Welche Hints soll ich anzeigen?

Delphi-Quellcode:

procedure TVGetHint(Sender: TBaseVirtualTree; Node: PVirtualNode; Column: TColumnIndex; var LineBreakStyle: TVTTooltipLineBreakStyle; var HintText: WideString);
var
  NData : PNodeData;
begin
  NData:=TV.GetNodeData(Node); //:)
  HintText:=NData.Hint;
end;

(TV.HintMode noch auf hmHint setzen)

3. Lücke: Und welche Bilder?

Delphi-Quellcode:

procedure TVGetImageIndex(Sender: TBaseVirtualTree;
  Node: PVirtualNode; Kind: TVTImageKind; Column: TColumnIndex;
  var Ghosted: Boolean; var ImageIndex: Integer);
var
  NData : PNodeData;
begin
  NData:=Tv.GetNodeData(Node); //ohne Kommentar
  ImageIndex:=Ndata.ImageIndex;
end;

Und fertig.

Das ist jetzt nur eine gaaaaanz kleine Einführung gewesen. Der Rest ergibt sich dann beim probieren und rumspielen. (... und die ganz Harten nehmen den VirtualDrawTree :) ) HF!

[StefanG]

wow, danke erstmals für die Mühe, ist alles super verständlich und ich habs auch soweit hinbekommen.

Kurze Frage noch, ob man 2 Dinge machen kann, die bei einer Listview automatisch funktionierten :

- Sortieren der Nodes nach ihrem Namen
- Springen zu einem node, wenn man den anfangsbuchstaben drückt

[chaosben]

Zitat:

Zitat von StefanG

ob man 2 Dinge machen kann

Wehe du sprichst noch einmal so zweifelnd über VST! ;)

Zum Sortieren:
TreeOptions.AutoOptions.AutoSort = true

und

Delphi-Quellcode:

procedure TVCompareNodes(Sender: TBaseVirtualTree; Node1,
  Node2: PVirtualNode; Column: TColumnIndex; var Result: Integer);
var
  NData1,
  NData2 : PNodeData;
begin
  NData1:=Tv.GetNodeData(Node1);
  Ndata2:=Tv.GetNodeData(Node2);
  Result:=AnsiCompareStr(Ndata1.Caption,Ndata2.Caption);
end;

Die andere Sache: Da hab ich im Moment keine schöne Lösung ... als Workaround kann man OnKeyXXXX nutzen. Aber ich bin mir sicher, das es da auch schon was natives gibt.

[jbg]

Zitat:

Zitat von chaosben

Die andere Sache: Da hab ich im Moment keine schöne Lösung ... als Workaround kann man OnKeyXXXX nutzen. Aber ich bin mir sicher, das es da auch schon was natives gibt.

Wie wäre es mit dem Ereignis: OnIncrementalSearch

[StefanG]

ahaha , danke für die Tipps, jetzt geht alles so wie es soll :D

[sh17]

es geht evtl. auch einfacher. wenn man die ganzen Daten sowieso schon aufbereitet hat, kann man die PNodeData-Sache weg lassen.

Einfaches Beispiel mit einer StringList, geht dann natürlich auch mit TObjectList und allen anderen List-Typen

Delphi-Quellcode:

vst.RootNodeCount := myStringList.Count;

...

procedure TVGetText(Sender: TBaseVirtualTree; Node: PVirtualNode; Column: TColumnIndex; TextType: TVSTTextType; var CellText: WideString); 
begin 
  CellText := myStringList[Node.Index]; 
end;

[Daniel]

Ich habe die Frage von sevenex in einen eigenen Thread ausgelagert: http://www.delphipraxis.net/internal...ct.php?t=90132