Email versenden

[MarcRB75]

Hallo,
ich versuche seit Tagen, dass ich einen Text im Memo per Mail versende.
Eine Mail, mit Anhang zu versenden, wäre super, aber daran denke ich jetzt jaa üüüüberhaupt noch nicht.

Einmal hatte ich Probleme mit der Gültigkeit des SSL und dann wieder konnte die SSL-Bibliothek nicht geladen werden.
Ich kenne mich jetzt überhaupt nicht mehr aus.

Ich hatte das letzte openssl heruntergeladen und auch installiert. Da gibt es zwei Download-Größen.

Dann wollte ich die Datei ssleay32.dll und libeay32.dll kopieren und in den Pfad meiner Programm-Exe kopieren, aber ich finde diese nicht bzw. ich weiß nicht, woher die kommt.

Vielleicht geht das ja auch generell nicht. Habe Delphi XE2, Windows7 mit 64-bit.
... irgendwie bringt mich das alles recht durcheinander :pale:

Wie gesagt, seit Tagen beschäftige ich mich mit der Thematik.
Aber ich komme da nicht weiter und mit Sicherheit liegt es auch daran, dass ich mich mit den INDY-Komponenten und Zusammenhänge gar nicht auskenne.

Dann habe ich hier natürlich einige Ansätze gelesen, wie und welche Komponenten zum Einsatz kommen. Dann geht es bei manchen, dann mit Fehlern ... gibt es ein Tutorial oder einen Code, der mich erkännen lässt, wie, was man braucht, was installiert werden muss, wie das überhaupt funktioniert usw. ...

Bitte: kann mir jemand da weiterhelfen. Ich kenne mich da einfach nicht mehr aus.

[DieDolly]

Versuch mal damit
https://www.delphipraxis.net/112798-...dy-senden.html

OpenSSL gibt es hier
https://indy.fulgan.com/SSL/

Du brauchst aber einen SMTP-Server, soviel ist klar.

JFSendMail finde ich komischerweise nirgendwo. Deswegen, hier ist sie

Delphi-Quellcode:

unit JFSendMail;

interface

uses
 Vcl.ComCtrls, System.SysUtils, System.Classes, System.IOUtils, IdSmtp, IdMessage, IdAttachmentFile, IdText, IdExplicitTLSClientServerBase, IdSSLOpenSSL, IdBaseComponent, IdIOHandler,
 IdIOHandlerSocket, IdIOHandlerStack, IdSSL;

type
 TLoginType = (ltNone, ltLogin);

 TMailPriority = (pHighest, pHigh, pNormal, pLow, pLowest);

 TJFSendMail = class
 private
  fLibeay32, fSSLeay32: string;
  fSmtp: TIdSMTP;
  fIdSSLIOHandler: TIdSSLIOHandlerSocketOpenSSL;
  fMsg: TIdMessage;
  fAttachmentList: TStringList;
  fiEMailSize: Integer;
  bUseSSL: Boolean;
  iTLSMode: Integer;

  procedure SetLibeay32(const aValue: string);
  procedure SetSSLeay32(const aValue: string);

  procedure SetHost(const aValue: string);
  procedure SetPort(const aValue: Word);
  procedure SetUserName(const aValue: string);
  procedure SetPwd(const aValue: string);
  procedure SetLoginType(const aValue: TLoginType);
  procedure SetMailAgent(const aValue: string);
  procedure SetReceiver(const aValue: string);
  procedure SetSender(const aValue: string);
  procedure SetSubject(const aValue: string);
  procedure SetPriority(const aValue: TMailPriority);
  procedure SetReturnReciept(const aValue: Boolean);
  procedure SetBody(aValue: TStrings);
  procedure SetUseSSL(const aValue: Boolean);
  procedure SetTLSMode(const aValue: Integer);

  function getLibeay32: string;
  function getSSLeay32: string;

  function getHost: string;
  function getPort: Word;
  function getUserName: string;
  function getPwd: string;
  function getLoginType: TLoginType;
  function getMailAgent: string;
  function getReceiver: string;
  function getSender: string;
  function getSubject: string;
  function getPriority: TMailPriority;
  function getReturnReciept: Boolean;
  function getBody: TStrings;
  function getUseSSL: Boolean;
  function getTLSMode: Integer;

  procedure setEmailSize(iEMailSize: Integer);
 protected
 public
  constructor Create;
  destructor Destroy; override;

  property Libeay32: string read getLibeay32 write SetLibeay32;
  property SSLeay32: string read getSSLeay32 write SetSSLeay32;

  property Host: string read getHost write SetHost;
  property Port: Word read getPort write SetPort;
  property Username: string read getUserName write SetUserName;
  property Password: string read getPwd write SetPwd;
  property LoginType: TLoginType read getLoginType write SetLoginType;
  property MailAgent: string read getMailAgent write SetMailAgent;

  property Receiver: string read getReceiver write SetReceiver;
  property Sender: string read getSender write SetSender;
  property Subject: string read getSubject write SetSubject;
  property Priority: TMailPriority read getPriority write SetPriority;
  property ReturnReciept: Boolean read getReturnReciept write SetReturnReciept;
  property Body: TStrings read getBody write SetBody;
  property Attachments: TStringList read fAttachmentList;
  property UseSSL: Boolean read getUseSSL write SetUseSSL;
  property TLSMode: Integer read getTLSMode write SetTLSMode;

  function SendMail: Boolean;
 end;

