XML Endtag finden

[Pader1305]

Hallo Zusammen,

Weiß jemand, ob es mit irgendeiner Funktion möglich ist den allerletzten Tag einer XML-Datei zu finden und vor diesen einen XML-Eintrag zu erstellen?
Ich hoffe meine Frage ist konkret genug formuliert. :-D

Über jeden Hinweis würde ich mich riesig freuen.

[Uwe Raabe]

Vielleicht so:

Delphi-Quellcode:

const
  FileName = 'MyXmlFile.xml';
var
  N: Integer;
  S: string;
begin
  S := TFile.ReadAllText(FileName);
  N := S.LastIndexOf('</');
  if N >= 0 then begin
    TFile.WriteAllText(FileName, S.Insert(N, '<MyTag>MyValue</MyTag>'));
  end;
end;

[Pader1305]

Vielen Dank schonmal für Ihre Antwort! :wink:

Vielleicht verdeutlicht eine Beispiels XML-Datei nocheinmal mein Problem.

Code:

<test>
   //Anderer Code
</test>

<test>
   //Anderer Code
</test>

<test>
   //Hier soll der entsprechende Code hinzugefügt werden
</test>

Ich weiß allerdings nicht, wie ich nur in den letzten Test-Tag etwas reinschreiben kann

[mkinzler]

Etwas erweitert:

Delphi-Quellcode:

const
  FileName = 'MyXmlFile.xml';
var
  N, N2: Integer;
  S: string;
begin
  S := TFile.ReadAllText(FileName);
  N := S.LastIndexOf('</');
  if N >= 0 then begin
    N2 := S.IndexOf( '>', N)+1;
    TFile.WriteAllText(FileName, S.Insert(N2, '<MyTag>MyValue</MyTag>'));
  end;
end;

[Uwe Raabe]

Zitat:

Zitat von Pader1305 (Beitrag 1411550)

Vielleicht verdeutlicht eine Beispiels XML-Datei nocheinmal mein Problem.

Auf dieses Beispiel angewendet erzeugt mein Code-Beispiel folgendes:

Code:

<test>
   //Anderer Code
</test>

<test>
   //Anderer Code
</test>

<test>
   //Hier soll der entsprechende Code hinzugefügt werden
<MyTag>MyValue</MyTag></test>

Zitat:

Zitat von mkinzler (Beitrag 1411552)

Etwas erweitert:

Mit dem Code wird der Textblock aber nach dem letzten End-Tag eingefügt, was einem simplen Append ziemlich nahe kommt.

[Der schöne Günther]

Ich will ja nichts schlechtreden, aber textbasiert XML bearbeiten finde ich etwas fahrlässig. Vor allem wenn das in Delphi doch so einfach geht:

Delphi-Quellcode:

implementation

uses XmlIntf, XmlDoc;

{$R *.dfm}

procedure TForm1.Button1Click(Sender: TObject);
var
   xmlDoc:      IXMLDocument;
   lastNode:   IXMLNode;
begin
   xmlDoc := LoadXMLData(Memo1.Text);
   lastNode := xmlDoc.DocumentElement.ChildNodes.Last();
   // Mach was mit lastNode...
   lastNode.AddChild('thisIsANewNode');

   Memo2.Text := xmlDoc.XML.Text;
end;

[Pader1305]

Danke nochmal für eure Antworten, das hat mir auf jeden Fall schonmal weitergeholfen!:)

Allerdings hab ich soeben bemerkt, dass der Fehler schon woanders liegt und zwar im Laden der Datei.

Code:

XMLDocument1.LoadFromFile(FILEPATH);

Dort haut er mir bereits einen Fehler raus, da die Struktur der XML-Datei folgendermaßen aussieht und ich diese auch nicht verändern kann.

Code:

<?xml version="1.0" encoding="utf-8"?>

<Beispiel>

</Beispiel>

<Beispiel>

</Beispiel>

Die Datei, die geladen wird hat keinen übergeordneten Knotenpunkt und diese Datei liegt so auf einem Server vor. Wenn allerdings ein übergeordneter Knoten vorhanden ist, dann funktioniert alles einwandfrei.
Ich schätze da lässt sich nicht viel machen, korrekt?

[Der schöne Günther]

Wenn man kein gültiges XML hat kann man auch keinen XML-Parser bemühen :(

[Pader1305]

Zitat:

Zitat von Der schöne Günther (Beitrag 1411557)

Wenn man kein gültiges XML hat kann man auch keinen XML-Parser bemühen :(

Ja, in der Tat. Ist nur sehr ärgerlich, dass mir das so spät auffällt. :|

Bin noch ganz neu in der Delphi-Programmierung. Wie sieht das denn aus, wenn man, wie die Vorgänger bereits erwähnten, die Datei stumpf als Textdatei ausliest, dann den entsprechenden Teil einfügt und schließlich als XML-Datei abspeichert?

[Delphi.Narium]

Bin mal naiv:

Datei in 'ne Stringliste laden und ein bisserl anpassen, ungefähr sinngemäß sowas:

Delphi-Quellcode:

var
  sl : TStringList;
begin
  sl := TStringList.Create;
  sl.LoadFromFile(FILEPATH);
  sl.Insert(1,'<reparaturtag>');
  sl.Add('</reparaturtag>');
  sl.SaveToFile(FILEPATH);
  sl.Free;

Sinnvoller wäre es, beim "Lieferanten" die Erstellung einer syntaktisch korrekten Datei einzufordern.