Helfer funktioniert nicht bei statischen Record-Methoden

[Der schöne Günther]

Wie komme ich mit einem Record-Helfer an private statische Methoden des Records?

Delphi-Quellcode:

type
   TSomeRecord = record
      strict private procedure instanceMethod();
      strict private class procedure StaticMethod(); static;
   end;

   TSomeRecordHelper = record helper for TSomeRecord
      public procedure _instanceMethod();
      public class procedure _StaticMethod(); static;
   end;

   TMyObject = class(TObject)
      strict private class procedure StaticMethod(); virtual; abstract;
   end;

{ TSomeRecord }

procedure TSomeRecord.instanceMethod();
begin
   //
end;

class procedure TSomeRecord.StaticMethod();
begin
   //
end;

{ TSomeRecordHelper }

procedure TSomeRecordHelper._instanceMethod();
begin
   self.instanceMethod(); // Das klappt schonmal...
end;

class procedure TSomeRecordHelper._StaticMethod();
begin
   //self.StaticMethod(); // E2003: Undeklarierter Bezeichner "self"
   //StaticMethod(); // E2003: Undeklarierter Bezeichner "StaticMethod"
   //TSomeRecord.StaticMethod(); // E2361 Auf private-Symbol TSomeRecord.StaticMethod kann nicht zugegriffen werden
   //inherited StaticMethod(); // E2075 Diese Form des Methodenaufrufs ist nur in Methoden von abgeleiteten Typen erlaubt
   raise EProgrammerNotFound.Create('Delphi-Praxis, zu Hilfe!');
end;

[Stevie]

Delphi-Quellcode:

type
   TSomeRecord = record
      strict private class procedure StaticMethod(); static;
   end;

   TSomeRecordHelper = record helper for TSomeRecord
      private procedure __StaticMethod(); inline;
      public class procedure _StaticMethod(); static; inline;
   end;

{ TSomeRecord }

class procedure TSomeRecord.StaticMethod();
begin
   //
end;

{ TSomeRecordHelper }

class procedure TSomeRecordHelper._StaticMethod();
var
  Self: TSomeRecord;
begin
  Self.__StaticMethod;
end;

procedure TSomeRecordHelper.__StaticMethod;
begin
  TSomeRecord.StaticMethod;
end;

[Der schöne Günther]

Ok, tatsächlich nur so. Danke.

PS: Warum das explizite inlining?

[Stevie]

Zitat:

Zitat von Der schöne Günther (Beitrag 1309547)

PS: Warum das explizite inlining?

Angewohnheit, ich kann unnütze Methodenaufrufe nicht leiden :)