DLLs dynamisch laden

[LarsMiddendorf]

Manchmal möchte man auch unter .Net DLL's dynamisch mit LoadLibrary und GetProcAddress laden. Ein Beispiel ist das dynynamische Laden von OpenGL Extensions. Unter .Net werden üblicherweise keine Zeiger auf Funktionen, sondern Delegates eingesetzt. Das Problem ist, dass GetProcAddress einen Zeiger und keine Delegate zurückgibt. Unter .Net 2.0 gibt es für die Konvertierung die Funktion Marshal.GetDelegateForFunctionPointer . Delphi2005 benutzt aber noch das alte Framework, so dass diese Funktion nicht zur Verfügung steht.

Die Funktion CreateDelegate erstellt mit Hilfe von System.Reflection.Emit dynamisch eine neue Klasse und generiert eine Wrapper Methode, die eine unmanaged Funktion über einen Zeiger aufruf. Der Rückgabewert ist dann ein Delegate auf diese neue Funktion.

Die Verwendung wird anhand des folgenden Beispiels gezeigt, indem die Funktion MessageBoxA dynamisch geladen wird.

Delphi-Quellcode:

type

  TMessageBox=function(hwnd:Integer; title, text: string; flags: Integer): Integer;

procedure TWinForm.Button1_Click(sender: System.Object; e: System.EventArgs);
var
  libhandle, ptr: Integer;
  msgbox: TMessageBox;
begin
  libhandle := LoadLibrary('User32');
  ptr := GetProcAddress(libhandle, 'MessageBoxA');
  msgbox := TMessageBox(CreateDelegate(ptr, TypeOf(TMessageBox)));
  msgbox(0, 'Title', 'Text', 2);
end;

Delphi-Quellcode:

unit dynload;

interface

uses System.Reflection, System.Reflection.Emit, System.Threading, System.Runtime.InteropServices;

  function CreateDelegate(ptr: Integer; dtype: System.Type): Delegate;
  function LoadLibrary(filename: string): Integer; external 'Kernel32.dll';
  procedure FreeLibrary(handle: Integer); external 'Kernel32.dll';
  function GetProcAddress(handle: Integer; name: string): Integer;

implementation

var
  modbuilder: ModuleBuilder;
  asmbuilder: AssemblyBuilder;

[DllImport('Kernel32.dll')]
function GetProcAddress(handle:Integer;name:string):Integer;
begin

end;


function CreateDelegate(ptr:Integer;dtype:System.Type):Delegate;
var
  d, m2: MethodInfo;
  paramlist: array of System.Type;
  i: Integer;
  t: TypeBuilder;
  t2: System.Type;
  m: MethodBuilder;
  ilgen: ILGenerator;
begin
  d := dtype.GetMethod('Invoke');
  setlength(paramlist, Length(d.GetParameters));
  for i := 0 to Length(paramlist) - 1 do
    paramlist[i] := d.GetParameters[i].ParameterType;
  t := modbuilder.DefineType('_' + dtype.Name);
  m := t.DefineMethod('Invoke', MethodAttributes.Static or MethodAttributes.Public,d.ReturnType,paramlist);
  ilgen := m.GetILGenerator;
  for i := 0 to Length(paramlist) - 1 do
    ilgen.Emit(OpCodes.Ldarg, i);
  ilgen.Emit(OpCodes.Ldc_I4, Integer(ptr));
  ilgen.EmitCalli(OpCodes.Calli, CallingConvention.StdCall, d.ReturnType, paramlist);
  ilgen.Emit(OpCodes.Ret);
  t2 := t.CreateType();
  m2 := t2.GetMethod('Invoke');
  Result := Delegate.CreateDelegate(dtype, m2);
end;

procedure InitAssembly;
var
  name: AssemblyName;
begin
  name := AssemblyName.Create;
  name.Name := 'Temp';
  asmbuilder := Thread.GetDomain.DefineDynamicAssembly(name, AssemblyBuilderAccess.Run);
  modbuilder := asmbuilder.DefineDynamicModule('Temp');
end;

initialization
 InitAssembly;

end.

[edit=Chakotay1308] Mfg, Chakotay1308[/edit]
[edit=Matze]Code formatiert. Mfg, Matze[/edit]
[edit=flomei]Wir "räumen auf", daher Titel geändert... Mfg, flomei[/edit]