System.TypeInfo Enumeration

[lxo]

Hallo,

mir ist aufgefallen das Enumeration die fest definiert wurden mit REST.Json.TJson.ObjectToJsonString einfach ignoriert werden.
Wie ich sehe liegt es daran das System.TypeInfo mit so einem Typen nicht klar kommt.

Hat da jemand eine Idee wie das trotzdem funktionieren könnte oder ist das ein Fehler von Delphi?

Delphi-Quellcode:

// TEnum = ( eOne, eTwo, eThree, eFour); // funktioniert
// TEnum = ( eOne = 0, eTwo = 1, eThree = 2, eFour = 3); // funktioniert
 TEnum = ( eOne = 1, eTwo = 2, eThree = 3, eFour = 4); // funktioniert nicht
 TClass = class
 private
   FEnum: TEnum;
 public
   property Enum: TEnum read FEnum write FEnum;
 end;

var
  Form87: TForm87;

implementation

{$R *.dfm}

procedure TForm87.FormCreate(Sender: TObject);
begin
  var lClass := TClass.Create;
  lClass.Enum := eThree;
  var lJsonString := REST.Json.TJson.ObjectToJsonString( lClass);

{ Es liegt wohl an System.TypeInfo,
 wenn man TEnum = ( eOne = 1, eTwo = 2, eThree = 3, eFour = 4); verwendet,
 kann auch gar nicht kompiliert werden }

 //  var ltest := System.TypeInfo( TEnum);
end;

[Der schöne Günther]

Ist nun mal leider so 😐

Siehe:
https://stackoverflow.com/q/1420562

[himitsu]

Genauer liegt es nicht daran, dass du die werte "deklariert" hast, sondern dass du Lücken drin hast ... dieses kann "aktuell" leider nicht in der RTTI gespeichert werden, da ein leerer Name zufällig genauso aussieht, wie das Listenende.

Und Borland/CodeGear/Embarcadero die einfach Lösung wohl nicht gefallen hat, Welche (und Andere) ihnen schon im QC/QualityPortal mehrmals vorgeschlagen wurde.


Enums mit Lücken, besitzen in der TypeInfo keine Liste der Wertnamen und daher kann die RTTI sie auch nicht auslesen/verwenden.




Stand das nicht sogar mal in der Hilfe mit drin, dass es dieses Problemchen bei "initialisierten Enums" gibt?

[lxo]

Zitat:

Zitat von himitsu (Beitrag 1498820)

Stand das nicht sogar mal in der Hilfe mit drin, dass es dieses Problemchen bei "initialisierten Enums" gibt?

Jetzt hab ich es auch gefunden :-D

https://docwiki.embarcadero.com/RADS....A4hlungstypen

Zitat:

Aufzählungskonstanten ohne festgelegten Wert haben Laufzeittypinformationen (RTTI):

Delphi-Quellcode:

type SomeEnum = (e1, e2, e3);

Zitat:

Bei Aufzählungskonstanten mit einem festen Wert ist dies nicht der Fall:

Delphi-Quellcode:

type SomeEnum = (e1 = 1, e2 = 2, e3 = 3);

[Uwe Raabe]

Solange ich die Kontrolle über die Enums habe, verwende ich dann folgende Herangehensweise:

Delphi-Quellcode:

type
  TEnum = (eOne, eTwo, eThree, eFour);
  TEnumHelper = record helper for TEnum
  public
    function GetAsInteger: Integer;
    procedure SetAsInteger(const Value: Integer);
    property AsInteger: Integer read GetAsInteger write SetAsInteger;
  end;

function TEnumHelper.GetAsInteger: Integer;
begin
  Result := Ord(Self) + 1;
end;

procedure TEnumHelper.SetAsInteger(const Value: Integer);
begin
  Self := TEnum(Value - 1);
end;

In Fällen, wo die Integer-Werte Bestandteil eines externen Records sind, kann man das dann so lösen:

Delphi-Quellcode:

type
  TMyRecord = record
  private
    { ein paar Felder }
    FEnumInt: Integer; // oder Byte, Word...
    { noch ein paar Felder }
    function GetEnum: TEnum;
    procedure SetEnum(const Value: TEnum);
  public
    property Enum: TEnum read GetEnum write SetEnum;
  end;

function TMyRecord.GetEnum: TEnum;
begin
  Result.AsInteger := FEnumInt;
end;

procedure TMyRecord.SetEnum(const Value: TEnum);
begin
  FEnumInt := Value.AsInteger;
end;

[BerndS]

@Uwe Raabe
aber warum

Delphi-Quellcode:

 Result := Ord(Self) + 1;

?

Wenn ich das mache dann so:

Delphi-Quellcode:

 Result := Ord(Self);

[Frickler]

Zitat:

Zitat von BerndS (Beitrag 1498885)

@Uwe Raabe
aber warum

Delphi-Quellcode:

 Result := Ord(Self) + 1;

?

Wenn ich das mache dann so:

Delphi-Quellcode:

 Result := Ord(Self);

Es ging ja darum, einen Enum zu haben, der nicht bei 0 anfängt, sondern bei 1.

[DeddyH]

Weil das im Ausgangspost so definiert ist?

Zitat:

Delphi-Quellcode:

TEnum = ( eOne = 1, eTwo = 2, eThree = 3, eFour = 4);

[BerndS]

:oops:
Dann ist das natürlich richtig.
Ich hatte den ersten Post nicht mehr im Kopf und das eher als allgemeine Empfehlung von Uwe verstanden.
Ich hätte das dann warscheinlich so definiert:

Delphi-Quellcode:

  TEnum = ( eNone, eOne = 1, eTwo = 2, eThree = 3, eFour = 4);

[Uwe Raabe]

Zitat:

Zitat von BerndS (Beitrag 1498891)

Ich hätte das dann warscheinlich so definiert:

Delphi-Quellcode:

  TEnum = ( eNone, eOne = 1, eTwo = 2, eThree = 3, eFour = 4);

Dann ginge ja auch gleich:

Delphi-Quellcode:

  TEnum = ( eNone, eOne, eTwo, eThree, eFour);