Panel im eigenen Event freigeben oder Event direkt an Parent geben

[Getox]

Mahlzeit.

Ich habe hier eine dynamische Übersicht bestehend aus einem Panel auf dem sich weitere Panels befinden (VCL). Diese Konstruktion ist mir vorgegeben und ich muss einige Fehler beheben. Das Hauptpanel ist zu Designzeit angelegt und die Child-Panels werden zur Laufzeit erzeugt.

Bei einem Doppelklick wird unter anderem diese Übersicht neu erzeugt. Also die Child-Panels werden alle freigegeben und alles wird neu generiert. Dieses Event soll aber nicht nur durch das Parent-Panel ausgelöst werden, sondern auch durch die Child-Panels. Daher ist es allen als Event zugewiesen.

Nun habe ich das Problem, dass ich beim Doppelklick auf ein Child-Panel eben dieses mit freigebe und dann im Anschluss Zugriffsverletzungen kommen, weil das Panel nach dem Event noch Dinge tun will, obwohl es schon freigegeben wurde.

Nun habe ich mehrere Ansätze die alle nicht so recht funktionieren wollen:

- Möglchkeit finden, ein Panel in seinem eigenen Event freizugeben. Es gibt aber kein Release, dass ich aufrufen könnte, damit es verzögert freigegeben wird.

- Die Child Panels so modifizieren, dass sie den Klick einfach zum Parent durchlassen. Ich darf aber keine Komponenten ableiten. Das ist mir so vorgegeben.

- Das Doppelklick-Event des Parent-Panels vom Event des Childpanels aufzurufen bringt auch nichts, weil ich mich dann in der selben Situation wie vorher befinde...

Hat jemand eine Idee, was ich tun kann?

Edit: Ich habe auch versucht mit dem Doppelklick Event des Forms zu arbeiten, aber das wird nie ausgelöst.

[DeddyH]

Nur so eine Idee und ungetestet:

Delphi-Quellcode:

const
  PM_DESTROYMESSAGE = WM_USER + 42;

type
  TYourForm = class(TForm)
  ...
  private
    procedure PMDestroyMessage(var Msg: TMessage); message PM_DESTROYMESSAGE;
  ...
  end;

In PMDestroyMessage erledigst Du dann das Freigeben und den Neuaufbau. Die Panels machen das dann nicht mehr direkt, sondern schicken einfach per PostMessage PM_DESTROYMESSAGE an das Formular. Du kannst ja mal Bescheid geben, ob das so funktioniert.

[Getox]

Keine Ahnung, was ich falsch mache, aber bei mir wird diese Funktion nie ausgelöst. Meine Erfahrungen mit den Messages sind auch sehr begrenzt, muss ich zugeben.

[DeddyH]

Kleines Beispiel (nur ein Panel und ein Button auf dem Formular):

Delphi-Quellcode:

unit Unit2;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls, Vcl.ExtCtrls;

const
  PM_HAUWECH = WM_USER + 42;

type
  TForm2 = class(TForm)
    Panel1: TPanel;
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
    procedure SendHauWech(Sender: TObject);
    procedure FormCreate(Sender: TObject);
  private
    { Private-Deklarationen }
    procedure PmHauWech(var Msg: TMessage); message PM_HAUWECH;
  public
    { Public-Deklarationen }
  end;

var
  Form2: TForm2;

implementation

{$R *.dfm}

{ TForm2 }

procedure TForm2.Button1Click(Sender: TObject);
var
  pnl: TPanel;
begin
  pnl := TPanel.Create(Panel1);
  pnl.Parent := Panel1;
  pnl.Align := alTop;
  pnl.OnDblClick := SendHauWech;
end;

procedure TForm2.FormCreate(Sender: TObject);
begin
  Panel1.OnDblClick := SendHauWech;
end;

procedure TForm2.PmHauWech(var Msg: TMessage);
var
  i: integer;
begin
  for i := Panel1.ControlCount - 1 downto 0 do
    Panel1.Controls[i].Free;
end;

procedure TForm2.SendHauWech(Sender: TObject);
begin  
  // Perform(PM_HAUWECH, 0, 0);
  PostMessage(Handle, PM_HAUWECH, 0, 0);
end;

end.

[Getox]

Also,

es wird die Aktualisierungsfunktion aufgerufen, aber die Zugriffsverletzungen erscheinen weiterhin - als würde diese Message trotzdem während des DblClick Events abgearbeitet werden.

Also ich finde das eben gelernte schon ziemlich cool... aber einen Effekt auf mein Problem hatte es augenscheinlich nicht.

[BerndS]

wäre hier nicht ein Postmessage besser?
So ist sichergestellt, dass alle bisherigen Botschaften schon bearbeitet sind.

Delphi-Quellcode:

procedure TForm2.SendHauWech(Sender: TObject);
begin
  PostMessage(Handle, PM_HAUWECH, 0, 0);
end;

[Uwe Raabe]

Zitat:

Zitat von BerndS (Beitrag 1501130)

wäre hier nicht ein Postmessage besser?

Genau! Das Perform arbeitet synchron und bringt in Bezug auf Entkopplung rein gar nichts. Steht auch so in der Doku:

Zitat:

Call Perform to bypass the Windows message queue and send a message directly to the control's window procedure.

[DeddyH]

Jaja, mea culpa, dabei hatte ich im ersten Post noch PostMessage geschrieben.

[himitsu]

Jupp, Perform ist halt ein "SendMessage"


Viele nehmen gern einen kurzen Timer.


Ansonsten nehme ich für sowas immer öfters ein ForceQueue, damit ich den anderen Code gleich vor Ort hab. (also dort, wo ich ihn eigentlich ausführen wollte)

Delphi-Quellcode:

TThread.ForceQueue(nil, procedure
  begin
    ...
  end);

Vorteil ist auch, dass Dieses ebenfalls in anderen Platformen geht, da die Message-Queue (PostMessage) ja ein Windows-Ding ist.



Bei Forms, die sich selbst freigeben sollen, kann man auch ein .Close mit caFree im OnClose nutzen (statt einem .Free).



Du könntest auch ein

Delphi-Quellcode:

Abort;

nach deinem Free (vorm Ende der Methode) versuchen.

[dummzeuch]

Zitat:

Zitat von Getox (Beitrag 1501122)

- Die Child Panels so modifizieren, dass sie den Klick einfach zum Parent durchlassen. Ich darf aber keine Komponenten ableiten. Das ist mir so vorgegeben.

Was ist der Hintergrund dieser Einschränkung? Bezieht sich das nur auf neue Komponenten, die in der IDE registriert/installiert werden müssen? (Was nervig sein kann, weil ja dann jeder diese Komponenten installieren muss.)

Oder auch auf das simple Erstellen einer abgeleiteten Klasse im Sourcecode (Interposer-Klasse)? Wenn letzteres erlaubt ist, wäre das meine bevorzugte Lösung.