Dateien in einem Ordner löschen

[kagi3624]

hallo, mit folgender Funkion möchte ich alle Dateien in einem Ordner löschen, die selbst keine Ordner sind.

Code:

SearchPattern := IncludeTrailingPathDelimiter(aPath) + '*.*';
  if FindFirst(SearchPattern, faAnyFile, Rec) = 0 then begin
    try
      repeat
        if Rec.Attr and faDirectory = 0 then begin

        delete(aPath+Rec.Name);

        end;
      until (FindNext(Rec) <> 0);
    finally
      SysUtils.FindClose(Rec);
    end;

  end;

Jetzt werden nicht alle Daten gelöscht und bleiben welche über, ich denke es ist deshalb, weil ich die Datei lösche bevor ich auf next springe. Ich habe es so versucht zu lösen, dass ich mir den Dateinamen merke und dann erst beim nächsten Durchlauf sie lösche. Aber so bleibt dann immer eine Datei am Ende übrig. Wie löse ich am besten, dass auch die letzte Datei gelöscht wird?

[Amateurprofi]

Delphi-Quellcode:

PROCEDURE DeleteFilesInDirectory(const Path:String);
var I,R:Integer; SR:TSearchRec;  List:TStringList;
begin
   List:=TStringList.Create;
   R:=FindFirst(Path+'\*.*', faAnyFile,SR);
   while R=0 do begin
      if (SR.Attr and faDirectory<>faDirectory) then List.Add(Path+'\'+SR.Name);
      R:=FindNext(SR);
   end;
   FindClose(SR);
   for I:=0 to List.Count-1 do DeleteFile(List[I]);
   List.Free;
end;

[himitsu]

Delete löscht Dateien?

Und noch einen Blick auf ein paar, inzwischen schon einige Jahre alte, Funktionen.

Delphi-Quellcode:

for S in TDirectory.GetFiles(Path) do  // GetFiles liest zuerst in ein String-Array und das wird am Ende abgearbeitet
  TFile.Delete(S);

[TurboMagic]

TDirectory etc. geht aber nicht wenn die Delphi Version des tragenden wirklich Delphi 6 ist. Der sollte sich Mal Gedanken machen ob ein Update drin ist. Seit D6 gab's so viele schöne neue Erweiterungen...

[himitsu]

Jo, es heißt ja nicht dass es so bleiben muß. :zwinker:
Wobei ich dachte IncludeTrailingPathDelimiter wurde auch erst nach D6 erfunden, so zu Zeiten, als die neue IDE auftauchte oder die mobilen Platformen dazu kamen, aber vielleicht kam es ja doch schon vom Kylix. (IncludeTrailingBackslash)

Ansonsten kann man sich ja auch Anrekungen holen.
z.B. das Suchen der Dateien in eine Funktion auslagern, und dann ebenfalls das Ergebnis nutzen.

[Dalai]

[OT]

Zitat:

Zitat von himitsu (Beitrag 1469564)

Wobei ich dachte IncludeTrailingPathDelimiter wurde auch erst nach D6 erfunden, so zu Zeiten, als die neue IDE auftauchte oder die mobilen Platformen dazu kamen, aber vielleicht kam es ja doch schon vom Kylix. (IncludeTrailingBackslash)

Ja, das kam schon mit Delphi 6 und Kylix auf.
[/OT]

Grüße
Dalai

[kagi3624]

Zitat:

Zitat von himitsu (Beitrag 1469559)

Delete löscht Dateien?

Und noch einen Blick auf ein paar, inzwischen schon einige Jahre alte, Funktionen.

Delphi-Quellcode:

for S in TDirectory.GetFiles(Path) do  // GetFiles liest zuerst in ein String-Array und das wird am Ende abgearbeitet
  TFile.Delete(S);

Nein, natürlich nicht :stupid:

[haentschman]

Moin...:P

Möööp... try/finally (List) ist hoffentlich kein Femdwort. :zwinker:

[kagi3624]

Zitat:

Zitat von haentschman (Beitrag 1469571)

Moin...:P

Möööp... try/finally (List) ist hoffentlich kein Femdwort. :zwinker:

Ne, ich hab alles durch 14 tausend Dateien von zwei Rechnern löscht er ohne Probleme. Wenn ich das Programm aber auf einem dritten Rechner starte (durch automatische Dienste) dann bleibt er immer bei der hälfte oder so hängen. Allerdings zum Schluß, wenn etwa nur 200 dateien sind, dann löscht er alle. Also ich kann es mir nicht erklären, an meinem Code liegt es nicht...wobei...ich habe Delphi6

[haentschman]

Moin...:P

Zitat:

List:=TStringList.Create;

...war darauf bezogen. Ich weis ja nicht, welche QT Version bei dir aktuell ist. :wink:

Delphi-Quellcode:

procedure DeleteFilesInDirectory(const Path: string);
var 
  I: Integer;
  R: Integer;
  SR: TSearchRec; 
  List: TStringList;
begin
   List := TStringList.Create;
   try
     R := FindFirst(Path + '\*.*', faAnyFile, SR);
     while R = 0 do 
     begin
       if (SR.Attr and faDirectory <> faDirectory) then 
       begin
         List.Add(Path + '\' + SR.Name);
       end;
       R := FindNext(SR);
     end;
     FindClose(SR);

     for I := 0 to List.Count - 1 do 
     begin
       DeleteFile(List[I]);
     end;
   finally
     List.Free;
   end;
end;