Streams

[Prototypjack]

Hallo,
Ich schreibe gerade eine Methode zum erstellen eines Komprimierten Archives mit Verzeichnisstrukturen. Ohne Kompressione funzt das ganze schon ganz gut aber mit Kompression macht es Probleme.
Das ganze basiert auf Luckies TArchiv.
Hier die Compressionsmethode die nicht funktioniert:

Delphi-Quellcode:

procedure TArchive.AddCompressedFiles(Files,ArchFileNames: TStrings);
var
  i: Integer;
  fs2: TFileStream;
  fs: TMemorystream;
  FilesCnt: Cardinal;
  FileSize: Int64;
  Filename: string[255];
  FileToAdd: TStreamProgressAdapter; // TFileStream;
  compressin: TFilestream;
  compressout: TMemorystream;
  CompressionStream: TZCompressionStream;
begin
  fs2 := TFileStream.Create(FArchiveFile, fmCreate or fmShareExclusive);
  fs  := TMemorystream.create;
  try
    FilesCnt := Files.Count;
    // write number of files at offset 0
    fs2.WriteBuffer(FilesCnt, sizeof(Cardinal));


    // write files at offset 0 + offset number of files + offset filesizes + offset filenamens
    for i := 0 to FilesCnt - 1 do
    begin
      if FCancel then exit;
      FFilename := Files[i];
      //Add Compression here!
      CompressIn :=Tfilestream.create(Files[i],fmOpenRead);
      compressout :=Tmemorystream.create;
      try
        CompressionStream := TZCompressionStream.Create(compressout, zcMax);
        try
          CompressionStream.CopyFrom(compressin, compressin.Size);
        finally
          CompressionStream.Free;
        end;
        // write filesizes at offset 0 + offset number of files
        FSize :=compressout.size;
        Filesize :=compressout.size;
        fs2.WriteBuffer(FileSize, sizeof(Int64));
        FileToAdd := TStreamProgressAdapter.Create(compressout);
      finally
        FreeAndNil(CompressOut);
        FreeAndNil(CompressIn);
      end;
      try
        FileToAdd.OnProgress := FileAddProgress;
        fs.CopyFrom(FileToAdd, FileToAdd.Size);
        showmessage('test');
      finally
        FreeAndNil(FileToAdd);
      end;
      if Assigned(OnTotalProgress) then
        OnTotalProgress(self, FilesCnt, i);
    end;
    // write filenames at offset 0 + offset number of files + offset filesizes
    for i := 0 to FilesCnt - 1 do
    begin
      Filename := (ArchFileNames[i]);
      fs2.WriteBuffer(Filename, 255);
    end;
    fs2.CopyFrom(fs,fs.size);
  finally
    FreeAndNil(fs);
    FreeAndNil(fs2);
  end;
end;

Hier die normale Schreibmethode, welche funktioniert:

Delphi-Quellcode:

procedure TArchive.AddFiles(Files,ArchFileNames: TStrings);
var
  i: Integer;
  fs: TFileStream;
  FilesCnt: Cardinal;
  FileSize: Int64;
  Filename: string[255];
  FileToAdd: TStreamProgressAdapter; // TFileStream;
begin
  fs := TFileStream.Create(FArchiveFile, fmCreate or fmShareExclusive);
  try
    FilesCnt := Files.Count;
    // write number of files at offset 0
    fs.WriteBuffer(FilesCnt, sizeof(Cardinal));
    // write filesizes at offset 0 + offset number of files
    for i := 0 to FilesCnt - 1 do
    begin
      FileSize := GetFileSize(Files[i]);
      fs.WriteBuffer(FileSize, sizeof(Int64));
    end;
    // write filenames at offset 0 + offset number of files + offset filesizes
    for i := 0 to FilesCnt - 1 do
    begin
      Filename := (ArchFileNames[i]);
      fs.WriteBuffer(Filename, 255);
    end;
    // write files at offset 0 + offset number of files + offset filesizes + offset filenamens
    for i := 0 to FilesCnt - 1 do
    begin
      if FCancel then exit;
      FSize := GetFileSize(Files[i]);
      FFilename := Files[i];
      FileToAdd := TStreamProgressAdapter.Create(TFileStream.Create(Files[i],
        fmOpenRead));
      try
        FileToAdd.OnProgress := FileAddProgress;
        fs.CopyFrom(FileToAdd, FileToAdd.Size);
      finally
        FreeAndNil(FileToAdd);
      end;
      if Assigned(OnTotalProgress) then
        OnTotalProgress(self, FilesCnt, i);
    end;
  finally
    FreeAndNil(fs);
  end;
end;

Ich würde es sehr begrüßen wenn mir jemand bei der Fehlerbeseitigung im obigen Code helfen könnte.
Achja, zu den Fehlern: Das sind so tolle Exceptions aus denen keiner Schlau wird.

Danke schonmal,
Gruß,
Max

[jim_raynor]

Am besten du schaltest mal den Debugger an und gehst mal Zeile für Zeile durch. Einfach zu sagen, hab Fehler könnt ihr mir sagen wo, wird hier nicht so gerne gesehen. Achja. Irgendjemand hat hier auch ein recht umfangreiches Tutorial zum Debugger geschrieben. Also falls du den Debugger noch nicht genutzt hast, schaust du hier:

http://www.delphipraxis.net/internal...ct.php?t=47972

[edit]Auf Anhieb kann ich keine Fehler entdecken[/edit]

[Prototypjack]

Entschuldigung.
Ich ahbe vergessen zu erwähnen das die Showmessage die 'Test' enthält nicht ausgegeben wird also liegt der Fehler zwangsläufig hier:

Delphi-Quellcode:

        FileToAdd.OnProgress := FileAddProgress;
        fs.CopyFrom(FileToAdd, FileToAdd.Size);

[jim_raynor]

Trotzdem ist der Debugger sehr hilfreich ;) Erspart dir die ShowMessage Arie und ähnliches.

Mittlerweile hab ich aber eventuell etwas gefunden. Ich denke du darfst CompressOut nicht freigeben. Dieses TStreamProgressAdapter ist ja nur ein Adapter. Er erzeugt bestimmt keinen neuen Stream sondern nutzt den, den du bei Create übergeben hast. Von daher ist das FreeAndNil(CompressOut) sehr fatal. Den darfst du erst freigeben, wenn du auch FileToAdd freigibts.

P.S: Überall verwendest du FreeAndNil, nur bei CompressionStream nicht ;)

[Prototypjack]

Hmm, schon komisch, diesesm Delphi :mrgreen:
Nein im ernst, erst nachdem ich deinen Tipp bekommen habe brachte mir der DeBugger brauchbare Ergebnisse. Davor hat er mir immer das Ende der Unit 1 empfohlen(In der aber auch _garnichts_ von dem Fehler war. Sogar der Code war in eine andere Unit ausgelagert)
Jetzt funktionieren beite Routinen gut.
Danke auf jeden Fall!
Gruß,
Max