Dateinamen in Edit-Feld onDragDrop

[kallculator]

Hallo allerseits,
habe mich heute zum ersten Mal in Delphi versucht und hänge jetzt bei dem Versuch, den Namen einer Datei, die ich auf das Fenster meiner Anwendung ziehe, in eine Edit-Box einzufügen.

Vereinfacht dargestellt:

Delphi-Quellcode:

procedure TForm1.FormDragDrop(Sender, Source: TObject; X, Y: Integer);
begin
  if (Source = [eine Datei]) then
    Edit1.Text = Source.Filename;
end;

Bekäme man das irgendwie hin und muss ich für so eine Operation irgendetwas includen ("uses ...")?

Grüße
kallC

[Sprint]

Du musst Windows sagen, dass dein Programm Dateien per Drag & Drop akzeptiert. Und dann musst du deine TForm um eine Nachrichtenschleife erweitern.

Delphi-Quellcode:

type
  TForm1 = class(TForm)
  ...
  private
    { Private-Deklarationen }
    procedure WMDropFiles(var Message: TWMDropFiles); message WM_DROPFILES;
  ...
  end;

Delphi-Quellcode:

uses ShellAPI;

Delphi-Quellcode:

procedure TForm1.FormCreate(Sender: TObject);
begin
  DragAcceptFiles(Self.Handle, True);
end;

Delphi-Quellcode:

procedure TForm1.WMDropFiles(var Message: TWMDropFiles);
var
  Buffer: array[0..MAX_PATH] of Char;
begin

  DragQueryFile(Message.Drop, 0, @Buffer, SizeOf(Buffer));
  Edit1.Text := Buffer;

end;

Wenn du mehrere Dateien auswerten willst, musst du den Rückgabewert von DragQueryFile auswerten und in einer Schleife DragQueryFile aufrufen.

Delphi-Quellcode:

procedure TForm1.WMDropFiles(var Message: TWMDropFiles);
var
  Count: Integer;
  I: Integer;
  Buffer: array[0..MAX_PATH] of Char;
begin

  Memo1.Clear;
  Count := DragQueryFile(Message.Drop, UINT(-1), nil, 0);

  for I := 0 to Count - 1 do
  begin
    DragQueryFile(Message.Drop, I, @Buffer, SizeOf(Buffer));
    Memo1.Lines.Add(Buffer);
  end;

end;

[kallculator]

Vielen Dank für deine ausführliche Antwort! :-D

Das ganze habe ich jetzt erst einmal für nur eine Datei eingebaut. Wenn ich "Run" klicke, werden keine Fehler angezeigt und ich bekomme meine exe-Datei. Nur passiert nichts, sobald ich eine Datei auf dem Window droppen will ("Nicht verfügbar"-Mauszeiger).

[Sprint]

Hast du auch DragAcceptFiles aufgerufen?

[kallculator]

Delphi-Quellcode:

procedure TForm1.FormCreate(Sender: TObject);
begin
  DragAcceptFiles(Self.Handle, True);
end;

Das ist eingebaut. Muss das an eine besondere Stelle?
Vielen Dank für deine Mithilfe!

[kallculator]

Delphi-Quellcode:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ShellAPI, StdCtrls;

type
  TForm1 = class(TForm)
    Edit1: TEdit;
  procedure FormCreate(Sender: TObject);
  private
    { Private declarations }
    procedure WMDropFiles(var Message: TWMDropFiles); message WM_DROPFILES;
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.FormCreate(Sender: TObject);
begin
  DragAcceptFiles(Self.Handle, True);
end;

procedure TForm1.WMDropFiles(var Message: TWMDropFiles);
var
  Buffer: array[0..MAX_PATH] of Char;
begin

  DragQueryFile(Message.Drop, 0, @Buffer, SizeOf(Buffer));
  Edit1.Text := Buffer;

end;

end.

So sieht der komplette Code aufs Wesentliche reduziert aus. Vielleicht habe ich ja schon hier einen Fehler gemacht.

[Sharky]

Hai kallculator,

bei mir geht der Code ohne Probleme (Delphi 7).

[Sprint]

Läuft bei mir unter Windows 95 mit Delphi 3 und unter Windows XP mit Delphi 5 einwandfrei.

[kallculator]

Zitat:

Zitat von Sharky

Hai kallculator,

bei mir geht der Code ohne Probleme (Delphi 7).

nur das Debuggen oder auch das Drag'n'Droppen? Egal welche Datei ich in das Fenster ziehe, es geht nicht.

:(
Was läuft bei mir falsch? Habe Delphi Personal 7 auf Win XP (ein Visual Style dürfte ja nichts ausmachen).
Muss ich bestimmte Form Properties auswählen (BorderStyle, FormStyle, usw.)? Habe den Standard (Neu...) drin.

[Sharky]

Zitat:

Zitat von kallculator

...oder auch das Drag'n'Droppen? ...

Auch das Droppen.

Ich hänge mein Projekt mal an.