OnClick mit zwei Units

[julchen]

Hallo,

ich habe eine Verständnisfrage ...
Ich wollte Code auf zwei, drei Units verteilen, um einen besseren Überblick zu halten.

Ich habe das jetzt mal so ausprobiert.
Button1 soll unter unit1 laufen, Button2 unter unit2:

Code:

unit unit_unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls;

type
  TForm1 = class(TForm)
    Button2: TButton;
    Label1: TLabel;
    Label2: TLabel;
    Button1: TButton;
    procedure Button1Click(Sender: TObject);


  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;

implementation

uses unit_unit2;

{$R *.dfm}

procedure TForm1.Button1Click(Sender: TObject);
begin
    Label1.Caption := '1';
end;

end.

Code:

unit unit_unit2;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls;

  procedure Button2Click(Sender: TObject);

implementation
uses unit_unit1;

procedure Button2Click(Sender: TObject);
begin
    Form1.Label2.Caption := '2';
end;

end.

Das Problem ist OnClick.

Warum kann ich nicht den Button2 bei OnClick zuweisen?
Da steht nur Button1 drin.
Kann also nicht funktionieren.
Nur warum und was mache ich falsch?
Viele Grüsse

[jaenicke]

Das eine ist eine Prozedur (ohne Objektbezug), das andere eine Methode (mit Objektbezug, hier das Formular). Die kann man nicht zuweisen. Außerdem würde es auch keinen Sinn machen, da du so nicht fachlich sauber das Formular vom Code trennen kannst. Richtig wäre:

Delphi-Quellcode:

unit unit_unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls;

type
  TForm1 = class(TForm)
    Button2: TButton;
    Label1: TLabel;
    Label2: TLabel;
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);


  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;

implementation

uses unit_unit2;

{$R *.dfm}

procedure TForm1.Button1Click(Sender: TObject);
begin
  Label1.Caption := '1';
end;

procedure TForm1.Button2Click(Sender: TObject);
begin
  Set2InLabel(Label1);
end;

end.

Delphi-Quellcode:

unit unit_unit2;

interface

uses
  Vcl.StdCtrls;

procedure Set2InLabel(const ALabel: TLabel);

implementation

procedure Set2InLabel(const ALabel: TLabel);
begin
  ALabel.Caption := '2';
end;

end.

Die zweite Unit sollte das Formular nicht kennen, damit keine Kreuzbeziehungen entstehen. Das Beispiel macht so natürlich wenig Sinn. Konkretere Ratschläge lassen sich ohne konkretes Beispiel aber nicht geben.

[himitsu]

Es sind normale VCL-Events und die müssen immer in einer Klasse liegen.
(procedure of object ... hier genauer ein TNotifyEvent)

Normale "procedure" sind hier garnicht möglich.

Delphi-Quellcode:

unit unit_unit2;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls;

type
  TMyEvents = class {vielleicht class(TDataModule) oder so}
    procedure Button2Click(Sender: TObject);
    class procedure Button3Click(Sender: TObject);
  end;

implementation

procedure TMyEvents.Button2Click(Sender: TObject);
begin
end;

class procedure TMyEvents.Button3Click(Sender: TObject);
begin
end;

Delphi-Quellcode:

// in Form1

// über Variable/Instanz (bei einem TDataModule könnte man es sogar im FormDesigner zuweisen)
Button2.OnClick := MyEvents.Button2Click;

// über Klasse
Button3.OnClick := TMyEvents.Button3Click;

Aber von Unit2 auf "Komponenten" der TForm1 zuzugreifen und das auch noch über die globale Variable Form1.

Dafür sollte man jemandem die Hände abhacken, wenn er das macht.

TMyEvents kann man ein Feld/Variable aufnehmen und z.B. die Instanz der Form1 via Constructor (Parameter) oder Property übergeben.
Aber da nur mit sowas wie einem Form1.SetTextXyz(), anstatt direkt auf Label1 zuzugreifen.
-> Ideal: Unit2 sollte es egal sein, wie die GUI von TForm1 aufgebaut ist. (dann knallt es z.B. auch nicht, wenn man in TForm1 mal das Label1 umbenennt)