VST Node mit Child Nodes hinzufügen (InitChildren)

[DieDolly]

Ich arbeite gerade mit einer VirtualStringTree und möchte gerne Nodes mit Childnodes hinzufügen.

Code:

node
  subnode
  subnode
  subnode
node
  subnode
  subnode
  subnode

Wie macht man das?

Ich initialisere Nodes so

Delphi-Quellcode:

procedure TMainForm.VSTInitNode(Sender: TBaseVirtualTree; ParentNode, Node: PVirtualNode; var InitialStates: TVirtualNodeInitStates);
begin
 Node.SetData<TNodeData>(NodeList[Node.Index]);
end;

Mein VSTInitChildren sieht so aus

Delphi-Quellcode:

procedure TMainForm.VSTInitChildren(Sender: TBaseVirtualTree; Node: PVirtualNode; var ChildCount: Cardinal);
begin
 ChildCount := 1;
end;

Damit bekomme ich aber so ein Resultat

Code:

A
  B
    C
      D

So zeige ich Texte an

Delphi-Quellcode:

procedure TMainForm.VSTGetText(Sender: TBaseVirtualTree; Node: PVirtualNode; Column: TColumnIndex; TextType: TVSTTextType; var CellText: string);
var
 NodeData: TNodeData;
begin
 NodeData := Node.GetData<TNodeData>;
 if not Assigned(NodeData) then
  Exit;

 case Sender.GetNodeLevel(Node) of
  0:
   CellText := NodeData.A;
  1:
   CellText := NodeData.B;
  2:
   CellText := NodeData.C;
  3:
   CellText := NodeData.D;
 end;
end;

Daten für einen neuen Node füge ich meiner Klassenliste so hinzu. Aber wie bekomme ich Childnodes dazu und auch noch angezeigt?

Delphi-Quellcode:

NodeData := TNodeData.Create;
NodeData.A := 'A';
NodeData.B := 'B';
NodeData.C := 'C';
NodeData.D := 'D';

NodeList.Add(NodeData);
VST.RootNodeCount := NodeList.Count;

[Wishmaster]

versuche es mal mit, ich hoffe es hilft.

Delphi-Quellcode:

(* Init Tree  DataSize *)

procedure TForm.FormCreate(Sender: TObject);
begin
  VST.NodeDataSize:= SizeOf(TData); // Ich initialisere Nodes so ;-)

erster eintrag/node

Delphi-Quellcode:

 Node:= VST.AddChild(Nil);
 Data:= VST.GetNodeData(Node);
 Data^.Text:= 'Test'

subnode

Delphi-Quellcode:

  Node:= VST.FocusedNode;
 if Assigned(Node) then
  begin
    Node:= VST.AddChild(Node);
    Data:= VST.GetNodeData(Node);
    Data^.Text:= 'Test'
    Data^.Caption:= 'Test'
  end;

schaue dir auch mal an die folgenden, besonders wenn du daten in einem loop verarbeiten willst.
GetFirst, GetLast, NextSibling,
FirstChild, LastChild
GetFirstLevel,

[DieDolly]

Danke für die Hilfe aber VST.AddChild(Nil); verwende ich nicht, da ich Daten von Design trenne.

[Wishmaster]

was genau versuchst du zu machen, kannst du mir eventuell ne demo schicken?

[DieDolly]

Ich möchte ganz normal Childnodes unter einem Hauptnode anzeigen (mehrere im Level 1 unter dem Hauptnode mit Level 0).

[jus]

Hallo,

ich hatte dazu auch quasi die selbe Frage in einem anderen äteren Beitrag "https://www.delphipraxis.net/1430423-post36.html" gestellt. Ich hatte daraus interpretiert, dass man bei mehreren Ebenen AddChild dazu verwenden muß. Aktuell versuche ich es über den TreeViewPresenter von DSharp die BL von GUI zu trennen.
Aber wenn es direkt mit VSTInitChildren auch funktioniert wäre ich auch sehr daran interessiert. :-D

lg,
jus

[Aviator]

Natürlich funktioniert das.

Du musst eben nur in Abhängigkeit vom

Delphi-Quellcode:

NodeLevel

oder eben von deiner Liste oder was auch immer du als Container für die Speicherung deiner Daten verwendest, den

Delphi-Quellcode:

ChildCount

setzen.

Delphi-Quellcode:

InitNode()

wird dann automatisch für die Nodes aufgerufen. Um einer Node initial mitzuteilen das sie ChildNodes hat (welche aber erst erstellt werden wenn

Delphi-Quellcode:

InitChildren

aufgerufen wird), solltest du im InitNode Event dem Referenzparameter

Delphi-Quellcode:

InitialStates

Delphi-Quellcode:

ivsHasChildren

zuweisen.

[jus]

@Aviator: ok, vielen Dank für den Hinweis! :thumb:

@DieDolly: ich habe daraus mal ein Beispielprojekt gebastelt, ist sicherlich noch verbesserungswürdig :oops: . Ich habe die Klassendefinition quasi von einem alten Beitrag von Stevie übernommen. :wink:

Delphi-Quellcode:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ContNrs, VirtualTrees;

type
  TNamedItem = class
  private
    fName: string;
    fItems: TObjectList;
  public
    constructor Create(const name: string);
    property Items: TObjectList read fItems;
    property Name: string read fName write fName;
  end;

  TNodeData = TNamedItem;
  PNodeData = ^TNodeData;

  TForm1 = class(TForm)
    VirtualStringTree1: TVirtualStringTree;
    procedure FormCreate(Sender: TObject);
    procedure VirtualStringTree1InitNode(Sender: TBaseVirtualTree; ParentNode,
      Node: PVirtualNode; var InitialStates: TVirtualNodeInitStates);
    procedure VirtualStringTree1InitChildren(Sender: TBaseVirtualTree;
      Node: PVirtualNode; var ChildCount: Cardinal);
    procedure VirtualStringTree1GetText(Sender: TBaseVirtualTree;
      Node: PVirtualNode; Column: TColumnIndex; TextType: TVSTTextType;
      var CellText: WideString);
  private
    { Private-Deklarationen }
    FVstRootItemList: TObjectList;
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.FormCreate(Sender: TObject);
var
  folder1 : TNamedItem;
  folder1_1, folder1_2, folder1_3 : TNamedItem;
  folder1_1_1 : TNamedItem;
begin
  FVstRootItemList := TObjectList.Create;
  folder1 := TNamedItem.Create('Folder 1');
  folder1_1 := TNamedItem.Create('Folder 1.1');
  folder1_1_1 := TNamedItem.Create('Folder 1.1.1');
  folder1_1.Items.Add(folder1_1_1);
  folder1.Items.Add(folder1_1);
  FVstRootItemList.Add(folder1);

  folder1 := TNamedItem.Create('node');
  folder1_1 := TNamedItem.Create('subnode');
  folder1_2 := TNamedItem.Create('subnode');
  folder1_3 := TNamedItem.Create('subnode');
  folder1.Items.Add(folder1_1);
  folder1.Items.Add(folder1_2);
  folder1.Items.Add(folder1_3);
  FVstRootItemList.Add(folder1);

  folder1 := TNamedItem.Create('node');
  folder1_1 := TNamedItem.Create('subnode');
  folder1_2 := TNamedItem.Create('subnode');
  folder1_3 := TNamedItem.Create('subnode');
  folder1.Items.Add(folder1_1);
  folder1.Items.Add(folder1_2);
  folder1.Items.Add(folder1_3);
  FVstRootItemList.Add(folder1);

  VirtualStringTree1.NodeDataSize := SizeOf(TNodeData);
  VirtualStringTree1.RootNodeCount := FVstRootItemList.Count;
end;

procedure TForm1.VirtualStringTree1GetText(Sender: TBaseVirtualTree;
  Node: PVirtualNode; Column: TColumnIndex; TextType: TVSTTextType;
  var CellText: WideString);
var
  data: PNodeData;
begin
  data:= Sender.GetNodeData(Node);
  if not assigned(data^) then exit;
  case Column of
    0: CellText := data^.Name;
  end;
end;

procedure TForm1.VirtualStringTree1InitChildren(Sender: TBaseVirtualTree;
  Node: PVirtualNode; var ChildCount: Cardinal);
var
  Data: PNodeData;
begin
  Data := Sender.GetNodeData(Node);
  ChildCount := Data^.items.Count;
end;

procedure TForm1.VirtualStringTree1InitNode(Sender: TBaseVirtualTree;
  ParentNode, Node: PVirtualNode; var InitialStates: TVirtualNodeInitStates);
var
  data: PNodeData;
  ParentData: PNodeData;
begin
  data := Sender.GetNodeData(Node);
  if VirtualStringTree1.GetNodeLevel(Node) = 0 then
    data^ := TNamedItem(FVstRootItemList[Node.Index])
  else
  begin
    ParentData := Sender.GetNodeData(ParentNode);
    data^ := TNamedItem(ParentData.items[Node.Index]);
  end;
  if data^.Items.Count > 0 then InitialStates := InitialStates + [ivsHasChildren];
end;

{ TNamedItem }
constructor TNamedItem.Create(const name: string);
begin
  fName := name;
  fItems := TObjectList.Create;
end;

end.

Im Anhang ist das ganze Projekt für Delphi 2007.

lg,
jus

[Aviator]

Das sieht doch schon mal gar nicht so schlecht aus. Die vielen Variablen im FormCreate hättest du natürlich nicht gebraucht, aber für diesen Test ist es evtl. auch gar nicht schlecht.

[SvB]

Guten Morgen Community,

