LkJSON Array?!? Lesen und ändern

[DelTurbo]

Hi,
leider muss ich noch mal etwas Fragen. Ihr habt mir schonmal hier geholfen.

Code:

{
   "success": true,
   "data": [
      {
         "id": "3276",
         "locked": "0"
      },
      {
         "id": "3272",
         "locked": "0"
      }
      ]
}

Und zwar möchte ich gerne das Array?!? data auslesen. Leider bekomme ich das nicht hin. Wäre toll wenn mit jemand sagen könnte was ich nun wieder falsch mache.
Auch möchte ich wissen was bei success steht.
Dann kommt noch hinzu, das wenn ich z.b. die id 3272 finde, einen Datensatz einfügen möchte. Das überfordert mich total, leider.

Damit es nicht zu lang wird habe ich nur 2 Datensätze (gekürzt) hier gepostet.

Vielen Dank im voraus

[Klaus01]

.. kennst Du schon diese Seite: https://jsontodelphi.com/

Dort könntest Du eine Klasse daraus herstellen:

Delphi-Quellcode:

  TData = class
  private
    FId: string;
    FLocked: string;
  published
    property Id: string read FId write FId;
    property Locked: string read FLocked write FLocked;
  end;
  
  TRoot = class(TJsonDTO)
  private
    [JSONName('data'), JSONMarshalled(False)]
    FDataArray: TArray<TData>;
    [GenericListReflect]
    FData: TObjectList<TData>;
    FSuccess: Boolean;
    function GetData: TObjectList<TData>;
  protected
    function GetAsJson: string; override;
  published
    property Data: TObjectList<TData> read GetData;
    property Success: Boolean read FSuccess write FSuccess;
  public
    destructor Destroy; override;
  end;

Grüße
Klaus

[softtouch]

Nimm XSuperObject von hier: https://github.com/onryldz/x-superobject

Lade deine JSON Datei in die Variable json, zum Beispiel mit TFile.ReadAllText('filename')

In success hast Du dann true oder false, und in der Schleife in id und locked die jeweiligen Werte, welche Du natürlich dort weiter verarbeiten must.

Delphi-Quellcode:

procedure ParseJson;
var
  id,locked:string;
  success:boolean;
  obj:iSuperObject;
  arr:iSuperArray;
begin
  obj:=so(json);
  success:=obj.B['success'];
  arr:=obj.A['data'];
  for i:=0 to arr.Length-1 do
  begin
    id:=arr.O[i].S['id'];
    locked:=arr.O[i].S['locked'];
  end;
end;

[mytbo]

Bei Delphi 2007 dürft mORMot die bessere Wahl sein:

Delphi-Quellcode:

uses
  mormot.core.base,
  mormot.core.data,
  mormot.core.json,
  mormot.core.text,
  mormot.core.rtti,
  mormot.core.variants,
  mormot.core.os;

type
  TData = packed record
    success: Boolean;
    data: array of record
      id: Integer;
      locked: Integer;
    end;
  end;

const
  JSON = '{"success":true,"data": [{"id": "3276","locked": "0"},{"id": "3272","locked": "0"}]}';
var
  i: Integer;
  rec: TData;
begin
  if RecordLoadJson(rec, RawUtf8(JSON), TypeInfo(TData)) then
  begin
    for i := 0 to High(rec.data) do
    begin
       ...
    end;

    ShowMessage(Utf8ToString(RecordSaveJson(rec, TypeInfo(TData))));

Oder als DocVariant:

Delphi-Quellcode:

var
  doc: TDocVariantData;
begin
  if doc.InitJson(JSON) then
  begin
    with doc.A['data']^ do
    begin
      if SearchItemByProp('id', '3272', {CaseSensitive=} False) >= 0 then
        AddObject(['id', 4000, 'locked', 0]);
    end;

    ShowMessage(Utf8ToString(doc.ToJson));
  end;

Hier noch ein Artikel zum Thema im Forum.

Bis bald...
Thomas

[DelTurbo]

Hallo,
erstmal vielen vielen Dank für eure Hilfe. Ich werde nun Probieren ob ich das hinbekomme und Rückmeldung geben. Beim suchen im Netz habe ich gemerkt das ich wohl nicht der einzige bin der das nicht so richtig hinbekommt.

