TEvent.free im Thread Destructor?

[Mavarik]

Hallo Zusammen.

Gegeben sei ein Thread der ein

Delphi-Quellcode:

MyEvent := TEvent...

handle hat.

Delphi-Quellcode:

Procedure TMyThread.Execute;
begin
  While not Terminated do
   begin
     MyEvent.WaitFor(infinite);
     if not(Terminated) then
       begin
         // Mach was schlaues... 
       end;
   end;
end;

Destructor TMyThread.destroy;
begin
  Terminate;
  MyEvent.SetEvent;
  MyEvent.Free;      // Gut oder schlecht???
  Inherited;
end;

Mavarik

[Dejan Vu]

Delphi-Quellcode:

if Mavarik.Erstellt(MyEvent).Im(Konstruktor) then 
  result := Gut
else
  result := Not Gut;

[Mavarik]

Zitat:

Zitat von Dejan Vu (Beitrag 1259624)

Delphi-Quellcode:

if Mavarik.Erstellt(MyEvent).Im(Konstruktor) then 
  result := Gut
else
  result := Not Gut;

LOL...

Delphi-Quellcode:

Constructor TMyThread.Create;
begin
  inherited Create(true);

  MyEvent := TEvent.Create(NIL,false,false,'');
  ....
end; 

Const
  Mavarik = Gut;

Danke

PS.: Die eigentliche Frage war, wird bei MyEvent.SetEvent der Thread sofort gestartet oder kann es sein, dass die
MyEvent.WaitFor(Infinite); plötzlich keinen Rücksprung mehr hat.

[Der schöne Günther]

Der Punkt ist folgender: Dein Thread läuft. Er ist zwar nicht sonderlich aktiv und wartet bis zum Tag des jüngsten Gerichts dass

Delphi-Quellcode:

myEvent

eintritt, aber er ist gestartet.

Wenn du ihn terminierst, läuft er weiter. Und weiter. Denn er wartet auf das Event.

Daher würde ich in deinem Thread noch die Methode

Delphi-Quellcode:

TerminatedSet

überschreiben: Diese sollte sich um das Setzen des Events kümmern, damit der Thread nicht ewig dort in seinem Execute darauf wartet, sollte es nie eingetreten sein.

Siehe auch hier: http://www.delphipraxis.net/1254537-post13.html

[Mavarik]

Zitat:

Zitat von Der schöne Günther (Beitrag 1259630)

Der Punkt ist folgender: Dein Thread läuft. Er ist zwar nicht sonderlich aktiv und wartet bis zum Tag des jüngsten Gerichts dass

Delphi-Quellcode:

myEvent

eintritt, aber er ist gestartet.

Wenn du ihn terminierst, läuft er weiter. Und weiter. Denn er wartet auf das Event.

emm... Nein...

Deswegen mache ich ja ein

Delphi-Quellcode:

   MyEvent.SetEvent;

[jaenicke]

Terminate gehört eigentlich nicht in den Destruktor, der ist rein zum Aufräumen da. Oder wenn es dort schon steht, sollte dann ein WaitFor auf den Thread folgen, in diesem Fall nach dem SetEvent. Danach kannst du ruhigen Gewissens alles freigeben.

Bei mir steht die Sequenz Terminate, WaitFor, Free außerhalb des Threads.

[Sir Rufo]

So ist es richtig und ausreichend:
(Ich habe mir erlaubt aus

Delphi-Quellcode:

MyEvent

ein

Delphi-Quellcode:

FMyEvent

um zu verdeutlichen, dass es sich um ein Feld der Klasse handelt)

Delphi-Quellcode:

procedure TMyThread.TerminatedSet;
begin
  inherited;
  FMyEvent.SetEvent; // auf jeden Fall auch NACH INHERITED!!!!
end;

Procedure TMyThread.Execute;
begin
  While not Terminated do
   begin
     FMyEvent.WaitFor(infinite);
     if not(Terminated) then
       begin
         // Mach was schlaues... 
       end;
   end;
end;

Destructor TMyThread.destroy;
begin
  Inherited;
  FMyEvent.Free; // NACH INHERITED!!!!!!
end;

Wen man wissen möchte, warum das reicht, dann schaut man sich den Source von

Delphi-Quellcode:

TThread.Destroy

einfach mal an (so habe ich auch herausgefunden, warum das so ausreicht) und sieht dort folgende lustige Dinge:

Delphi-Quellcode:

destructor TThread.Destroy;
begin
  if (FThreadID <> 0) and not FFinished and not FExternalThread then
  begin
    Terminate;
    if FCreateSuspended or FSuspended then
      Resume;
{$IFDEF MSWINDOWS}
    while not FStarted do
{$ELSE}
    while not ((not FCreateSuspended or FInitialSuspendDone) and FStarted) do
{$ENDIF}
      Yield;
    WaitFor;
  end;
  ...
end;

[Mavarik]

Zitat:

Zitat von Sir Rufo (Beitrag 1259641)

So ist es richtig und ausreichend:
(Ich habe mir erlaubt aus

Delphi-Quellcode:

MyEvent

ein

Delphi-Quellcode:

FMyEvent

um zu verdeutlichen, dass es sich um ein Feld der Klasse handelt)

Delphi-Quellcode:

procedure TMyThread.TerminatedSet; // Erst ab XE? jedenfalls gibt es das nicht in D2007
begin
  inherited;
  FMyEvent.SetEvent;
end;

Procedure TMyThread.Execute;
begin
  While not Terminated do
   begin
     FMyEvent.WaitFor(infinite);
     if not(Terminated) then
       begin
         // Mach was schlaues... 
       end;
   end;
end;

Destructor TMyThread.destroy;
begin
  Inherited;
  FMyEvent.Free; // NACH INHERITED!!!!!! Stimmt hab ich auch gefunden!
end;

s.o.

[Mavarik]

Zitat:

Zitat von jaenicke (Beitrag 1259639)

Terminate gehört eigentlich nicht in den Destruktor, der ist rein zum Aufräumen da. Oder wenn es dort schon steht, sollte dann ein WaitFor auf den Thread folgen, in diesem Fall nach dem SetEvent. Danach kannst du ruhigen Gewissens alles freigeben.

Bei mir steht die Sequenz Terminate, WaitFor, Free außerhalb des Threads.

Waitfor nicht nötig da im Thread Destructor schon vorhanden!

[jaenicke]

Zitat:

Zitat von Mavarik (Beitrag 1259644)

Waitfor nicht nötig da im Thread Destructor schon vorhanden!

Wenn man es denn in der Reihenfolge aufruft wie Sir Rufo geschrieben hat, funktioniert das auch, ja.