strings einer combobox vergleichen

[neroo]

Hallo,

ich möchte hier nachdem ich die Datei eingelesen haben, die erste spalte der Tabelle zu einer combobox hinzufügen.
Dies mache ich mit dem Befehl combobox.items.add(); aber ich möchte hier die mehrmals vorkommenden strings löschen,
sodass ein string nur einmal vorkommt. Leider komme ich hier nicht weiter. ich wäre dankbar für die Hilfe:-D.

Code:

unit Datei;

{$mode objfpc}{$H+}

interface

uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, ComCtrls,
  Buttons, Grids, StdCtrls;

type

  { TForm1 }

  TForm1 = class(TForm)
    schliess_knopf: TButton;
    einlesen_knopf: TButton;
    s_standortname: TComboBox;
    Label1: TLabel;
    oeffnen_knopf: TButton;
    ende_knopf: TBitBtn;
    fuss: TStatusBar;
    OpenDialog: TOpenDialog;
    etabelle: TStringGrid;
    procedure beenden(Sender: TObject);
    procedure einlesen(Sender: TObject);
    procedure FormShow(Sender: TObject);
    procedure schliessen(Sender: TObject);
  end;

var Form1: TForm1;

implementation

{$R *.lfm}

{ TForm1 }

var anzahl: integer;
    datei_name: string;
    datei: textfile;
procedure TForm1.FormShow(Sender: TObject);
begin
  datei_name:='d:\temp\windenergie01.csv';
  with etabelle do
    begin
      Cells[1,0]:='Standort';
      Cells[2,0]:='Windrad';
      Cells[3,0]:='Nennleistung';
      Cells[4,0]:='Datum';
      Cells[5,0]:='Energiemenge';
    end;

  //
end;

procedure TForm1.schliessen(Sender: TObject);
begin
  //
end;

procedure TForm1.beenden(Sender: TObject);
begin
  close;
end;

procedure TForm1.einlesen(Sender: TObject);
var i,posi: integer;
    maxi,wert: double;

    buffer,eintrag,s1,s2,s3,s4,s5: string;
    ok: boolean;
begin
  with opendialog do
    begin
      title:='Windenergie einlesen';
      filename:=datei_name;
      initialdir:=extractfilepath(datei_name);
      filter:='Windenergieergebnisse (*.csv)|*.csv|alle Dateien (*.*)|*.*';
    end;
  if opendialog.execute then
    begin
      datei_name:=opendialog.filename;
      assignfile(datei,datei_name);
      {$I-}
      reset(datei);
      readln(datei);
      i:=0;
      while not(eof(datei)) do
        begin
          inc(i);
          readln(datei,eintrag);
          //Suedkueste,ElCedro2,3.4MW,01.02.2017,4092kWh
          posi:=pos(',',eintrag);
          s1:=copy(eintrag,1,posi-1);
          delete(eintrag,1,posi);
          //ElCedro2,3.4MW,01.02.2017,4092kWh
          posi:=pos(',',eintrag);
          s2:=copy(eintrag,1,posi-1);
          delete(eintrag,1,posi);
          //3.4MW,01.02.2017,4092kWh
          posi:=pos(',',eintrag);
          s3:=copy(eintrag,1,posi-1);
          delete(eintrag,1,posi);
          //01.02.2017,4092kWh
          posi:=pos(',',eintrag);
          s4:=copy(eintrag,1,posi-1);
          delete(eintrag,1,posi);
          //4092kWh
          s5:=eintrag;


          //
          with etabelle do
            begin
              if i>=rowcount then rowcount:=rowcount+1;
              cells[1,i]:=s1;
              cells[2,i]:=s2;
              cells[3,i]:=s3;
              cells[4,i]:=s4;
              cells[5,i]:=s5;
            end;
          //standortname in combobox schreiben
            d1:=s1;
            s_standortname.Items.Add(etabelle.Cells[1,i]);

          //--

          //
        end;
      closefile(datei);
      {$I+}
      ok:=(ioresult=0);
      //--


      //--
    end;

end; //einlesen



end.

[H.Bothur]

Moin,

wahrscheinlich gibt es 1000 bessere Lösungen aber wie wäre es damit

Delphi-Quellcode:

 
function NameBereitsVorhanden(const SuchString: String): Boolean;
var
  i: integer;
  gefunden: Boolean;
begin
  gefunden := false;
  for i := 0 to ETabelle.Count -1 do
  begin
    if SuchString := ETabelle:.String[i] then gefunden := true;
  end;
  Result := gefunden
end;

         //
          with etabelle do
            begin
              if i>=rowcount then rowcount:=rowcount+1;
              cells[1,i]:=s1;
              cells[2,i]:=s2;
              cells[3,i]:=s3;
              cells[4,i]:=s4;
              cells[5,i]:=s5;
            end;
          //standortname in combobox schreiben
            d1:=s1;
            if not NameBereitsVorhanden(etabelle.Cells[1,i]) then s_standortname.Items.Add(etabelle.Cells[1,i]);

Das ist Pseudo-Code - also nicht kopieren, aber der Ansatz ist eine Idee :-)

gruß
hans

[Delphi.Narium]

Delphi-Quellcode:

          //standortname in combobox schreiben
          d1:=s1;
          if s_standortname.Items.IndexOf(etabelle.Cells[1,i]) < 0 then begin
            s_standortname.Items.Add(etabelle.Cells[1,i]);
          end;

[Michael II]

Du schreibst, dass du die Einträge einzeln zu deiner Combobox hinzufügst. In diesem Fall könntest du eine Proc schreiben, welche überprüft, ob neuereintrag bereits in der Liste vorkommt oder nicht:

Delphi-Quellcode:

if combobox.Items.IndexOf( neuereintrag ) < 0 then
  combobox.Items.Add( neuereintrag );

[Luckie]

Hat die Combobox nicht sogar eine Eigenschaft, die man nutzen kann, dass sie keine Doubletten beinhaltet?

[Michael II]

Kann sein, ich kenn's nur von TStringList - dort über .Duplicates := dupIgnore; aber nur (wieso dem so ist, weiss wohl nicht mal die Firma) wenn die Elemente sortiert sind, also .Sorted := true;

Also etwa so:

Delphi-Quellcode:

  hs := TStringList.Create;
 try
  hs.Sorted := true;
  hs.Duplicates := dupIgnore;
  hs.Text := combobox1.items.Text;
  combobox1.Items.Text := hs.Text;
 finally
  hs.Free;
 end;

[Dalai]

Das dachte ich zuerst auch. Sieht aber so aus, als gäbe es da nur TStringList.Duplicates. Da TComboBox.Items aber vom Typ TStrings ist, gibt's da offenbar kein simples Property, um Duplikate zu verhindern. Daher ist die Variante mit TComboBox.Items.IndexOf wohl ein einfacher Workaround. Oder man erweitert TComboBox mit einer Ableitung um eine Methode, die die Existenz eines Strings in der Liste prüft.

Grüße
Dalai

[Luckie]

Ah. OK. Ich hatte nur im Hinterkopf, dass da was war.

Warum aber nicht erst alles in eine Stringliste packen und diese dann der Combobox zuweisen?

[Delphi.Narium]

Zitat:

Zitat von Luckie (Beitrag 1429682)

Ah. OK. Ich hatte nur im Hinterkopf, dass da was war.

Warum aber nicht erst alles in eine Stringliste packen und diese dann der Combobox zuweisen?

Weil TStringList intern die Methoden nutzt, die es von TStrings geerbt hat.

Man landet also in beiden Fällen zur Suche nach Dubletten bei IndexOf. Dann kann man es auch direkt verwenden ;-)

[Bernhard Geyer]

Lade die Liste erst mit dupIgnore in eine TStringsList und kopiere das Ergebnis dann EnBlock in die ComboBox.
Ist auch noch viel schneller als die Strings einzeln in die ComboBox zu bringen.