TNotifyEvent durchreichen?

[mcinternet]

Hallo,

ich habe hier eine Klasse, welche einfach eine RadioGroup erzeugt:

Code:

  TDruckerAuswahl = Class
    procedure GDruckerAuswahlClick(Sender: TObject);
    private
      fGDruckerAusWahl : TRadioGroup;
      fDrucker : String;
      fSettigsFileName : String;
      fPEvent : TNotifyEvent;
    public
      Constructor Create(SettigsFileName : String; DPanel : TPanel);
      Destructor  Destroy;
    Published
      Property DruckerAusWahl : TRadioGroup read fGDruckerAusWahl write fGDruckerAusWahl;
      Property Drucker : String read fDrucker write fDrucker;
      Property OnClick : TNotifyEvent read fPEvent write fPEvent;
  End;

Der Constructor dazu:

Code:

Constructor TDruckerAuswahl.Create(SettigsFileName : String; DPanel : TPanel);
  var qr : TQuickRep;

begin
  fSettigsFileName := SettigsFileName;
  fGDruckerAusWahl := TRadioGroup.Create(DPanel);
  fGDruckerAusWahl.Parent := DPanel;
  qr := TQuickRep.CreateNew(nil);
  qr.Prepare;
  fGDruckerAusWahl.Items := qr.QRPrinter.Printers;
  freeandnil(qr);
  fGDruckerAusWahl.Align := alClient;
  fGDruckerAusWahl.Caption := '  Druckerauswahl';
  fGDruckerAusWahl.Show;
  fGDruckerAusWahl.OnClick := GDruckerAuswahlClick;
  fDrucker := GetPrinter(fSettigsFileName);
end;

Hier nun der aufrufende Programmteil:

Code:

    DruckerListe := TDruckerAuswahl.Create(fglobals.Settingsfile, PanPrinters);
    DruckerListe.OnClick :=  PanPrintersClick;

Zur Erklärung:

diese Klasse setzt als Parent ein TPanel voraus. Bei diesem TPanel benötige ich ein Event, welches ich dem aufrufenden Programm durchreichen kann.
Also im Prinzip das "GDruckerAuswahlClick" (Klick auf die RadioGroup)

Hat jemand eine Idee?

Gruss

mcinternet

[bcvs]

Wenn ich das richtig verstehe, soll bei einem Klick auf ein Item der RadioGroup das OnClick des Panels aufgerufen werden, auf dem die Radiogroup liegt.

Du übergibst das Panel do sowieso an deinen Constructor. Geht nicht so was?

Delphi-Quellcode:

Constructor TDruckerAuswahl.Create(SettigsFileName : String; DPanel : TPanel);
  var qr : TQuickRep;

begin
  fGDruckerAusWahl := TRadioGroup.Create(DPanel);
  fGDruckerAusWahl.Parent := DPanel;
  ...
  fGDruckerAusWahl.OnClick := DPanel.OnClick;
end;

[mcinternet]

Nicht wirklich, ich habe mir jetzt so beholfen, dass ich das Event erst einmal von dem aufrufenden Programm umleite:

DruckerListe.DruckerAusWahl.OnClick := PanPrintersClick;

und in PanPrintersClick:

DruckerListe.GDruckerAuswahlClick(Sender); // diese muss zuerst aufgerufen werden, weil dort der Drucker ausgewählt und gespeichert wird.
lblDrucker.Caption := DruckerListe.Drucker;


allerdings finde ich das nicht sonderlich elegant. Besser wäre es meiner Meinung nach, wenn ich das irgendwie über ein "inherited" durchreichen könnte. - würde Codezeilen sparen.

Gruss

mcinternet

[bcvs]

Du hast doch in deinem TDruckerAuswahl schon ein Property OnClick mit der zugrundeliegende Variablen fPEvent (Wieso heißt die eigentlich nicht fOnClick?) Wird die irgendwo benutzt?

Damit würde ich so etwas machen:

Im aufrufenden Programm

Delphi-Quellcode:

procedure TForm1.OnDruckerAuswahlClick(Sender:TObject);
begin
  lblDrucker.Caption := DruckerListe.Drucker;
end;

und

Delphi-Quellcode:

    DruckerListe := TDruckerAuswahl.Create(fglobals.Settingsfile, PanPrinters);
    DruckerListe.OnClick := OnDruckerAuswahlClick;

Und in deinem GDruckerAuswahlClick :

Delphi-Quellcode:

procedure TDruckerAuswahl.GDruckerAuswahlClick(Sender: TObject);
begin
  ... // Drucker auswählen
  if assigned(fPEvent) then
    fPEvent(Sender);
end;

Spart zwar keine Codezeilen, eher im Gegenteil, ist aber übersichtlicher.

[jziersch]

Hallo,

da Du die radio group ja im code erzeugsts, kannst Du leicht eine eigene Klasse verwenden:

Code:

type TMyRadioGroup=class(TRadioGroup)
   protected
   procedure Click; override;
end;

{ TMyRadioGroup }

procedure TMyRadioGroup.Click;
begin
   inherited;
   if Assigned((Parent as TPanel).OnClick) then
        (Parent as TPanel).OnClick(Parent);
end;

und dann so erzeugen:

rd := TMyRadioGroup.Create(Panel1);

Leider ist im TControl das OnClick protected sodass ich hier die Klasse des Parent as TPanel fest codiert habe.
Ein Zugriff auf die protected Eigenschaften ist über die runtime information möglich, ist aber overkill, wenn man eh weis, was das Parent ist.

[mcinternet]

Vielen Dank für Eure Tipps, ich werde da mal weitertesten

Beste Grüße

mcinternet

[HolgerX]

Hmm...

Zitat:

Zitat von jziersch (Beitrag 1429105)

Leider ist im TControl das OnClick protected sodass ich hier die Klasse des Parent as TPanel fest codiert habe.
Ein Zugriff auf die protected Eigenschaften ist über die runtime information möglich, ist aber overkill, wenn man eh weis, was das Parent ist.

Wieso RTTI ?

Geht auch einfacher, nur 2 Zeilen mehr ;)

Delphi-Quellcode:

type
  TMyRadioGroup=class(TRadioGroup)
  protected
    procedure Click; override;
end;


{ TMyRadioGroup }

Type
  TControlCrack = class(TControl);

procedure TMyRadioGroup.Click;
begin
  inherited;
  if Assigned(TControlCrack(Parent).OnClick) then
        TControlCrack(Parent).OnClick(Parent);
end;

(Oder geht das mit neuerem Delphi nicht mehr)

(Erstellt mit D6)