Fenster zur Laufzeit in einer Klasse - Fehler bei FREE

[TERWI]

Moin zusammen !
Ich bastle grade an meinem Universal-Logger herum. Wenn er fertig (und vor allem fehlerfrei) ist stelle ich den gerne hier ein.

Dieser besteht aus einer Klasse (keine Form !), beeinhaltet aber u.a. eine Form, die ich ggf. gleich beim Erzeugen des Loggers (im constructor) selbst mit erstelle oder bei Bedarf zur Laufzeit erzeuge und auch wieder freigebe - oder - bzw. prüfe ob beim Beenden der Logger-Class (im dstructor) das Fenster noch vorhanden ist.

Starten des Loggers mit Fenster oder erzeugen des Fensters zur Laufzeit, bzw. (mehrmals) wieder freigeben/zerstören (und auch wieder erzeugen) ist kein Problem ! Keinerlei Fehlermeldungen.

Aber:
Ist ein Fenster beim beenden des Loggers erzeugt/offen (egal, ob sichtbar oder nicht), bekomme ich folgende Fehlermeldung:
Access violation at address 00000000. Read of address 00000000
Ist kein Fenster (mehr) vorhanden, gibt's auch kein Gemecker.
Warum ?

Man könnte vermuten, FLOGWIN (so heisst die var) ist nicht mehr zugewiesen.
Prüfe ich im destructor mit if Assigned(FLOGWIN) then FLOGWIN.Free; kommt der gleiche Fehler.
Lasse ich FLOGWIN.Free einfach weg, scheint alles 'gut'. Frgat sich nur, was da im Speicher hängenbleibt ?!

Hat da mal jemand eine Erklärung für mich ?

Ich erzeuge u.a. zur Laufzeit auch noch eine TStringList und ein TFileStream.
Diese beiden 'beschweren' sich in keiner Weise, wenn ich sie mit Free im destructor des Loggers freigebe.

[Bernhard Geyer]

Ich tipp mal darauf das von Windows dein Fenster "gefreet" wird und du das einfach nicht mit bekommst.
Du solltest die entweder ins OnDestroy-Event hängen oder gleich als Notifier registrieren.

[TERWI]

Hmm, war ja ne Idee wert - hab ich den Logger mal sich selbst loggen lassen (wo es geht).
Hier der LOG von:
- 2x mal Fenster erzeugen/freigeben
- 1x Fenster erzeugen
- Logger beenden

Code:

destructor TLOG.Destroy;
begin
  FOnDestroy := true;     // das scheint absolut nicht zu interessieren im OnDesrtoy des Fensters
  SetLogWin(false);       // ..... hier schon
  if Assigned(FLOGWIN) then FLOGWIN.Free;        // FEHLER, wenn nicht ausmarkiert !
  SetLogFile(false);      
  ...
  inherited destroy;
end;

Das LOG:

Code:

[18:31:25:640]  [LOGGER - MAIN]: .... Logger created
[18:31:29:171]  [LOGGER - SetLogWin = true]: create
[18:31:29:187]  [LOG_WIN - OnCreate]: ....
[18:31:38:671]  [LOGGER - SetLogWin = false]: Destroy manually
[18:31:38:671]  [LOG_WIN - OnDestroy]: Destroy manually
[18:31:41:859]  [LOGGER - SetLogWin = true]: create
[18:31:41:859]  [LOG_WIN - OnCreate]: ....
[18:31:45:875]  [LOGGER - SetLogWin = false]: Destroy manually
[18:31:45:875]  [LOG_WIN - OnDestroy]: Destroy manually
[18:31:51:859]  [LOGGER - SetLogWin = true]: create
[18:31:51:859]  [LOG_WIN - OnCreate]: ....
[18:31:54:765]  [LOG_WIN - OnDestroy]: Destroy manually
[18:31:54:765]  [LOGGER - SetLogWin = false]: Destroy in destructor

Das letzte 'Destroy manually' kommt aus dem OnDestroy des Fensters - und zwar vor dem Aufruf der eigentlichen Routine 'SetLogWin(false)' !

Für mich macht das den Eindruck, als wenn der Destructor der Loggers selbst das Fenster schon gleich beim Aufruf zumacht - wenn es denn noch da ist.
FLOGWIN ist dann aber nicht NIL.

.... sehr eigenartig.

[Sir Rufo]

Wenn du

Delphi-Quellcode:

FLOGWIN

nicht auf

Delphi-Quellcode:

nil

setzt, dann wird das auch nicht den Wert annehmen. Es gibt da keine Automatik.

Helfen kann FreeAndNil

[TERWI]

.... ist schon klar, Sir Rufo. 8-)
Das mache ich ja auch in der Routine SetLogWin(false), weil ich im Programm auf Assigned zum Neuerstellen mit SetLogWin(true) abfrage.

Nur wieso kommt im OnDestroy der Logger-Klasse ausgerechnet die Freigabe des Fenster VOR dem eigentlichen Aufruf zum Entfernen ????
Beim Freigeben der Stringliste und des TFileStrams klappt das ja auch ....

[Uwe Raabe]

Zeig doch mal, wie du das Form erzeugst.

[TERWI]

Gerne, Uwe. In Auszügen mal die Logger-Klasse. Sonst wird's zu lang, der Rest funzt ja.

Code:

