Record mit PChars aus DLL befüllen lassen

[DeddyH]

Es gibt ja API-Funktionen, denen man eine Struktur übergibt, welche befüllt werden soll. Diese kann auch Strings (eigentlich PChars) beinhalten. So etwas möchte ich auch schreiben, bin aber ein wenig durcheinander, was die Speicherverwaltung betrifft. Angenommen, wir haben folgenden Record:

Delphi-Quellcode:

type
  PTestDataA = ^TTestDataA;
  TTestDataA = packed record
    Number: integer;
    AString: PAnsiChar;
  end;

In meinem jetzigen Teststadium mache ich in der DLL das hier:

Delphi-Quellcode:

procedure FillDataA(Data: PTestDataA); stdcall;
var
  s: AnsiString;
  sl: TStringlist;
begin
  if Assigned(Data) then
    begin
      Data^.Number := 42;
      sl := TStringlist.Create;
      try
        sl.Add('Eins');
        sl.Add('Zwei');
        sl.Add('Drei');
        sl.Add('Vier');
        sl.Add('Fünf');
        sl.Add('Sechs');
        sl.Add('Sieben');
        sl.Add('Acht');
        sl.Add('Neun');
        sl.Add('Zehn');
        s := AnsiString(sl.Text);
        Data^.AString := AnsiStrAlloc(Length(s));
        StrPCopy(Data^.AString, s);
      finally
        sl.Free;
      end;
    end;
end;

Aufruf innerhalb der Echse:

Delphi-Quellcode:

procedure TFormTest.ButtonFillClick(Sender: TObject);
var
  Data: TTestdataA;
begin
  FillDataA(@Data);
  ShowMessage(Data.AString);
end;

Damit wurde der Speicher für den PAnsiChar innerhalb der DLL reserviert. Wie gebe ich den denn wieder frei und wo? Oder geschieht das automatisch mittels irgendwelcher Compiler-Magic? Ich komme auf keinen grünen Zweig, möglicherweise funktioniert das ja überhaupt nicht so, wie ich das gern hätte. Kann mich mal jemand erleuchten?

[uligerhardt]

Einfach in die DLL eine

Delphi-Quellcode:

procedure ClearDataA(Data: PTestDataA); stdcall;

packen, die das Gegenstück zu AnsiStrAlloc aufruft?
Würde dann so verwendet werden:

Delphi-Quellcode:

procedure TFormTest.ButtonFillClick(Sender: TObject);
var
  Data: TTestdataA;
begin
  FillDataA(@Data);
  try
    ShowMessage(Data.AString);
  finally
    ClearDataA(@Data);
  end;
end;

[DeddyH]

Hallo Uli,

daran habe ich auch schon gedacht, war nur nicht sicher, ob das nötig ist. Da es aber auf keinen Fall schaden kann, werde ich das wohl so machen.

Danke Dir :thumb:

[uligerhardt]

Zitat:

Zitat von DeddyH (Beitrag 1204565)

daran habe ich auch schon gedacht, war nur nicht sicher, ob das nötig ist.

Hab sowas ehrlich gesagt noch nie ausprobiert, aber wenn du mit rohen Zeigern (nicht irgendwelche Delphi-Strings) hantierst, würde es mich sehr wundern, wenn da automatisch aufgeräumt werden würde (außer bei Prozessende :mrgreen:).

Und mit der ClearDataA-Methode hast du alles schön ordentlich an die "richtige" Stelle gepackt - AnsiStrAlloc neben AnsiStrDispose (?), FillDataA neben ClearDataA - so würde ich es haben wollen. :lol:

[DeddyH]

Auszug aus meiner Wrapper-Unit:

Delphi-Quellcode:

procedure FillDataA(Data: PTestDataA); stdcall;
  external 'TestDLL.dll' name 'FillDataA';

procedure FillDataW(Data: PTestDataW); stdcall;
  external 'TestDLL.dll' name 'FillDataW';

procedure FillData(Data: PTestData); stdcall;
  external 'TestDLL.dll' name {$IFDEF UNICODE}'FillDataW'{$ELSE}'FillDataA'{$ENDIF};

procedure ClearDataA(Data: PTestDataA); stdcall;
  external 'TestDLL.dll' name 'ClearDataA';

procedure ClearDataW(Data: PTestDataW); stdcall;
  external 'TestDLL.dll' name 'ClearDataW';

procedure ClearData(Data: PTestData); stdcall;
  external 'TestDLL.dll' name {$IFDEF UNICODE}'ClearDataW'{$ELSE}'ClearDataA'{$ENDIF};

;)

[uligerhardt]

Ich würde vielleicht den Parameter per Referenz übergeben:

Delphi-Quellcode:

procedure FillDataA(var Data: TTestDataA); stdcall;

weil du (vermutlich) nicht

Delphi-Quellcode:

nil

übergeben darfst. Ist aber Geschmackssache.

[DeddyH]

Naja, es ist ja nur ein erster Test, außerdem prüfe ich innerhalb der Routinen als Erstes auf nil. Allerdings könnte man immer noch einen wilden Zeiger übergeben, vermutlich werde ich das dann später in der "heißen" DLL besser auf Variablenparameter umstellen. Thx again.