Kann den Titel der Form nicht ändern

[RWarnecke]

Hallo zusammen,

ich habe mit der folgenden Procedure eine Form aus einer DLL aufgerufen :

Delphi-Quellcode:

procedure TMainControl.Configuration_btnClick(Sender: TObject);
var
  hDLL : THandle;
  ConfigWindow : TConfigWindow;
begin
  hDLL := LoadLibrary(PChar(ExtractFilePath(ParamStr(0))+'config.dll'));
  if hDLL <> 0 then begin
    try
      ConfigWindow := GetProcAddress(hDLL, 'configuration');
      ConfigWindow(Application.Handle);
    finally
      FreeLibrary(hDLL);
    end;
  end;
  setLanguage;
end;

In der DLL steht folgendes :

Delphi-Quellcode:

procedure configuration(appHandle: THandle); stdcall;
begin
  if appHandle = 0 then apphandle := GetActiveWindow;
  Application.Handle := appHandle;
  try
    with TConfigurationMain.Create(Application) Do
      try
        ShowModal
      finally
        Free;
      end
  except
    On E: Exception Do Application.HandleException(E);
  end;
  Application.Handle := 0;
end;

Wenn ich nun im FormShow-Ereignis die Caption der Form ändern möchte, bleibt immer die Caption drin, die ich im Objekt-Inspektor eingegeben habe. Was mache ich falsch ?

[SirThornberry]

an welcher stelle änderst denn du die caption? ich seh in dem geposteten source nirgends wo du die caption neu setzt. Desweiteren gibst du ja das handle der Application weiter und nicht das von einem TForm.

[RWarnecke]

Ich vergebe eine neue Caption der Form im OnCreate-Ereignis der TForm.

Delphi-Quellcode:

procedure TConfigurationMain.FormCreate(Sender: TObject);
var
  hDLL : THandle;
begin
  Label7.Caption := 'Rechnungsdatum' + #13#10 + 'plus x Tage';
  Label8.Caption := 'Minimum Limit' + #13#10 + 'der Ware für Bestellung';
  hDLL := LoadLibrary(PChar('ressource.dll'));
  if hDLL <> 0 then begin
    try
      Closebtn.Glyph.LoadFromResourceName(hDLL,'beenden');
    finally
      FreeLibrary(hDLL);
    end;
  end;
  ConfigurationMain.Caption := 'Test';        {<---- Da vergebe ich die neue Caption der Form. Dieses ist jetzt nur ein Beispiel.
                                                    Später wird hier eine Funktion den String liefern.}

Zitat:

Zitat von SirThornberry

Desweiteren gibst du ja das handle der Application weiter und nicht das von einem TForm.

Was meinst Du damit ? Ich habe das ganze nur so aus einem Tutorial gelernt.

[SirThornberry]

das liegt an deiner Programmierweise, du hast objectorientierung mit globaler Programmierung vermischt.

Delphi-Quellcode:

ConfigurationMain.Caption := 'Test';

setzt die Caption von ConfigurationMain

richtiger wäre hier

Delphi-Quellcode:

Self.Caption := 'Test';

oder nur

Delphi-Quellcode:

Caption := 'Test';

[RWarnecke]

Danke für Deine Hilfe. Jetzt funktioniert es. Aber ganz verstehen tue ich das noch nicht ganz.

Wenn ich mehrere Forms in einer EXE habe, da kann ich das so machen. Was ist denn jetzt der Unterschied ?

[SirThornberry]

du kannst dein TConfigurationMain mehrfach erstellen.

Delphi-Quellcode:

x1 := TConfigurationmain.Create(nil);
x2 := TConfigurationmain.Create(nil);
x3 := TConfigurationmain.Create(nil);

danach kannst du mit

Delphi-Quellcode:

x1.caption := 'abc';
x2.caption := 'def';
x3.caption := 'ghi';

die captions der einzelnen forms ändern.

wenn du allerdings nur

Delphi-Quellcode:

TConfigurationmain.Create(nil);
TConfigurationmain.Create(nil);
TConfigurationmain.Create(nil);

aufrufst kannst du logischer weise NICHT mit

Delphi-Quellcode:

x1.caption := 'abc';
x2.caption := 'def';
x3.caption := 'ghi';

die captions ändern. Aber genau das hast du versucht. Du hast versucht die Caption von "Configurationmain" zu ändern obwohl du nie etwas auf "Configurationmain" zugewiesen hast.

[RWarnecke]

Danke für Deine ausführliche Erklärung. Ich habe wieder etwas dazugelernt. Danke.