implementation

function _MIMEConvert(s: string): string;
var
 i: Integer;
begin
 Result := '';
 for i := 1 to Length(s) do
  begin
   if s[i] = '€' then
    begin
     Result := Result + '?=ISO-8859-15?Q?=A4?='
    end
   else if Ord(s[i]) > $99 then
    Result := Result + '=?ISO-8859-1?Q?=' + Format('%x', [Ord(s[i])]) + '?='
   else
    Result := Result + s[i];
  end;
end;

constructor TJFSendMail.Create;
begin
 fSmtp := TIdSMTP.Create(nil);
 fIdSSLIOHandler := TIdSSLIOHandlerSocketOpenSSL.Create(nil);
 fMsg := TIdMessage.Create(nil);
 fAttachmentList := TStringList.Create;
end;

destructor TJFSendMail.Destroy;
begin
 FreeAndNil(fSmtp);
 FreeAndNil(fIdSSLIOHandler);
 FreeAndNil(fMsg);
 FreeAndNil(fAttachmentList);
 inherited;
end;

function TJFSendMail.getLoginType: TLoginType;
begin
 if fSmtp.AuthType = satNone then
  Result := ltNone
 else
  Result := ltLogin;
end;

function TJFSendMail.getHost: string;
begin
 Result := fSmtp.Host;
end;

function TJFSendMail.getPort: Word;
begin
 Result := fSmtp.Port;
end;

function TJFSendMail.getPwd: string;
begin
 Result := fSmtp.Password;
end;

function TJFSendMail.getUserName: string;
begin
 Result := fSmtp.Username;
end;

procedure TJFSendMail.SetLoginType(const aValue: TLoginType);
begin
 if aValue = ltNone then
  fSmtp.AuthType := satNone
 else
  fSmtp.AuthType := satDefault;
end;

procedure TJFSendMail.SetHost(const aValue: string);
begin
 if aValue <> fSmtp.Host then
  fSmtp.Host := aValue;
end;

procedure TJFSendMail.SetPort(const aValue: Word);
begin
 if aValue <> fSmtp.Port then
  fSmtp.Port := aValue;
end;

procedure TJFSendMail.SetPwd(const aValue: string);
begin
 if aValue <> fSmtp.Password then
  fSmtp.Password := aValue;
end;

procedure TJFSendMail.SetUserName(const aValue: string);
begin
 if aValue <> fSmtp.Username then
  fSmtp.Username := aValue;
end;

function TJFSendMail.getMailAgent: string;
begin
 Result := fSmtp.MailAgent;
end;

procedure TJFSendMail.SetMailAgent(const aValue: string);
begin
 if aValue <> fSmtp.MailAgent then
  fSmtp.MailAgent := aValue;
end;

function TJFSendMail.getBody: TStrings;
begin
 Result := fMsg.Body;
end;

function TJFSendMail.getUseSSL;
begin
 Result := bUseSSL;
end;

function TJFSendMail.getTLSMode;
begin
 Result := iTLSMode;
end;

function TJFSendMail.getPriority: TMailPriority;
var
 iTmp: Byte;
begin
 iTmp := Ord(fMsg.Priority);
 Result := TMailPriority(iTmp);
end;

function TJFSendMail.getReceiver: string;
begin
 Result := fMsg.Recipients.EMailAddresses;
end;

function TJFSendMail.getReturnReciept: Boolean;
begin
 Result := fMsg.ReceiptRecipient.Text <> '';
end;

function TJFSendMail.getSender: string;
begin
 Result := fMsg.From.Text;
end;

function TJFSendMail.getSSLeay32: string;
begin
 Result := fSSLeay32;
end;

function TJFSendMail.getLibeay32: string;
begin
 Result := fLibeay32;
end;

function TJFSendMail.getSubject: string;
begin
 Result := fMsg.Subject;
end;

procedure TJFSendMail.SetBody(aValue: TStrings);
begin
 fMsg.Body.Assign(aValue);
end;

procedure TJFSendMail.SetUseSSL(const aValue: Boolean);
begin
 bUseSSL := aValue;
end;

procedure TJFSendMail.SetTLSMode(const aValue: Integer);
begin
 iTLSMode := aValue;
end;

procedure TJFSendMail.SetPriority(const aValue: TMailPriority);
var
 iTmp: Byte;
begin
 iTmp := Ord(aValue);
 fMsg.Priority := TIdMessagePriority(iTmp);
end;

