TGroupbox, Tag property

[Gutelo]

Hallo,

ich moechte folgendes realisieren:

Auf einem Form habe ich eine TRadioGroup mit diversen items und mehrere TGroupboxes. Abhaengig davon welches item in der RadioGroup ausgewaehlt wird sollen bestimmte Groupboxes angezeigt werden (visible=true) waehrend alle uebrigen verteckt werden sollen (visible = false).

Ist es eine gute Praxis die Zuordnung von Groupbox <--> Radiogroup item ueber die Tag property der TGroupboxes zu machen oder sollte ich bei:

Delphi-Quellcode:

case RadioGroup1.itemindex of
  0: begin Group1.visible:= true; Group2.visible:=false; Group3.visible:=true; end;
  1: begin Group1.visible:= false; Group2.visible:=true; Group3.visible:=false; end;
  ...
end;

bleiben? Bei der Variante mit den Tags koennte ich es spaeter einfacher um weitere Groupboxes erweitern. Ich hab folgendes im Sinn:

Delphi-Quellcode:

for i :=0 to Form1.ComponentCount - 1 do
    begin
     if Components[i] is TGroupBox then
     begin
       if (StrToInt(Components[i].Tag) = RadioGroup1.itemindex) 
          then Components[i].visible := true else Components[i].visible:=false;
     end;
end;

Gutelo

[Namenloser]

Meiner Meinung nach ist die Variante mit den Tags besser. Nicht genau gelesen.

[himitsu]

Es kommt drauf an.

Wenn die anderen Komponenten bei mehreren Items angezeigt werden soll, dann fängt man an in dem Tag binär zu rechnen.
PS: siehe ManifestCreator .... dort wird praktisch alles über Tag und Co. behandelt :lol: (hatte damals dieses Konzept damit zu exzessiv ausprobiert)

Einmal sieht man es direkt im OI was wann angezeigt wird (falls man sich merkt, oder es dokumentiert hat, was Tag eigentlich bedeutet)
und andererseits hätte man im Code einen Überblick, was beim Umschalten alles für Komponenten betroffen sind.

Zitat:

Delphi-Quellcode:

case RadioGroup1.itemindex of
  0: begin Group1.visible:= true; Group2.visible:=false; Group3.visible:=true; end;
  1: begin Group1.visible:= false; Group2.visible:=true; Group3.visible:=false; end;
  ...
end;

Aber sowas bitte nicht, denn da sieht keiner mehr durch, vorallem wenn es mal mehr als 3 Komponenten werden.

Delphi-Quellcode:

Group1.Visible := RadioGroup1.ItemIndex = 0;
Group2.Visible := RadioGroup1.ItemIndex = 1;
Group3.Visible := RadioGroup1.ItemIndex = 2;
...
Group99.Visible := RadioGroup1.ItemIndex in [1, 5, 33];

PS: Es gibt noch eine dritte Möglichkeit. :zwinker:
Du blendest die "andere" GroupBox nicht ein/aus, sondern es gibt nur noch "Eine", welche entsprechend mit den zugehörigen Werte/Komponenten gefüllt wird.

Oder, wenn es nur je eine GroupBox ist, dann halt ein TPageControl umschalten, wo die Tabs ausgeblendet sind, was sich im FormDesigner bestimmt schöner bearbeiten lässt.



Und ich würde empfehlen die Rechtschreibung (CamelCase) beizubehalten, dank Codevervollständigung ist das auch keine Arbeit, aber es verbessert IMHO die Lesbarkeit des Codes,
genauso wie manch nutzlose Leerzeichen oder eine halbwegs korrekte/einheitliche Einrückungen. (jetzt nicht nur auf deinen schnell dahin getippten Code bezogen ... das sieht man überall immer öfter)

[Gutelo]

Danke Himitsu

Zitat:

Wenn die anderen Komponenten bei mehreren Items angezeigt werden soll, dann fängt man an in dem Tag binär zu rechnen.

Eine Groupbox kann bei mehreren Items angezeigt werden. Oh stimmt, daran hab ich noch garnicht gedacht. Wird dann auch etwas umstaendlicher.

