RichEdit und Zeilenumbruch

[Rose08]

Hallo,

habe ein kleines Problem. Habe in einem RichEditFeld einen Text.

Möchte nun das jedes Wort in einer Zeile geschrieben wird. Hatte mich schon am Auslesen der Leerzeichen probiert und dann einen Zeilenumbruch eingefügt, aber irgendwie funzt das nicht.
Hat vielleicht irgendeiner eine Idee?

Gruß

[DP-Maintenance]

Dieses Thema wurde von "alcaeus" von "Fragen / Anregungen zur DP" nach "VCL / WinForms / Controls" verschoben.
Ist keine Frage zur DP, sondern zu einer VCL-Komponente ;)

[sECuRE]

Hi,

Meinst du so?

Delphi-Quellcode:

MeinRichedit.Lines.Add('zeile1');
MeinRichedit.Lines.Add('zeile2');
// ...

cu

[Matze]

Oder du machst es einfach so:

Delphi-Quellcode:

RichEdit1.Text := StringReplace(RichEdit1.Text, ' ', #13#10, [rfReplaceAll]);

[marabu]

Hallo Rose08,

ich würde es so machen, allerdings verlierst du dann eventuell vorhandene Formatierungen:

Delphi-Quellcode:

unit MainFrm;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ActnList, ComCtrls;

type
  TMainForm = class(TForm)
    RichEdit: TRichEdit;
    ActionButton: TButton;
    procedure ActionButtonClick(Sender: TObject);
  end;

var
  MainForm: TMainForm;

implementation

{$R *.dfm}

function ParseStr(var S: String; delimit: string; purge: boolean): string;
var
  i: integer;
begin
  for i := 1 to Succ(Length(S)) do
    if (i > Length(S)) or (Pos(S[i], Delimit) > 0) then Break;
  Result := Copy(S, 1, Pred(i));
  Dec(i, Ord(not purge));
  Delete(S, 1, i);
end;

procedure MakeWordList(s, delimiters: string; sl: TStrings);
var
  t: string;
begin
  sl.Clear;
  while s <> '' do begin
    t := ParseStr(s, delimiters, true);
    if t <> '' then
      sl.Add(t);
  end;
end;

procedure TMainForm.ActionButtonClick(Sender: TObject);
begin
  MakeWordList(RichEdit.Text, #9#13#10#32'?!".,;:=()/&%$<>#''', RichEdit.Lines);
end;

end.

Grüße vom marabu

[Rose08]

Na das ging ja fix.
Danke hab es eingebaut und es funzt.

Gruß