Probleme beim Auslesen der Registry

[Sascha L]

Hallo,

ich habe eine TreeView-Komponente, in der ich alle Keys aus der Registry anzeigen möchte. Natürlich in Form einer normalen Baumstruktur.

Das klappt auch alles soweit gut. Nun gibt es ja Keys, die Subkeys haben und welche, die keine haben. Die, die keine haben, bekommen natürlich kein "Plus" vor ihrem Text.

Auch das funktioniert mit folgendem Code:

Delphi-Quellcode:

   Reg.GetKeyNames(KeyNames);
   KeyNames.Sort;
   for I := 0 to KeyNames.Count - 1 do
    begin
        TreeView1.Items.AddChild(Node,KeyNames.Strings[i]);
        Reg2.OpenKey(KeyNames.Strings[i],false);
        Reg2.GetKeyInfo(info);
        if info.NumSubKeys > 0 then Node.Item[i].HasChildren := true;
        Reg2.CloseKey;
    end;

Mit "Reg" lese ich alle Keys aus und mit Reg2 überprüfe ich ob die Keys noch Subkeys haben.


Der Code ist natürlich nur ein kleiner Ausschnit. Ich gebe natürlich Reg und Reg2 am Ende frei, und habe den Aufruf in einem try-Block, etc.


Mein Problem ist nun, dass der Code oben mit allen Keys funktioniert. Wenn ich aber den Code für "HKEY_CLASSES_ROOT" durchlaufen, stürzt mein Programm und die CPU-Auslastung ist bei 100%. Ich weiß, dass in HKEY_CLASSES_ROOT, sehr viele Keys drin sind, aber es muss doch eine mögichkeit geben, zu überprüfen, ob all diese Keys noch Subkeys haben.

Ich habe es auch schon mit "Reg2.hassubkeys" probiert, aber da stürzt mein Programm auch ab.

Da es mit "HKEY_CURRENT_USER", etc. einwandfrei funktioniert, liegt es wohl daran, dass HKEY_CLASSES_ROOT sehr viele Keys hat. Da der Code funktioniert, denke ich mal, dass die Registry nicht so viele Zugriffe direkt hintereinander verkraftet.

Hat jemand eine Idee, wie das Problem lösen könnte?

Viele Grüße
Sascha

[BTeam]

Auch wenn es dir bei deinem Problem jetzt nicht wirklich Hilft aber in der Jedi VCL gibt es eine Komponente Namens "JvRegistryTreeView" die macht genau das was du da versuchst. ^^

[Sascha L]

Hi,

ja das hilft mir glaube ich nicht, da ich nämlich die Komponente benutzen will, die ich im Moment nutze, da die bestimmte Dinge kann, die ich benötige.

Gruß
Sascha

[dahead]

1.) wenn dein programm bei vielen keys abschmiert, kann es sein, dass du irgendwo evtl. vergisst etwas freizugeben?
2.) warum verwendest du mehrere TRegistry's? du kannst doch mit Reg1 auch prüfen ob da subkeys drin sind. ich würde an deiner stelle evtl. mal kucken, ob der zugriff von zwei TRegistry's den fehler verursacht.
3.) falls das alles nicht zutrifft, kannst du versuchen, die subkeys erst zu laden, wenn der benutzer auf den ordner klickt.

[Sascha L]

Zitat:

Zitat von dahead

1.) wenn dein programm bei vielen keys abschmiert, kann es sein, dass du irgendwo evtl. vergisst etwas freizugeben?
2.) warum verwendest du mehrere TRegistry's? du kannst doch mit Reg1 auch prüfen ob da subkeys drin sind. ich würde an deiner stelle evtl. mal kucken, ob der zugriff von zwei TRegistry's den fehler verursacht.
3.) falls das alles nicht zutrifft, kannst du versuchen, die subkeys erst zu laden, wenn der benutzer auf den ordner klickt.

zu 1.) nein, wird alles freigegeben. Wie gesagt, es funktioniert ja mit allen Keys, nur wenn ich "HKEY_CLASSES_ROOT" öffnen will.
zu 2.) daran liegt es nicht. ich habe 2 TRegistriys verwendet, weil mit nur einer auch der Fehler kam, da hab ich ausprobiert, ob der Fehler weg geht, wenn ich 2 verwende.
zu 3.) Das mache ich ja auch so. Worum es mir aber geht ist, dass ich ja wissen muss, ob der Ordner Subkeys hat oder nicht. Ich kann ja nicht vor jedem Ordner ein Plus machen, obwohl der Ordner gar keine Subkeys hat. Also muss ich erstmal durchprüfen, welcher Key Subkeys hat und dann nur vor diesen Keys ein Plus setzen. Verstehst du?

[dahead]

ja, ist mir klar.

allerdings verwendet z.b. der explorer beim anzeigen von bspw. netzwerk-freigabe-ordnern auch immer ein plus, erst wenn du dann auf den ordner klickst, und dieser keine unterordner hat, verschwindet das plus. das wird da gezeichnet, um geschwindigkeit zu erzielen.

welche Treeview komponente verwendest du? nimm (falls nicht schon) die TVirtualTreeView von Mike Lischke (http://www.soft-gems.net), die ist sehr schnell und bietet genau diese funktionalität.

falls du das nicht willst, könntest du auch einfach speichern, ob der key subkeys hat oder nicht (Keys > 0), noch gar nicht auslesen, nur kucken _ob_ oder _nicht_.

[SirThornberry]

ich hab das ganze so gelöst das wenn ein subkey existiert ein Item "\" angelegt wird. Im OnExpand überprüfe ich dann ob ein solches Item existiert und wenn dies der fall ist wird der unterzweig dann gefüllt.
Folgende Procedure befüllt den TreeView

Delphi-Quellcode:

procedure ShowRegInTree(ATree: TTreeView; AParentNode: TTreeNode; ARegPath: String);
var LRegistry, LReg2: TRegistry;
    LNames: TStringlist;
    LCount: Integer;
    LNode: TTreeNode;
begin
  ATree.Items.BeginUpdate;
  LRegistry := TRegistry.Create;
  LRegistry.RootKey := HKEY_CLASSES_ROOT;
  if Assigned(AParentNode) then
    AParentNode.DeleteChildren;
  if LRegistry.OpenKey(ARegPath, False) then
  begin
    LReg2 := TRegistry.Create;
    LReg2.RootKey := LRegistry.RootKey;
    LNames := TStringList.Create;
    LRegistry.GetKeyNames(LNames);
    for LCount := 0 to LNames.Count - 1 do
    begin
      LNode := ATree.Items.AddChild(AParentNode, LNames.Strings[LCount]);
      if LReg2.OpenKeyReadOnly(ARegPath + '\' + LNames.Strings[LCount]) then
      begin
        if LReg2.HasSubKeys then
          ATree.Items.AddChild(LNode, '\');
        LReg2.CloseKey;
      end;
    end;
    LNames.Free;
    LRegistry.CloseKey;
    LReg2.Free;
  end;
  LRegistry.Free;
  ATree.Items.EndUpdate;
end;

Um den Baum erstmal mit den ersten Items zu befüllen

Delphi-Quellcode:

ShowRegInTree(TreeView1, TreeView1.Items.GetFirstNode, '');

und im OnExpanding

Delphi-Quellcode:

var LPath: String;
    LNode2: TTreeNode;
begin
  AllowExpansion := True;
  if (Node.Count = 1) and (Node.Item[0].Text = '\') then
  begin
    LNode2 := Node;
    LPath := LNode2.Text;
    while Assigned(LNode2.Parent) do
    begin
      LNode2 := LNode2.Parent;
      LPath := LNode2.Text + '\' + LPath;
    end;
    ShowRegInTree(TreeView1, Node, LPath);
  end;
end;

[Sascha L]

SUPER! Danke, der Code funktioniert :)

EDIT:
---------

Irgendwie steige ich da nicht durch den Code durch :(

Ich bekomme es nicht hin, dass ich im Baum alle HKEYS habe und der Code damit funktioniert. Dein Code ruft ja nur HKEY_CLASSES_ROOT und dessen Subkeys auf.

[SirThornberry]

dann eben so:

zum befüllen des Tree:

Delphi-Quellcode:

procedure ShowRegInTree(ATree: TTreeView; AParentNode: TTreeNode; ARegPath: String);
var LRegistry, LReg2: TRegistry;
    LNames: TStringlist;
    LCount: Integer;
    LNode: TTreeNode;
begin
  ATree.Items.BeginUpdate;
  LRegistry := TRegistry.Create;
  LNode := AParentNode;
  while (LNode.Data = nil) and Assigned(LNode.Parent) do
    LNode := LNode.Parent;
  LRegistry.RootKey := HKey(LNode.Data);
  AParentNode.DeleteChildren;
  if LRegistry.OpenKey(ARegPath, False) then
  begin
    LReg2 := TRegistry.Create;
    LReg2.RootKey := LRegistry.RootKey;
    LNames := TStringList.Create;
    LRegistry.GetKeyNames(LNames);
    for LCount := 0 to LNames.Count - 1 do
    begin
      LNode := ATree.Items.AddChild(AParentNode, LNames.Strings[LCount]);
      if LReg2.OpenKeyReadOnly(ARegPath + '\' + LNames.Strings[LCount]) then
      begin
        if LReg2.HasSubKeys then
          ATree.Items.AddChild(LNode, '\');
        LReg2.CloseKey;
      end;
    end;
    LNames.Free;
    LRegistry.CloseKey;
    LReg2.Free;
  end;
  LRegistry.Free;
  ATree.Items.EndUpdate;
end;

Ganz am Anfang um erstmal root-Items in den Baum zu bekommen

Delphi-Quellcode:

var LNode: TTreeNode;
begin
  //Root
  LNode := TreeView1.Items.AddChild(nil, 'Root');
  LNode.Data := Pointer(HKEY_CLASSES_ROOT);
  ShowRegInTree(TreeView1, LNode, '');
  //User
  LNode := TreeView1.Items.AddChild(nil, 'User');
  LNode.Data := Pointer(HKEY_CURRENT_USER);
  ShowRegInTree(TreeView1, LNode, '');

und im OnExpanding:

Delphi-Quellcode:

var LPath: String;
    LNode2: TTreeNode;
begin
  AllowExpansion := True;
  if (Node.Count = 1) and (Node.Item[0].Text = '\') then
  begin
    LNode2 := Node;
    LPath := LNode2.Text;
    while Assigned(LNode2.Parent) and (LNode2.Parent.Data = nil) do
    begin
      LNode2 := LNode2.Parent;
      LPath := LNode2.Text + '\' + LPath;
    end;
    ShowRegInTree(TreeView1, Node, LPath);
  end;

[Sascha L]

ja, nun geht es.

vielen dank. hast was gut bei mir :)