Wie lese ich den Typen REG_MULTI_SZ aus der Registry aus?

[f.r.e.s.h.d]

Ich möchte den Wert als String auslesen, aber der Wert ist wohl Binär, obwohl er als Stringwert in der Registry zulesen ist, aber wenn ich einen doppelklick auf diesen Wert mache, dann wird mir ein Binärwert angezeigt.

[f.r.e.s.h.d]

stark habs hinbekommen... :hello:

[Gollum]

Hallo,

kannst Du uns auch mitteilen wie?

[f.r.e.s.h.d]

So, hier ist ein Beispiel....

Delphi-Quellcode:

procedure ReadREG_MULTI_SZ(const CurrentKey: HKey; const Subkey, ValueName: string;
  Strings: TStrings);
var 
  valueType: DWORD; 
  valueLen: DWORD; 
  p, buffer: PChar; 
  key: HKEY;
begin
  // Clear TStrings 
  // TStrings leeren 
  Strings.Clear; 
  // open the specified key 
  // CurrentKey Schlüssel öffnen
  if RegOpenKeyEx(CurrentKey,
                  PChar(Subkey),
                  0, KEY_READ, key) = ERROR_SUCCESS then
  begin
    // retrieve the type and data for a specified value name 
    // Den Typ und Wert des Eintrags Ermitteln. 
    SetLastError(RegQueryValueEx(key, 
                 PChar(ValueName), 
                 nil, 
                 @valueType, 
                 nil, 
                 @valueLen)); 
    if GetLastError = ERROR_SUCCESS then
      if valueType = REG_MULTI_SZ then
      begin
        GetMem(buffer, valueLen); 
        try 
          // receive the value's data (in an array). 
          // Ein Array von Null-terminierten Strings 
          // wird zurückgegeben 
          RegQueryValueEx(key, 
                          PChar(ValueName), 
                          nil, 
                          nil, 
                          PBYTE(buffer), 
                          @valueLen); 
          // Add values to stringlist 
          // Werte in String Liste einfügen 
          p := buffer; 
          while p^ <> #0 do 
          begin 
            Strings.Add(p); 
            Inc(p, lstrlen(p) + 1) 
          end 
        finally 
          FreeMem(buffer) 
        end 
      end 
      else 
        raise ERegistryException.Create('Stringlist expected/ String Liste erwartet...') 
    else 
      raise ERegistryException.Create('Cannot Read MULTI_SZ Value/'+ 
        'Kann den MULTI_SZ Wert nicht lesen...'); 
  end; 
end; 

procedure TForm1.Button1Click(Sender: TObject);
begin
  ReadREG_MULTI_SZ(*CurrentKEY*, *SubKey*, *ValueName*, *Strings*);
end;

Ich hoffe damit kommen einige weiter falls sie es auch mal brauchen! :spin: