Gethtml in einem Delphi Thread?

[Prym]

Zitat:

Zitat von huberlix

Oder, wenn du die Seite als Quelltext haben willst: Das folgende hab ich aus "Easy Delphi Helper" kopiert:

Zitat:

Den Inhalt einer HTML-Datei aus dem Internet downloaden


Wie kann ich eine HTML-Datei aus dem Internet downloaden und in einem Memofeld anzeigen.

Diese Lösung habe ich bei www.delphi3000.com gefunden. Damit die Funktion funktioniert muss noch eine Unit eingebunden werden:

Delphi-Quellcode:

uses WinInet;


Function GetHTML(AUrl: string): string;
var
  databuffer : array[0..4095] of char;
  ResStr : string;
  hSession, hfile, hRequest: hInternet;
  dwindex,dwcodelen,datalen,dwread,dwNumber: cardinal;
  dwcode : array[1..20] of char;
  res    : pchar;
  Str    : pchar;
begin
  ResStr:='';
  if pos('http://',lowercase(AUrl))=0 then
     AUrl:='http://'+AUrl;
  hSession:=InternetOpen('InetURL:/1.0',
                         INTERNET_OPEN_TYPE_PRECONFIG,
                         nil,
                         nil,
                         0);
  if assigned(hsession) then
  begin
    hfile:=InternetOpenUrl(
           hsession,
           pchar(AUrl),
           nil,
           0,
           INTERNET_FLAG_RELOAD,
           0);
    dwIndex  := 0;
    dwCodeLen := 10;
    HttpQueryInfo(hfile,
                  HTTP_QUERY_STATUS_CODE,
                  @dwcode,
                  dwcodeLen,
                  dwIndex);
    res := pchar(@dwcode);
    dwNumber := sizeof(databuffer)-1;
    if (res ='200') or (res ='302') then
    begin
      while (InternetReadfile(hfile,
                              @databuffer,
                              dwNumber,
                              DwRead)) do
      begin
        if dwRead =0 then
          break;
        databuffer[dwread]:=#0;
        Str := pchar(@databuffer);
        resStr := resStr + Str;
      end;
    end
    else
      ResStr := 'Status:'+res;
    if assigned(hfile) then
      InternetCloseHandle(hfile);
  end;
  InternetCloseHandle(hsession);
  Result := resStr;
end;

So erfolgt der Aufruf:

Delphi-Quellcode:

procedure TForm1.MultilineButton1Click(Sender: TObject);
begin
  Memo1.Text:=GetHTML('http://localhost/index.htm');
end;

--
Homepage: http://www.delphi3000.com

also ich wollte fragen wie man die obige gethtml funktion in einen thread tun kann ich habe da nicht viel ahnung weil zb kann ich in der unit beim thread oder muss ich da die funktion einfach so reinklopen usw?

und kann ich die funktion überhaupt darein tun weil ich schon was mit fehlern wegen irgend welchen sachen die da nicht kompatiobel sind usw?

[edit=alcaeus]Delphi-Tags eingefuegt. Bitte in Zukunft selbst machen, Danke. Mfg, alcaeus[/edit]

[yankee]

du machst dir das Leben reichlich schwer. Probier es mal damit:

Delphi-Quellcode:

function getHTML(const url: string):string;
var idhttp :Tidhttp;
begin
    idhttp :=Tidhttp.Create(Form1);
    result :=idhttp.Get(url);
    idhttp.Free;
end;

nicht vergessen:

Delphi-Quellcode:

uses IdBaseComponent, IdComponent, IdTCPConnection, IdTCPClient,
  IdHTTP;

einfach oben ergänzen *fg*

Warum sollte man das nicht in Threads ausführen können? Probier's doch einfach aus!

[Prym]

und wo bekomme ich die komponenten her?

[yankee]

Zitat:

Zitat von Prym

und wo bekomme ich die komponenten her?

was hast du für eine Delphi-Version? *kopfkratz*
Also eigentlich ist die immer vorinstalliert und bei Delphi direkt dabei. Schau einfach mal unter "Indy clients"
Anosnsten:
http://www.indyproject.org/download/Files/Indy9.html

[x000x]

Zitat:

Zitat von Prym

also ich wollte fragen wie man die obige gethtml funktion in einen thread tun kann ...

Delphi-Quellcode:

unit UDemo2;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm1 = class(TForm)
    Memo1: TMemo;
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;

  TMyThread = class(TThread)
  private
     FMemoHandle : THandle;
     FUrl        : String;
  protected
     procedure Execute; override;
  public
    constructor Create(MemoHandle: THandle; AUrl: String);
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

uses WinInet;

Function GetHTML(AUrl: string): string;
var
  databuffer : array[0..4095] of char;
  ResStr : string;
  hSession, hfile, hRequest: hInternet;
  dwindex,dwcodelen,datalen,dwread,dwNumber: cardinal;
  dwcode : array[1..20] of char;
  res    : pchar;
  Str    : pchar;
begin
  ResStr:='';
  if pos('http://',lowercase(AUrl))=0 then
     AUrl:='http://'+AUrl;
  hSession:=InternetOpen('InetURL:/1.0',
                         INTERNET_OPEN_TYPE_PRECONFIG,
                         nil,
                         nil,
                         0);
  if assigned(hsession) then
  begin
    hfile:=InternetOpenUrl(
           hsession,
           pchar(AUrl),
           nil,
           0,
           INTERNET_FLAG_RELOAD,
           0);
    dwIndex  := 0;
    dwCodeLen := 10;
    HttpQueryInfo(hfile,
                  HTTP_QUERY_STATUS_CODE,
                  @dwcode,
                  dwcodeLen,
                  dwIndex);
    res := pchar(@dwcode);
    dwNumber := sizeof(databuffer)-1;
    if (res ='200') or (res ='302') then
    begin
      while (InternetReadfile(hfile,
                              @databuffer,
                              dwNumber,
                              DwRead)) do
      begin
        if dwRead =0 then
          break;
        databuffer[dwread]:=#0;
        Str := pchar(@databuffer);
        resStr := resStr + Str;
      end;
    end
    else
      ResStr := 'Status:'+res;
    if assigned(hfile) then
      InternetCloseHandle(hfile);
  end;
  InternetCloseHandle(hsession);
  Result := resStr;
end;

constructor TMyThread.Create(MemoHandle: THandle; AUrl: String);
begin
  FMemoHandle := MemoHandle;
  FUrl:= AUrl;
  FreeOnTerminate := True;
  inherited Create(True);
end;

procedure TMyThread.Execute;
begin
  inherited;
  SendMessage(FMemoHandle, WM_SETTEXT, 0, Integer(@GetHTML(FUrl)[1]));
end;

procedure TermThread;
begin
   Form1.Button1.Enabled := True;
end;

procedure TForm1.Button1Click(Sender: TObject);
var thGetHTML : TMyThread;
begin
  Button1.Enabled := False;
  thGetHTML := TMyThread.Create(Memo1.Handle, 'www.delphipraxis.net');
  with thGetHTML do begin
     @OnTerminate := @TermThread;
     Suspended := False;
  end;
end;

end.

[Luckie]

Delphi-Quellcode:

procedure TMyThread.Execute; 
begin 
  inherited; 
  SendMessage(FMemoHandle, WM_SETTEXT, 0, Integer(@GetHTML(FUrl)[1])); 
end;

Warum so umständlich? Warum übergibst du nicht eine Variable vom Typ TStrings, dann kannst du es in ein TMemo, ein TRichEdit oder in eine TStringListe laden, je nach belieben wie du willst.

Desweiteren greifst du auf ein VCL Kontroll außerhalb einer Synchronize Methode zu, was potentiel gefährlich ist. Nicht umsonst schreibt der Assistent in jede neue TThread Unit:

Delphi-Quellcode:

{ Important: Methods and properties of objects in VCL or CLX can only be used
  in a method called using Synchronize, for example,

      Synchronize(UpdateCaption);

  and UpdateCaption could look like,

    procedure TTest.UpdateCaption;
    begin
      Form1.Caption := 'Updated in a thread';
    end; }

[x000x]

Moin moin,

Zitat:

Zitat von Luckie

Desweiteren greifst du auf ein VCL Kontroll außerhalb einer Synchronize Methode zu, was potentiel gefährlich ist.

Aus diesem Grunde habe ich SendMessage genommen, bzw. wo greife ich überhaupt auf die VCL zu? :gruebel:

[Luckie]

Ich nehme mal an, dass er wohl ein TMemo aubenutzt. Du benutzt zwar keine VCL methode, um in das Memo zuschreiben, erstmal nicht, aber wie kommt denn das TMemo zu seinen Lines? Doch wohl über eine VCL Methode.

[x000x]

Zitat:

Zitat von Luckie

aber wie kommt denn das TMemo zu seinen Lines? Doch wohl über eine VCL Methode.

Mag sein, der Text wird dann aber vom Hauptthread in das Memo eingefügt, somit kann es doch
nicht zu Problemen führen...
(Nach meinem Wissensstand ist SendMessage Thread sicher, ich lasse mich aber auch eines besseren belehren)