Flexible Propertys

[Sämy]

Hallo

Ich möchte eine Komponente erstellen, in der ich in einem Property alle meine Druckernamen auflisten möchte. (Man soll schlussendlich einen auswählen können)
Wie kann ich dies tun? (Ich kann ja nicht einfach ein type erstellen in der alle Namen vorhanden sind, da die installierten Drucker von Computer zu Computer variieren)

Besten Dank

[Luciano]

Hi..

Schau mal in der OH nach TPrinter.Printers das sollte dich weiterbringen

Greets

[choose]

Hallo Sämy,

ein herzliches Willkommen bei der Delphi-PRAXiS! :)

Um das gewünschte Ergebnis zu erlangen, solltest Du einen Property-Editor anlegen und ihn zur String-Eigenschaft Deiner Komponente registrieren. Dein Problem ist vergleichbar mit dem zur Eigenschaft DatabaseName der Erben von TDBDataSet (also zB TQuery, TTable). Dort werden alle verfügbaren Datenbanken aufgeliste, obwohl es sich um eine String-Eigenschaft handelt.

Sieh Dir zur Implementierung einmal in der "BDEReg.pas" den Editor TDatabaseNameProperty und dessen Registratur

Delphi-Quellcode:

RegisterPropertyEditor(TypeInfo(string), TDBDataSet, 'DatabaseName', TDatabaseNameProperty);

genauer an.

[Stevie]

Hi Sämy,

erstmal willkommen in der DP!

Möchtest du die Auswahlliste zur Designzeit haben? Oder willst du zur Laufzeit aus der ermittelte Liste einen Auswählen können?

[Sämy]

@choose: Besten Dank für den Tip! Ich bekomme jetzt aber in der Zeile

Code:

(GetComponent(0) as TPrinterBox).getPrinterNames(List);

eine Fehlermeldung: "Undeclared Indifier: 'GetComponent'"
Diese Methode sollte aber eigentlich in der Klasse TPropertyEditor liegen, welche sich in der Unit DesignEditors befindet. Wenn ich nun diese Unit implementiere, und Compiliere, kann er die Unit gar nicht finden...


@Stevie: am besten beides :wink:

[choose]

Hey Sämy, in Deinem DP-Profil kannst Du Deine Delphi-Version angeben.
Hast Du diese Hinweise beachtet?
Vielleicht hilft Dir auch der dritte Teil von Peter Morris' Component writing weiter?

[Stevie]

Hab mal schnell was zusammengeschnippselt:

Delphi-Quellcode:

unit PrinterComponent;

interface

uses
  Windows, Messages, SysUtils, Classes, Printers, DesignEditors, DesignIntf;

type
  TPrinterNameProperty = class(TStringProperty)
  public
    function GetAttributes: TPropertyAttributes; override;
    procedure GetValueList(List: TStrings); virtual;
    procedure GetValues(Proc: TGetStrProc); override;
  end;

  TPrinterComponent = class(TComponent)
  private
    FPrinterName: string;
    function GetPrinters: TStrings;
  public
    function IsPrinterInList(const PrinterName: string): Boolean;
    property Printers: TStrings read GetPrinters;
  published
    property PrinterName: string read FPrinterName write FPrinterName;
  end;

procedure Register;

implementation

procedure Register;
begin
  RegisterComponents('Beispiele', [TPrinterComponent]);
  RegisterPropertyEditor(
   TypeInfo(string), TPrinterComponent, 'PrinterName', TPrinterNameProperty);
end;

{ TPrinterComponent }

function TPrinterComponent.GetPrinters: TStrings;
begin
  Result := Printer.Printers;
end;

{ TZStringProperty }

function TPrinterNameProperty.GetAttributes: TPropertyAttributes;
begin
  Result := [paValueList, paSortList];
end;

procedure TPrinterNameProperty.GetValueList(List: TStrings);
begin
  List.Assign((GetComponent(0) as TPrinterComponent).Printers);
end;

procedure TPrinterNameProperty.GetValues(Proc: TGetStrProc);
var
  i: Integer;
  Values: TStringList;
begin
  Values := TStringList.Create;
  try
    GetValueList(Values);
    for i := 0 to Pred(Values.Count) do
      Proc(Values[i]);
  finally
    Values.Free;
  end;
end;

function TPrinterComponent.IsPrinterInList(const PrinterName: string): Boolean;
begin
  Result := GetPrinters.IndexOf(PrinterName) > -1;
end;

end.

Denk aber dran, die PropertyEditor-Sache in ein reines DesignTime-Package zu packen, wenn du Delphi 6 und aufwärts benutzt. (Stichwort Proxies.pas ;-)) Außerdem dürfte das so noch nicht so dolle funktionieren, denn was bringt dir ein zur Designzeit festgelegter Drucker, wenn das Programm irgendwo anderes läuft, wo es den Drucker ja nicht gibt!?

[Sämy]

Besten Dank!!
Habe es jetzt hinbekommen.
Dass die Druckerliste zur Laufzeit erstellt wird, das bekomme ich schon noch irgentwie hin :wink:

[Sämy]

Hab doch noch mal eine Frage:
Wie kann ich nun ein Event auslösen, wenn dieses Property geändert wird?

[Stevie]

Zitat:

Zitat von Sämy

Hab doch noch mal eine Frage:
Wie kann ich nun ein Event auslösen, wenn dieses Property geändert wird?

Moin,

du musst dir eine Set-Methode schreiben:

Delphi-Quellcode:

procedure SetPrinterName(const Value: string);

und diese beim write der Property eintragen:

Delphi-Quellcode:

property PrinterName: string read FPrinterName write SetPrinterName;

Ebenso kann man übrigens eine Get-Methode schreiben:

Delphi-Quellcode:

function GetPrinterName: string;

Also, in die SetPrinterName schreibst du:

Delphi-Quellcode:

begin
  if Value <> FPrinterName then
  begin
    FPrinterName := Value;
    MeinEvent(...);
  end;
end;