Fehler beim laden einer Funktion aus einer DLL - PC bootet?

[Pseudemys Nelsoni]

hi,

ich habe folgendes versucht:

Delphi-Quellcode:

program patch;

{$APPTYPE CONSOLE}

uses
  Windows;

type
  TRegOpenCurrentUser = function(samDesired: REGSAM; phkResult: PHKEY): LongInt; stdcall;

var
  LibModule: HMODULE;
  RegOpenCurrentUser: TRegOpenCurrentUser;
  phkResult: PHKEY;

begin
  LibModule := LoadLibrary('Advapi32.dll');
  if LibModule <> 0 then // DLL wurde erfolgreich geladen
  begin
    RegOpenCurrentUser := GetProcAddress(LibModule, 'RegOpenCurrentUser');
    if (@RegOpenCurrentUser <> nil) and (RegOpenCurrentUser(KEY_READ, phkResult) = ERROR_SUCCESS) then
    begin
      //
    end;
  end;
end.

Die zweite Bedingung der letzten If-Abfrage löst einen Fehler aus und mein PC bootet direkt... was ist da denn falsch? Und das beste is noch das nach dem Start die projektdatei nichtmehr lesbar ist und ich alles neu schreiben muss (delphi zeigt dann nur vierecke an ~~)

[Robert Marquardt]

Standard-Fehler der Delphiprogrammierer. Ein Zeiger in C ist oft Call-by-Reference.
Du gibst einen zufaelligen Zeigerwert an eine funktion, die dorthin schreibt.

Delphi-Quellcode:

program patch;

{$APPTYPE CONSOLE}

uses
  Windows;

type
  TRegOpenCurrentUser = function(samDesired: REGSAM; phkResult: PHKEY): LongInt; stdcall;

var
  LibModule: HMODULE;
  RegOpenCurrentUser: TRegOpenCurrentUser;
  hkResult: HKEY;
begin
  LibModule := LoadLibrary('Advapi32.dll');
  if LibModule <> 0 then // DLL wurde erfolgreich geladen
  begin
    RegOpenCurrentUser := GetProcAddress(LibModule, 'RegOpenCurrentUser');
    if Assigned(RegOpenCurrentUser) and (RegOpenCurrentUser(KEY_READ, @hkResult) = ERROR_SUCCESS) then
    begin
      //
    end;
  end;
end.

[Pseudemys Nelsoni]

nun gehts, danke dir :)

[Sprint]

Ich würde es eher so machen...

Delphi-Quellcode:

program patch;

{$APPTYPE CONSOLE}

uses
  Windows;

type
  TRegOpenCurrentUser = function(samDesired: REGSAM; var phkResult: HKEY): Integer; stdcall;

var
  RegOpenCurrentUser: TRegOpenCurrentUser;
  hkResult: HKEY;
begin

  RegOpenCurrentUser := GetProcAddress(GetModuleHandle('ADVAPI32.DLL'), 'RegOpenCurrentUser');
  if Assigned(RegOpenCurrentUser) then
    if RegOpenCurrentUser(KEY_READ, hkResult) = ERROR_SUCCESS then
    begin
      //
      RegCloseKey(hkResult);
    end;

end.

[Pseudemys Nelsoni]

hallo springt,

danke für den code, sieht gut aus, dann bräucht ich LoadLibrary/FreeLibrary also nicht, richtig?

Noch eine Frage: Was passiert wenn die dll nicht gefunden wird? Löst GetProcAddress dann einen fehler aus oder wird sie einfach nil zurückgeben?

[Sprint]

Zitat:

Zitat von Pseudemys Nelsoni

dann bräucht ich LoadLibrary/FreeLibrary also nicht, richtig?

Genau.

Zitat:

Was passiert wenn die dll nicht gefunden wird? Löst GetProcAddress dann einen fehler aus oder wird sie einfach nil zurückgeben?

GetProcAddress kann keinen Fehler auslösen. Dafür benutzt du dann Assigned und prüfst, ob GetProcAddress erfolgreich war. Die DLL wird beim Programmstart mitgeladen und befindet sich in deinem Adressraum. Darum brauchst du auch kein LoadLibrary. Hier reicht ein GetModuleHandle. AdvAPI32 ist eine wichtige Systemdatei. Ohne dieses Datei würde dein Programm auch ohne RegOpenCurrentUser nicht laufen.

[Luckie]

Zitat:

Zitat von Pseudemys Nelsoni

danke für den code, sieht gut aus, dann bräucht ich LoadLibrary/FreeLibrary also nicht, richtig?

Das geht aber nur, weil in diesem Fall die DLL schon geladen wurde.