WM_COPYDATA sendet nur 62 Bytes

[Kostas]

Hallo Zusammen,

ich versuche hiermit einen String zu einer anderen Delphi App zu senden. Der String ist 120 Bytes lang.
Gesendet werden jedoch nur die ersten 62 Bytes. Hat jemand eine Idee warum?

Delphi-Quellcode:

procedure TfrPlantafel.SendData(aImage, aLink, aText: String);
var receiverHandle : THandle;
   copyDataStruct : TCopyDataStruct;
   SendMsgText: String;
begin
 receiverHandle := FindWindow(PChar('TfrSenderApp'),PChar('frSenderApp'));
 SendMsgText := Format('%s;%s;%s',[aLink, aImage, aText]);   //<< SendMsgText ist 120 Bytes lang. 

 
 
 if receiverHandle > 0 then
 begin
   copyDataStruct.dwData := Ord(ntSendWhatsAppMsg);
   copyDataStruct.cbData := 1 + Length(SendMsgText);
   copyDataStruct.lpData :=  PChar(SendMsgText);

   SendMessage(receiverHandle, WM_COPYDATA, LPARAM(Handle), WPARAM(@copyDataStruct)) ;
 end else
 begin
   bsm('Die Sender Anwendung läuft nicht.');
 end;
end;

Gruß Kostas

[himitsu]

Zitat:

Delphi-Quellcode:

copyDataStruct.cbData := 1 + Length(SendMsgText);

Wie groß ist seit D2009 ein Char (WideChar) eines String (UnicodeString) ?


Und gerade bei solchen prozessübergreifenden Daten verwendet man NIEMALS "dynamische" DatenFormate (maximal dann, wenn man auch das Format mit übergibt und der Andere das dann auch beachtet)

Also z.B. explizit WideChar (mit PWideChar und WideString bzw. UnicodeString).

[Kostas]

Danke für die Antwort.

vermutlich habe ich dich nicht richtig verstanden, ich habe String durch WideString ersetzt und PChar durch PWideChar.
Das hat noch nichts gebracht. Oder meintest du ich soll nicht String sondern ein Array of WideChar verwenden?

Delphi-Quellcode:

procedure TfrPlantafel.SendData(aImage, aLink, aText: String);
var receiverHandle : THandle;
   copyDataStruct : TCopyDataStruct;
   SendMsgText: WideString;
begin
 receiverHandle := FindWindow(PChar('TfrSenderApp'),PChar('frSenderApp'));
 SendMsgText := Format('%s;%s;%s',[aLink, aImage, aText]); //<< SendMsgText ist 120 Bytes lang.

 
 
 if receiverHandle > 0 then
 begin
   copyDataStruct.dwData := Ord(ntSendWhatsAppMsg);
   copyDataStruct.cbData := 1 + Length(SendMsgText);
   copyDataStruct.lpData := PWideChar(SendMsgText);

   SendMessage(receiverHandle, WM_COPYDATA, LPARAM(Handle), WPARAM(@copyDataStruct)) ;
 end else
 begin
   bsm('Die Sender Anwendung läuft nicht.');
 end;
end;

[DeddyH]

cbData bezeichnet die Byte-Größe.

Delphi-Quellcode:

copyDataStruct.cbData := 1 + Length(SendMsgText * SizeOf(Char));

[edit]Es müsste wohl eher heißen

Delphi-Quellcode:

copyDataStruct.cbData := (1 + Length(SendMsgText)) * SizeOf(Char);

[/edit]

[himitsu]

Wenn das als PChar/PWideChar übertragen wird, dann gehört die abschließende #0 mit dazu
und die ist auch 2 Byte groß.

Delphi-Quellcode:

copyDataStruct.cbData := (Length(SendMsgText) + 1) * SizeOf(WideChar);
copyDataStruct.lpData := PWideChar(SendMsgText);

[Kostas]

Herzlichen Dank, genau so funktioniert es.
Jetzt ist auch klar was du meintest. :-)