PrintDialog.Execute wird nicht ausgeführt

[dataspider]

Ich habe eine Funktion zum Aufruf von TPrintDialog

Delphi-Quellcode:

function PrintDialog(var AFromPage, AToPage: Integer): Boolean;
Var
  APrintDialog: TPrintDialog;
begin
  APrintDialog := TPrintDialog.Create(Application);
  try
    APrintDialog.Options := [poPageNums];
    APrintDialog.PrintRange := prPageNums;
    APrintDialog.FromPage := AFromPage;
    APrintDialog.MaxPage := AToPage;
    APrintDialog.ToPage := AToPage;
    Result := APrintDialog.Execute;
    AFromPage := APrintDialog.FromPage;
    AToPage := APrintDialog.ToPage;
  finally
    APrintDialog.Free;
  end;
end;

Die rufe ich hier auf:

Delphi-Quellcode:

procedure TImageViewer.Print(AShowDialog: Boolean = True);
var
  RR: TRect;
  ABitMap: TBitmap;
  AFileName: string;
  AFromPage: Integer;
  AToPage: Integer;
  APrintPage: Integer;
  AFileStream: TMemoryStream;
begin
  AFromPage := 1;
  AToPage := PageCount;
  if not PrintDialog(AFromPage, AToPage) then
    Exit;
  ABitMap := TBitmap.Create;
  AFileStream := TMemoryStream.Create;
  try
    Printer.BeginDoc;
    try
      for APrintPage := AFromPage to AToPage do
      begin
        AFileStream.Clear;
        if Provider.DocProviderMode = dpmFile then
        begin
          AFileName := FileNames[APrintPage -1];
          AFileStream.LoadFromFile(AFileName)
        end
        else
          Provider.AssignFileFromDataSet(AFileStream);
        AssignImage(ABitMap, AFileStream, IsTiff(Provider.FileExtension));
        RR := Rect(0, 0, ABitMap.Width, ABitMap.Height);
        PrintBitmapEx(ABitMap);
        if APrintPage < AToPage then
          Printer.NewPage;
      end;
    finally
      Printer.EndDoc;
    end;
  finally
    ABitMap.Free;
    AFileStream.Free;
  end;
end;

Nur hier passiert einfach nichts. Der Dialog wird nicht angezeigt.
Wenn ich die Funktion an anderer Stelle aufrufe, ist alles schick.
Ich verzweifle langsam. Im Debugger springt er auch in die Routine in Vcl.Dialogs.

Was kann man falsch machen oder wo könnte man bei der Ursachensuche ansetzen?

Frank

[Der schöne Günther]

Also ich wette wenn du im Debugger nachschaust wird der Parameter

Delphi-Quellcode:

AToPage

kleiner sein als

Delphi-Quellcode:

AFromPage

.

[dataspider]

Zitat:

Zitat von Der schöne Günther (Beitrag 1393682)

Also ich wette wenn du im Debugger nachschaust wird der Parameter

Delphi-Quellcode:

AToPage

kleiner sein als

Delphi-Quellcode:

AFromPage

.

Ja, damit kann ich leben, wenn er mir erst mal diesen Dialog anzeigen würde...

Aber - mit der Wette..
In der Regel ist PageCount immer 1.

Frank

[Der schöne Günther]

Also ich sehe nur dass ich genau dein beschriebenes Verhalten (Dialog wird nicht angezeigt) bekomme wenn "bis Seite y" kleiner ist als "ab Seite x".

Dein PageCount kommt irgendwo von außen und wird der Methode nicht übergeben. Es ist so ziemlich das einzige was sich mit dem Aufruf von "anderswo" unterscheiden kann.

[himitsu]

Einige Dialog-Klassen verwenden den Owner als Ausrichtungs-Parent für das Dialog-Fenster.
Andere verwenden den HWND-Parameter, den man dem Execute übergeben kann.
Und wieder Andere ignorieren alle Parameter und bauen irgendwelchen Scheiß ein.

Nja, was TPrintDialog macht, weiß ich jetzt nicht, aber was wäre wohl, wenn sie den Owner verwenden und der hier aber unsichtbar ist?
Oder der geht auf ActiveForm ... k.A. wie das an den jeweiligen Aufrufstellen aussieht.

[dataspider]

Zitat:

Zitat von Der schöne Günther (Beitrag 1393688)

Also ich sehe nur dass ich genau dein beschriebenes Verhalten (Dialog wird nicht angezeigt) bekomme wenn "bis Seite y" kleiner ist als "ab Seite x".

Dein PageCount kommt irgendwo von außen und wird der Methode nicht übergeben. Es ist so ziemlich das einzige was sich mit dem Aufruf von "anderswo" unterscheiden kann.

:oops:

Danke, PageCount gehört zur Klasse und ist hier tatsächlich 0.
Das Verhalten hätte ich nicht erwartet...

Du hast was gut!

Frank