procedure TJFSendMail.SetReceiver(const aValue: string);
begin
 fMsg.Recipients.EMailAddresses := aValue;
end;

procedure TJFSendMail.SetReturnReciept(const aValue: Boolean);
begin
 if aValue then
  fMsg.ReceiptRecipient.Text := fMsg.From.Text
 else
  fMsg.ReceiptRecipient.Text := '';
end;

procedure TJFSendMail.SetSender(const aValue: string);
begin
 fMsg.From.Text := aValue;
end;

procedure TJFSendMail.SetSSLeay32(const aValue: string);
begin
 fSSLeay32 := aValue;
end;

procedure TJFSendMail.SetLibeay32(const aValue: string);
begin
 fLibeay32 := aValue;
end;

procedure TJFSendMail.SetSubject(const aValue: string);
begin
 fMsg.Subject := aValue;
end;

procedure TJFSendMail.setEmailSize(iEMailSize: Integer);
begin
 fiEMailSize := iEMailSize;
end;

function TJFSendMail.SendMail: Boolean;
var
 i: Integer;
begin
 Result := False;

 try
  fMsg.Subject := _MIMEConvert(fMsg.Subject);

  if fAttachmentList.Count > 0 then
   begin
    for i := 0 to fAttachmentList.Count - 1 do
     begin
      if FileExists(fAttachmentList[i]) then
       begin
        TIdAttachmentFile.Create(fMsg.MessageParts, fAttachmentList[i]);

        TIdText.Create(fMsg.MessageParts).ContentType := 'text/html';
        TIdText.Create(fMsg.MessageParts).CharSet := 'ISO-8859-1';

        if i = 0 then
         TIdText.Create(fMsg.MessageParts).Body.Add(fMsg.Body.Text);
       end;
     end;
   end
  else
   begin
    fMsg.ContentType := 'text/html';
    fMsg.CharSet := 'ISO-8859-1';
   end;

  setEmailSize(Length(fMsg.Body.Text));
  fSmtp.ConnectTimeout := 10000;

  if getUseSSL and FileExists(fLibeay32) and FileExists(fSSLeay32) then
   begin
    fSmtp.IOHandler := fIdSSLIOHandler;
    fSmtp.UseTLS := TIdUseTLS(getTLSMode);
    {*
    0 utNoTLSSupport
    1 utUseImplicitTLS
    2 utUseRequireTLS
    3 utUseExplicitTLS
    *}
   end;

  try
   fSmtp.Connect;

   if fSmtp.Connected then
    begin
     try
      fSmtp.Send(fMsg);
      Result := True;
     finally
      fSmtp.Disconnect;
     end;
    end;
  except
   Result := False;
  end;
 except
  Result := False;
 end;
end;

end.

[MarcRB75]

Dankeschön. Dann versuche ich das mal wieder.
Nochmal Danke fürs helfen.

[DieDolly]

Nur als Hinweis noch. Lege die SMTP-Logindaten nicht im Programm selber ab. Das ist, als ob du deine Haustüre offen lässt.

[MarcRB75]

Danke für den Hinweis.
Werde die Daten in einer Datenbank ablegen.
Bin ja dann mal gespannt, ob das dann so funktioniert.
Hab mir mal alles runtergeladen, bei dem ich denke, dass ich das installieren muss.

Eine Frage noch:
Habe gelesen, dass man die openssl schnellstmöglich auf 1.1.1 umstellen bzw. updaten soll.
Hat das dann auf den Source-Code selbst auch einen Einfluss, muss da ggf. was umgeschrieben werden?

[DieDolly]

Zitat:

Hab mir mal alles runtergeladen, bei dem ich denke, dass ich das installieren muss.

Eigentlich muss man nix runterladen bis auf beiden OpenSSL-DLL-Dateien. Installieren auch nicht.

Ob 1.1.1 einen Einfluss hat weiß ich nicht. Kann man nur testen.
Ich lade 1.1.1 eh erst runter, wenn es auf Fulgan herunterladbar ist.

[MarcRB75]

Ach sooooo ...
Ich brauche also nur die 2 DLL-Dateien, mehr nicht.

Dann brauche ich diese Dateien/Downloads gar nicht?

http://slproweb.com/products/Win32OpenSSL.html

ich dachte, ich muss das auch installieren.

Das habe ich auch hier irgendwo im Forum gelesen, dass man quasi das für Windows auch installieren muss.
Darum kannte ich mich auch gar nicht mehr aus, was ich alles installieren muss und was nicht.

Und diese 2 Dll's sind quasi das Zertifikat, also die Gültigkeit für's versenden/empfangen vom Mails?

[DieDolly]

Hier runterladen und die beiden DLL-Dateien libeay32.dll und ssleay32.dll in das Verzeichnis kopieren wo deine Exe ist.
https://indy.fulgan.com/SSL/

Die sind dafür da, um den Inhalt zu verschlüsseln.

[MarcRB75]

Danke nochmal für Deine Hilfe!

Es klappt alles super :-)