ich habe einige Zeit nichts mit VirtualTreeView gemacht und hab nach genau so einem Beispiel gesucht, um eine neue Anforderung bei einem Projekt umsetzen zu können.
Da ich mit Generics arbeite, habe ich den Beispielcode zum besseren Verständnis angepasst und stelle ihn hier für euch bereit.
Ich habe hier mit Delphi 10.4 gearbeitet.

Code:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms, System.Generics.Collections,
  Dialogs, ContNrs, VirtualTrees;

type
  TNamedItem = class
  private
    fName: string;
    fItems: TObjectList<TNamedItem>;
  public
    constructor Create(const name: string);
    property Items: TObjectList<TNamedItem> read fItems;
    property Name: string read fName write fName;
  end;

  TForm1 = class(TForm)
    VirtualStringTree1: TVirtualStringTree;
    procedure FormCreate(Sender: TObject);
    procedure VirtualStringTree1InitNode(Sender: TBaseVirtualTree; ParentNode, Node: PVirtualNode; var InitialStates: TVirtualNodeInitStates);
    procedure VirtualStringTree1InitChildren(Sender: TBaseVirtualTree; Node: PVirtualNode; var ChildCount: Cardinal);
    procedure VirtualStringTree1GetText(Sender: TBaseVirtualTree; Node: PVirtualNode; Column: TColumnIndex; TextType: TVSTTextType; var CellText: string);
  private
    { Private-Deklarationen }
    FVstRootItemList: TObjectList<TNamedItem>;
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.FormCreate(Sender: TObject);
var
  folder1: TNamedItem;
  folder1_1, folder1_2, folder1_3: TNamedItem;
  folder1_1_1: TNamedItem;
begin
  FVstRootItemList := TObjectList<TNamedItem>.Create;
  folder1 := TNamedItem.Create('Folder 1');
  folder1_1 := TNamedItem.Create('Folder 1.1');
  folder1_1_1 := TNamedItem.Create('Folder 1.1.1');
  folder1_1.Items.Add(folder1_1_1);
  folder1.Items.Add(folder1_1);
  FVstRootItemList.Add(folder1);

  folder1 := TNamedItem.Create('node');
  folder1_1 := TNamedItem.Create('subnode');
  folder1_2 := TNamedItem.Create('subnode');
  folder1_3 := TNamedItem.Create('subnode');
  folder1.Items.Add(folder1_1);
  folder1.Items.Add(folder1_2);
  folder1.Items.Add(folder1_3);
  FVstRootItemList.Add(folder1);

  folder1 := TNamedItem.Create('node');
  folder1_1 := TNamedItem.Create('subnode');
  folder1_2 := TNamedItem.Create('subnode');
  folder1_3 := TNamedItem.Create('subnode');
  folder1.Items.Add(folder1_1);
  folder1.Items.Add(folder1_2);
  folder1.Items.Add(folder1_3);
  FVstRootItemList.Add(folder1);

  VirtualStringTree1.NodeDataSize := SizeOf(TNamedItem);
  VirtualStringTree1.RootNodeCount := FVstRootItemList.Count;
end;

procedure TForm1.VirtualStringTree1GetText(Sender: TBaseVirtualTree; Node: PVirtualNode; Column: TColumnIndex; TextType: TVSTTextType; var CellText: string);
var
  NamedItem: TNamedItem;
begin
  NamedItem := Sender.GetNodeData<TNamedItem>(Node);
  if not assigned(NamedItem) then
    exit;
  case Column of
    0:
      CellText := NamedItem.name;
  end;
end;

procedure TForm1.VirtualStringTree1InitChildren(Sender: TBaseVirtualTree; Node: PVirtualNode; var ChildCount: Cardinal);
var
  NamedItem: TNamedItem;
begin
  NamedItem := Sender.GetNodeData<TNamedItem>(Node);
  ChildCount := NamedItem.Items.Count;
end;

procedure TForm1.VirtualStringTree1InitNode(Sender: TBaseVirtualTree; ParentNode, Node: PVirtualNode; var InitialStates: TVirtualNodeInitStates);
var
  NamedItem: TNamedItem;
begin
  if VirtualStringTree1.GetNodeLevel(Node) = 0 then begin
    NamedItem := FVstRootItemList[Node.Index];
    Node.SetData<TNamedItem>(NamedItem)
  end
  else
  begin
    NamedItem := Sender.GetNodeData<TNamedItem>(ParentNode).Items[Node.Index];
    Node.SetData<TNamedItem>(NamedItem);
  end;
  if NamedItem.Items.Count > 0 then
    InitialStates := InitialStates + [ivsHasChildren, ivsExpanded];
end;

{ TNamedItem }
constructor TNamedItem.Create(const name: string);
begin
  fName := name;
  fItems := TObjectList<TNamedItem>.Create;
end;

end.