type
......
  TLOGWIN = class(TForm)
    lb_LOG   : TListBox;
    cb_W2Log : TCheckBox;
    cb_AOT   : TCheckBox;
    btn_Hide : TBitBtn;
    procedure btn_HideClick(Sender: TObject);
  end;
  ......
  TLOG = class
  protected
    .....
    FOnMessageLock : TBCCritSec;
    FLogList       : TStringList;  // internal list of messages
    FLogTimer      : TTimer;       // internal timer to read from list
    FLOGWIN        : TLOGWIN;      // the Logger-Window
    FFileStream    : TFileStream;  // write the log-file....
    .....
    procedure  SetLogWin(Mode : boolean);
  public
    constructor Create(APath, AName : string; WinShow, FileLog, WriteOver : boolean);
    destructor  Destroy; override;
    procedure   Log(AModul, AFunc, AText : string);
  published
    ... 
    property LogFile   : boolean read FLogFile   write SetLogFile;
    property ShowWin   : boolean read FShowWin   write SetLogWin;
    ... 
  end;

constructor TLOG.Create(APath, AName : string; WinShow, FileLog, WriteOver : boolean);
var
  ....
begin
  inherited Create;
  ....
  // create the filename for read/write INI-file
  ....
  // set several var's as default if INI_read fails:
  ....
  // read INI-file, if existing ! ... maybe overwrting setted var's ! see above
  ....
  // init Timer
  FLogTimer          := TTimer.Create(Application);  
  FLogTimer.Enabled  := false;   // true if something to display / write
  FLogTimer.Interval := 250;     // 250ms should be fast enough
  FLogTimer.OnTimer  := OnTimer;
  // only internal
  FOnMessageLock := TBCCritSec.Create;
  FLogList       := TStringList.Create;                // a 'must have'
  FLOGWIN        := NIL;
  FFileStream    := NIL;                               // no file open
  ....
  // now initalize window and / or filewriter
  SetLogWin(FShowWin);      // opens window, if true
  SetLogFile(FLogFile);     // opens file, if true
  FLogTimer.Enabled  := true;
  FOnDestroy         := false;
end;

destructor TLOG.Destroy;
begin
  FOnDestroy := true;
  SetLogWin(false);       // closes window, if open
  if Assigned(FLOGWIN) then FLOGWIN.Free;
  SetLogFile(false);      // closes file, if open
  ....
  FLogTimer.Enabled := false;
  FLogTimer.Free;
  FLogList.Free;
  FOnMessageLock.Free;
  INI_write;
  inherited destroy;
end;

......

procedure TLOG.SetLogWin(Mode : boolean);
begin
  if NOT Assigned(FLOGWIN) then   // no window open / created
  begin
    if Mode then                  // we want to open / create it
    begin
      FLOGWIN         := TLOGWIN.Create(Application);
      FLOGWIN.Visible := true;        // first make visible ...
      FLOGWIN.Top     := FWinTop;     // then set pos & size !
      FLOGWIN.Left    := FWinLeft;
      FLOGWIN.Width   := FWinWidth;
      FLOGWIN.Height  := FWinHeight;
      if FWinOnTop then
        FLOGWIN.FormStyle := fsStayOnTop
      else
        FLOGWIN.FormStyle := fsNormal;
      FLOGWIN.Caption := FAppName + ' - LOGGER';
      FShowWin        := true; 
    end;
  end
  else                            // window is open / created
  begin
    if NOT Mode then              // we want to close / destroy it
    begin
      FWinTop    := FLOGWIN.Top;    // remind position
      FWinLeft   := FLOGWIN.Left;
      FWinWidth  := FLOGWIN.Width;  // remind size
      FWinHeight := FLOGWIN.Height;
      if NOT FOnDestroy then          // little helper doesnt work !
      begin
        FLOGWIN.Free;
        FLOGWIN  := NIL;
      end;
      FShowWin   := false; 
    end;
  end;
end;

Ich hoffe, "man" kann da ein wenig durchblicken !?

Noch mal als Anmerkung:
SetLogWin(true/false) kann ich vom Hauptprogramm x-mal aufrufen. Kein Thema ....
Der Aufruf SetLogWin(false) in LOG.Destroy geht immer in die Hose.
Auch if Assigned(FLOGWIN) then FLOGWIN.Free.

[Sir Rufo]

Du delegierst die Lifetime von dem Fenster an

Delphi-Quellcode:

Application

.

Wenn du also die Anwendung beendest, dann wird auf das Objekt (also die Form) auf das FLogWin referenziert aus dem Speicher geworfen, aber die Variable nicht auf nil gesetzt ;)

Darum der Zugriffsfehler

Lösung:

Delphi-Quellcode:

...
FLOGWIN        := TLOGWIN.Create( nil );
...

Ach ja, beim Timer wird dich aus dem gleichen Grund derselbe Fehler ereilen ;)

[TERWI]

Sir Rufo: Prost ! Ich hab mal ein Bierchen für dich mit aufgemacht und noch nen Eierlikör dazu eingeschenkt. :dancer: :hello:

Ich dachte, ich kenne seit vielen Jahren Delphi auch vieles, aber das war mir in der Art noch nicht bewusst.
Ausprobiert (auf NIL gesetzt) und Ruhe im Karton !
Jetzt wo ich es weiss, ist das in etwa so wie damals mit (ungültigen) Strings via PostMessage schicken. :witch:

Nun denn:
Ich danke dir auf jeden Fall für diese neue Erkenntniss, welche mir bei früheren Problemen sicher auch schon hätte helfen können.
... bin absolut begeistert, dass das nach Anfrage in wenigen Stunden gelöst wurde.

Meine Frau hat heute lecker Frankfurter Kranz gemacht - darf ich dir ein paar Stücke mailen ? :mrgreen: