MouseMove außerhalb

[Jean312]

Hallo an die Programmierer-Gilde,

ich stehe vor einem "kleinen" Problem und weiß einfach nicht weiter.

Ich möchte gern die Funktion wie beim "autmatischen Ausblenden der Taskleiste" in Windows nachbilden.
Über das MouseMove- und MouseLeave-Ereignis habe ich schon viele Versuche gestartet, die mich aber nicht zufrieden stellen.

Ich kann im Form einen Bereich definieren, wo das MouseMove-Ereignis gut funktioniert. Leider kann ich keinen großen Rand lassen (max. 1-2 Pixel), weil ich nicht den Platz dafür habe und desweiteren es auch unschön aussehen würde, wenn ich einen zu großen Rand stehenlassen müsste.

In einem Forum habe ich gelesen, dass man das auch über eine Win-Message lösen kann. Ich habe schon das heilige Orakel befragt, aber eine Lösung (Beispiel) nicht gefunden. Ich bin kein Profi und habe leider keinen Einblick im Umgang mit Win-Message.

Das Problem in meiner Anwendung ist, dass das Ausblenden nicht funktioniert, wenn ich die Maus zu schnell über den Bereich ziehe, wo das Ausblenden aufgerufen wird. Bei der Taskleiste von Windows funktioniert das, egal wie schnell ich die Maus bewege.

Hat jemand eine Lösung? :roll:

Vielen Dank schon im Voraus.

LG, Jean

[davtix]

Setze einen Timer mit dem Intervall auf 5
Mit dem prüfst du die mausposition auf dem gewünschten Feld

Delphi-Quellcode:

if (mouse.cursorpos.x > 100) and (mouse.cursorpos.x < 300) and (mouse.cursorpos.y>200) and(mouse.cursorpos.y<300) then show(True) Else show(False)

So hab ich das ein und ausblenden gemacht

[Jean312]

Danke für die schnelle Antwort. Das werde ich auf jeden Fall mal versuchen. :o

[davtix]

http://www.delphi-treff.de/tipps/sys...einem-control/

[Mavarik]

WMMouseMove

[stahli]

aus einem älteren Projekt von mir:

Delphi-Quellcode:

function IsMouseOverControl(const ctrl: TControl): boolean;
var
  sr: TRect;
begin
  sr := Rect(ctrl.ClientToScreen(Point(0, 0)), ctrl.ClientToScreen(Point(ctrl.Width, ctrl.Height)));
  result := PtInRect(sr, Mouse.CursorPos);
end;

procedure TFormSettingKo.TimerZoomTimer(Sender: TObject);
var
  YD, XD, YG: Integer;
  SY, Y: Integer;
  F: Boolean;
begin
  YD := odDesignerKo.Top + odDesignerKo.Height;
  XD := odDesignerKo.Left;
  YG := GroupBoxZoom.Top - 12;
  SY := GroupBoxZoom.Height;
  GroupBoxZoom.Parent := odDesignerKo.Parent;
  GroupBoxZoom.Left := XD;
  Y := YD - YG;
  if (IsMouseOverControl(GroupBoxZoom)) and (IsMouseOverControl(Self)) then
    begin
      F := Y <> SY;
      Y := Min(Y, SY);
      if F then
        begin
          GroupBoxZoom.Width := Round(200 * (Y / SY));
          TimerZoom.Interval := 1;
          Inc(Y);
        end
      else
        TimerZoom.Interval := 1000;
      GroupBoxZoom.Top := YD - Y + 12;
      GroupBoxZoom.Left := XD;
    end
  else
    begin
      F := Y <> 12;
      Y := Max(Y, 12);
      if F then
        begin
          GroupBoxZoom.Width := Round(40 * (Y / 12));
          TimerZoom.Interval := 1;
          Dec(Y);
        end
      else
        TimerZoom.Interval := 1000;
      GroupBoxZoom.Top := YD - Y + 12;
      GroupBoxZoom.Left := XD;
    end;
  CheckBoxZoomAuto.Visible := GroupBoxZoom.Width > 60;
  GroupBoxZoom.Visible := True;
  GroupBoxZoom.BringToFront;
end;

[Bummi]

Statt eines Timer könntest Du auch einen MouseHook verwenden.

Delphi-Quellcode:

unit Unit3;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs;

type
  TForm3 = class(TForm)
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;

var
  Form3: TForm3;

implementation

{$R *.dfm}

var
  HookHandle: Cardinal;

Type
  tagMSLLHOOKSTRUCT = record
    POINT: TPoint;
    mouseData: DWORD;
    flags: DWORD;
    time: DWORD;
    dwExtraInfo: DWORD;
  end;

  TMSLLHOOKSTRUCT = tagMSLLHOOKSTRUCT;
  PMSLLHOOKSTRUCT = ^TMSLLHOOKSTRUCT;

function LowLevelMouseProc(nCode: Integer; wParam: wParam; lParam: lParam): LRESULT; stdcall;
var
  Delta: Smallint;
begin
  if (nCode >= 0) then
  begin
    if PMSLLHOOKSTRUCT(lParam)^.POINT.Y > (Screen.Height - 100) then
      Form3.Height := 100
    else
      Form3.Height := 0;
  end;
  Result := CallNextHookEx(HookHandle, nCode, wParam, lParam);
end;

function InstallMouseHook: Boolean;
begin
  Result := False;
  if HookHandle = 0 then
  begin
    HookHandle := SetWindowsHookEx(WH_MOUSE_LL, @LowLevelMouseProc, hInstance, 0);
    Result := HookHandle <> 0;
  end;
end;

procedure TForm3.FormCreate(Sender: TObject);
begin
  Height := 100;
  BorderStyle := bsNone;
  Color := clBlue;
  Align := alBottom;
  InstallMouseHook;
end;

procedure TForm3.FormDestroy(Sender: TObject);
begin
  if HookHandle <> 0 then
    UnhookWindowsHookEx(HookHandle);
end;

end.

[Jean312]

Hallo liebe Leute,

wow, bin erst einmal mächtig geplättet. Danke für die vielen Anregungen. Die werde ich mir in den nächsten Tagen auch gleich vornehmen.
Ich finde es super, wie einem im Forum geholfen wird.

Viele Grüße,

Jean :thumb: