RichEdit und Enter im Text ?!?

[spacewolf]

Moin,

sacht weiß jemand wie man im RichEdit feststellt ob hinter einem Wort ein Enter ist oder nicht ?
Ein Wort zu selektieren das schaff ich jetzt schon ;-)
Aber festzustellen ob nach dem Wort sich eine oder zwei Leerzeilen befinden, da weiß ich nicht wie es geht.
Und dann würd ich noch gern das Enterzeichen (\par) einfügen lassen...

Tja, falls jemand ne Lösung hat... wär toll

THANX and be blessed

say Andreas

Delphi-Quellcode:

var
  foundat : integer;
begin
  with RichEdit do
  begin
    foundat := FindText('Titel:',0,length(Text),[stMatchCase]);
    if foundat > 0 then
    begin
      SetFocus;
      SelStart  := FoundAt;
      SelLength := Length('Titel:');
    end;
  end;
end;

[marabu]

Hallo Andreas,

nimm dir was du brauchst:

Delphi-Quellcode:

uses
  StrUtils;

function TDemoForm.HasTail(line, tail: string): boolean;
begin
  Result := RightStr(line, Length(tail)) = tail;
end;

procedure TDemoForm.FindButtonClick(Sender: TObject);
var
  iLine, iStart, iEmpty: integer;
begin
  with RichEdit do begin
    // character offset der Fundstelle
    iStart := FindText(FindEdit.Text, 0, GetTextLen, []);
    // cursor dahinter positionieren
    SelStart := iStart + Length(FindEdit.Text);
    // Zeilenumbruch hat Länge 2
    SelLength := 2;
    if SelText = #13#10 then begin
      // steht am ende, jetzt leerzeilen zählen
      iEmpty := 0;
      repeat
        Inc(iEmpty);
        SelLength := SelLength + 2;
      until not HasTail(SelText, #13#10);
      ShowMessage(Format(
        '"%s" steht am Zeilenende, gefolgt von %d Leerzeilen',
        [FindEdit.Text, Pred(iEmpty)]
      ));
    end else begin
      // steht nicht am ende, also zeilenumbruch einfügen
      SelLength := 0;
      SelText := #13#10;
    end;
  end;
end;

Grüße vom marabu

[spacewolf]

danke das funzt... super :-)

was macht eigendlich HasTail ???

[marabu]

HasTail() erhöht in meinen Augen die Lesbarkeit des Codes - mehr nicht.

marabu