[DelTurbo]

So,
also mORMot läuft nicht auf 2007. Der möchte RTTI haben und andere Sachen die es bei 2007 nicht gibt.
Ich habe das Beispiel von softtouch genommen. Allerdings mit einem anderen superobjekt, eins für 2007.

Dann musste ich den Code leicht ändern und schon klappt es. Nun bekomme ich langsam auch ein Verständnis für JSON.

Hier der Code für 2007:

Delphi-Quellcode:

procedure ParseJson;
var
  id      :String;
  locked  :String;
  success :boolean;
  obj     :iSuperObject;
  arr     :TSuperArray;
  i       :Integer;
  json    :TStringList;
begin
    try
      json:=TStringList.Create;
      json.LoadFromFile('json.txt');
      obj:=so(json.Text);
      success:=obj.B['success'];
      arr:=obj.A['data'];
      for i:=0 to arr.Length-1 do begin
        id:=arr.O[i].S['id'];
        locked:=arr.O[i].S['locked'];
      end;
    finally
      json.Free;
    end;
end;

Nun versuche selber raus zu finden wie man etwas im JSON ändern kann. Ich wollte ja wenn ich z.b. eine bestimmte ID finde 2 Zeilen/Werte dazu tragen. Sollte ich das nicht hinbekommen würde ich mich nochmal melden.

Ich danke euch allen für die nette Hilfe.

[DelTurbo]

Hallo,
es tut mir wirklich leid, aber ich bekomme es nicht hin, bei id 3272 etwas zu ändern bzw. Werte hinzu zu fügen. Ich habe nichts bei Google gefunden. Eventuell suche ich auch falsch. Es wäre super wenn jemand mir verraten würde was ich machen muss.

Delphi-Quellcode:

      for i:=0 to arr.Length-1 do begin
        id:=arr.O[i].S['id'];
        if ( id='3272' ) then begin
          // ????
        end;
        locked:=arr.O[i].S['locked'];
      end;

Schonmal vielen Dank im voraus

[EDIT]
Ich habe es gefunden. Ob das aber so "sauber" ist weiß ich nicht.

Delphi-Quellcode:

procedure ParseJson;
var
  id      :String;
  locked  :String;
  success :boolean;
  obj     :iSuperObject;
  arr     :TSuperArray;
  i       :Integer;
  json    :TStringList;
  Mem     :TMemoryStream;
  x       :ISuperObject;
begin
    try
      json:=TStringList.Create;
      json.LoadFromFile('json.txt');
      obj:=so(json.Text);
      success:=obj.B['success'];
      arr:=obj.A['invoices'];
      for i:=0 to arr.Length-1 do begin
        id:=arr.O[i].S['id'];
        if ( id='3272' ) then begin
          x:=SO;
          x.S['test']:='doedel';
          arr.O[i].Merge(x);
        end;
        locked:=arr.O[i].S['locked'];
      end;
    finally
      json.Free;
    end;
    Mem:=TMemoryStream.Create;
    obj.SaveTo(Mem);
    Mem.Position:=0;
    Mem.SaveToFile('json1.txt');
    Mem.Free;

end;

[/EDIT]

[mytbo]

Zitat:

Zitat von DelTurbo (Beitrag 1531725)

also mORMot läuft nicht auf 2007. Der möchte RTTI haben und andere Sachen die es bei 2007 nicht gibt.

Code:

Synopse mORMot 2 is an Open Source Client-Server ORM SOA MVC framework for Delphi 7 up to Delphi 12 Athens and FPC 3.2/trunk, targeting Windows/Linux/BSD/MacOS for servers, and any platform for clients (including mobile or AJAX).

Es gibt einen Grund, warum ich die Uses Liste in meinem Post mit angegeben habe. Verwende es mit Delphi Version 7, 2007, XE, 10.x, 11.x und 12.

Bis bald...
Thomas

[DelTurbo]

Achso,
hatte mich schon gewundert aber nicht weiter drüber nachgedacht. Aber mein "Problem" ist ja mit superobject gelöst. Trotzdem vielen dank.