Wie findet man den richtigen angemeldeten Windows Benutzer

[DavidKlimas]

Hallo zusammen,

ich hab verschiedenes ausprobiert, kann aber den Benutzernamen nicht finden in dessen Windows Profil ich angemeldet bin.

Delphi-Quellcode:

function UserName: String;
var User: PChar;
    i: DWord;
begin
  i := 1024;
  user := StrAlloc(Succ(i));
  if GetUserName(User, i) then Result := StrPas(User)
                          else Result := 'unknown';
end;

Diese Funktion gibt mir den Benutzernamen von jenem der das Programm ausführt, aber nicht unbedingt jener bei dem ich angemeldet bin: Wenn ich meine App as "Run as Admin" starte, bekomme ich immer den Namen vom Admin zurück.

Wie kann ich den laufenden Benutzernamen finden ?

Danke

[Luckie]

Was ist der "laufende" Benutzername?

Der in dessen Kontext das Programm ausgeführt wird? Der, der vor dem Monitor sitzt oder der, der per RemoteSession angemeldet sind?

[DavidKlimas]

Der bei dem ich bei Windows Angemeldet bin, der der im Startmenu steht, wenn ich unten links auf das Windows zeichen klicke. ;-)

Bei Windows heißt es bei GetUserName:
"If the current thread is impersonating another client, the GetUserName function returns the user name of the client that the thread is impersonating."

[Zacherl]

Versuch mal WTSGetActiveConsoleSessionId. Existiert allerdings erst seit Vista die API.

Hatte ich damals in folgender Form verwendet, um den aktiven Benutzer aus einem Service heraus abzufragen:

Delphi-Quellcode:

class function TServiceHelper.QueryActiveSessionId: DWord;
var
  WTSGetActiveConsoleSessionId: function: DWord; stdcall;
begin
  Result := 0;
  @WTSGetActiveConsoleSessionId :=
    GetProcAddress(LoadLibrary('kernel32.dll'), 'WTSGetActiveConsoleSessionId');
  if Assigned(@WTSGetActiveConsoleSessionId) then
  begin
    Result := WTSGetActiveConsoleSessionId;
  end;
end;

Edit:
Achso ganz vergessen ... danach brauchst du natürlich noch WTSQuerySessionInformation mit WTSUserName InfoClass.

[DavidKlimas]

In der Richtung hab ich schon gesucht, konnte aber keine Beispiele zur WTSQuerySessionInformation finden.

Ich probier das mal aus ;-)

[Zacherl]

Ich sehe grade, dass es für die aktuelle Sitzung sogar Konstanten gibt. Folgender Aufruf sollte für dich funktionieren:

Delphi-Quellcode:

function WTSQuerySessionInformationW(hServer: THandle; SessionId: DWord; WTSInfoClass: DWord;
  var ppBuffer: LPTSTR; var BytesReturned: DWord): BOOL; stdcall;
  external 'Wtsapi32.dll';

procedure WTSFreeMemory(pMemory: Pointer); stdcall;
  external 'Wtsapi32.dll';

procedure Test;
const
  WTS_CURRENT_SERVER_HANDLE = 0;
  WTS_CURRENT_SESSION       = DWord(-1);
const
  WTSUserName = 5;
var
  Buffer: LPTSTR;
  BytesReturned: DWord;
begin
  if WTSQuerySessionInformationW(WTS_CURRENT_SERVER_HANDLE, WTS_CURRENT_SESSION, WTSUserName,
    Buffer, BytesReturned) then
  try
    ShowMessage(Buffer);
  finally
    WTSFreeMemory(Buffer);
  end;
end;

[himitsu]

Zitat:

WTSGetActiveConsoleSessionId

Und was bekommt man bei einer RemoteSitzung, wenn garkeiner vorm PC sitzt?

PS: Wenn man eine Resource anfordert, dann hat man diese gefälligst auch wieder freizugeben!
LoadLibrary -> FreeLibrary
Aber da man davon ausgehen kann, dass diese DLL (kernel32) immer geladen ist, kann man auch einfach GetModuleHandle verwenden.

[Luckie]

Und wozu muss das ein Programm wissen?

[DavidKlimas]

Super, dass klappt alles wie es soll. Danke an euch

[Zacherl]

Zitat:

Zitat von himitsu (Beitrag 1363972)

Und was bekommt man bei einer RemoteSitzung, wenn garkeiner vorm PC sitzt?

Man bekommt den Namen des Benutzerkontos mit dem man sich per RDP eingeloggt hat. Intern unterscheidet Windows gar nicht mehr großartig zwischen lokalem Login und einer Remote-Session. Session ist Session :stupid:

Zitat:

Zitat von Luckie (Beitrag 1363973)

Und wozu muss das ein Programm wissen?

In meinem Falle benötigte ich das Token des angemeldeten Users, um bestimmte Aktionen in seinem Userkontext ausführen zu können.