Zitat:

Aber sowas bitte nicht, denn da sieht keiner mehr durch, vorallem wenn es mal mehr als 3 Komponenten werden.

Das ist der Grund warum ich nach einer Alternative suche :)

Zitat:

Oder, wenn es nur je eine GroupBox ist, dann halt ein TPageControl umschalten, wo die Tabs ausgeblendet sind, was sich im FormDesigner bestimmt schöner bearbeiten lässt.

Mache ich an anderer Stelle routine-maessig. Da aber keine "logische Zuordnung" GroupBoxen <-> Item existiert muesste ich in dem Fall viele Groupboxen mehrfach auf den Tabs erstellen.

[Perlsau]

Ich würde das ganz anders angehen:

1. Schreibe eine Procedure, die alle GroupBoxes unsichtbar macht:

Delphi-Quellcode:

Procedure TFormMain.GroupBoxenUnsichtbar;
begin
  Group1.Visible := False;
  Group2.Visible := False;
  Group3.Visible := False;
  Group4.Visible := False;
  Group5.Visible := False;
end;

Dann schreibst du dir eine Ereignisbehandlung für OnClick deiner RadioGroup:

Delphi-Quellcode:

Procedure TFormMain.Radio_WasWeisIchClick(Sender: TObject);
begin
  GroupBoxenUnsichtbar;
  Case Radio_WasWeisIch.ItemIndex Of
   1 : Group1.Visible := True;
   2 : Group2.Visible := True;
   3 : Group3.Visible := True;
   4 : Group4.Visible := True;
   5 : Group5.Visible := True;
  End;
end;

Kommen nun weitere GroupBoxen hinzu, trägst du die einfach in diese beiden Proceduren ein.

Alternativ könntest du diese GroupBoxen auch in einer Objektliste verwalten ...

Delphi-Quellcode:

  PRIVATE { Private-Deklarationen }

   MyObjectList : Generics.Collections.TObjectList<TGroupBox>;
   ...

Procedure TFormMain.FormCreate(Sender: TObject);
begin
  ...
  MyObjectList := Generics.Collections.TObjectList<TGroupBox>.Create;
  ...
end;

... und eine Methode schreiben, um die Objektliste zu befüllen:

Delphi-Quellcode:

Procedure TFormMain.MyObjectListFill;
begin
  MyObjectList.Add(Group1);
  MyObjectList.Add(Group2);
  MyObjectList.Add(Group3);
  MyObjectList.Add(Group4);
  MyObjectList.Add(Group5);
end;

Dann wäre Radio_WasWeisIch.Items analog zu MyObjektList.Items und die Methoden sähen wie folgt aus:

Delphi-Quellcode:

Procedure TFormMain.GroupBoxenUnsichtbar;
Var
  i : Integer;
begin
  For i := 0 TO MyObjectList.Count -1 DO
    MyObjectList.Items[i].Visible := False;
end;

Procedure TFormMain.Radio_WasWeisIchClick(Sender: TObject);
begin
  GroupBoxenUnsichtbar;
  MyObjectList.Items[Radio_WasWeisIch.ItemIndex].Visible := True;  
end;

... oder gleich alles in einer Procedure:

Delphi-Quellcode:

Procedure TFormMain.Radio_WasWeisIchClick(Sender: TObject);
Var
  i : Integer;
begin
  For i := 0 TO MyObjectList.Count -1 DO
    MyObjectList.Items[i].Visible := False;
  MyObjectList.Items[Radio_WasWeisIch.ItemIndex].Visible := True;  
end;

Hinweis: Alles ungetestet ...

[Gutelo]

Hallo Perlsau,

danke fuer die ausfuehrliche Antwort :)

Idee 1 finde ich ganz gut, so spart man sich schonmal die Arbeit mit allen visible:=false und das case of bleibt auch recht uebersichtlich. Mit TObjectList habe ich noch nicht gearbeitet. Scheint eine Art StringList fuer Objekte zu sein. Einen wirklichen Vorteil sehe da nicht im Vergleich zu Idee 1. Letztere wird implementiert :)

[DeddyH]

Zitat:

Zitat von Gutelo (Beitrag 1256893)

Einen wirklichen Vorteil sehe da nicht im Vergleich zu Idee 1.

Ich schon, das geht nämlich auch kürzer.

Delphi-Quellcode:

for i := 0 to MyObjectList.Count - 1 do
    TGroupBox(MyObjectList.Items[i]).Visible := i = Radio_WasWeisIch.ItemIndex;

GroupboxenUnsichtbar braucht man dann nicht mehr. Außerdem: kommen später noch weitere Groupboxen dazu, muss man nur eine Stelle im Code anfassen, nämlich beim Befüllen der Liste (es sei denn, man iteriert dabei über Components oder Controls, dann kann man sich sogar das sparen).

[Perlsau]

Zitat:

Zitat von DeddyH (Beitrag 1256898)

Delphi-Quellcode:

for i := 0 to MyObjectList.Count - 1 do
    TGroupBox(MyObjectList.Items[i]).Visible := i = Radio_WasWeisIch.ItemIndex;

:thumb::thumb:

[DeddyH]

:wink:

[edit] Ich hab mal fix ein Beispiel mit Labels statt GroupBoxen geschrieben. Zunächst braucht man die Unit Contnrs (für TObjectList oder TComponentList). Dann natürlich eine Liste (heißt hier FLabels), die im OnCreate erzeugt und im OnDestroy wieder freigegeben wird. Zusätzlich habe ich noch 2 private Methoden deklariert.

Delphi-Quellcode:

type
  TfrmTest = class(TForm)
    Label1: TLabel;
    Label2: TLabel;
    Label3: TLabel;
    Label4: TLabel;
    RadioGroup1: TRadioGroup;
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure RadioGroup1Click(Sender: TObject);
  private
    { Private-Deklarationen }
    FLabels: TObjectList;
    procedure InitializeList;
    procedure SetLabelsVisible;
  public
    { Public-Deklarationen }
  end;

InitializeList iteriert über Components und fügt die gefundenen Labels der Objektliste und den Items der Radiogroup hinzu (damit das auch schön synchron bleibt). Der Aufruf erfolgt im OnCreate:

Delphi-Quellcode:

procedure TfrmTest.FormCreate(Sender: TObject);
begin
  FLabels := TObjectList.Create(false);
  InitializeList;
end;

procedure TfrmTest.InitializeList;
var
  i: integer;
  ALabel: TLabel;
begin
  RadioGroup1.Items.Clear;
  for i := 0 to ComponentCount - 1 do
    if Components[i] is TLabel then
      begin
        ALabel := TLabel(Components[i]);
        FLabels.Add(ALabel);
        RadioGroup1.Items.Add(ALabel.Caption);
      end;
end;

SetLabelsVisible entspricht dem eben schon gezeigten Code und wird im OnClick der RadioGroup aufgerufen.

Delphi-Quellcode:

procedure TfrmTest.RadioGroup1Click(Sender: TObject);
begin
  SetLabelsVisible;
end;

procedure TfrmTest.SetLabelsVisible;
var
  i: integer;
begin
  for i := 0 to FLabels.Count - 1 do
    (FLabels[i] as TLabel).Visible := i = RadioGroup1.ItemIndex;
end;

Jetzt fehlt nur noch die Freigabe der Liste im OnDestroy:

Delphi-Quellcode:

procedure TfrmTest.FormDestroy(Sender: TObject);
begin
  FLabels.Free;
end;

Ich habe hier 4 Labels zur Designtime aufs Formular gepackt. Man kann aber noch 100 andere dazupacken, ohne dass auch nur eine einzige Zeile Code geändert werden müsste. [/edit]

[Gutelo]

Nur dass bei dieser Methode jedem item der RadioGroup genau eine Groupbox eindeutig zugeordnet ist. Ich muss jedoch jedem Radiogroup item eine gewisse Teilmenge aus der Menge aller Groupboxen zuweisen. Aus diesem Grund bringt die ObjectList keine wirklichen Vorteile.