![]() |
OnChange o.ä. für Speicheraufforderung
Hallo zusammen
Ich habe eine immer umfangreicheres Projekt und ich möchte eine Funktion realiseren, wie man sie von Word o.ä. kennt: Sobald der Benutzer etwas an den verwendeten Daten ändert, soll u.ä. in der Caption ein Sternchen an den Namen angehängt werden und vor dem Beenden eine Speicheraufforderung kommen. Ohne etwas geändert zu haben, soll das natürlich nicht passieren. Die Daten selbst liegen in einer Eigenen Klasse mit einigen Read und Write Methoden. Jetzt dachte ich zum Beispiel an ein onChange - Ereignis, das triggert, wenn Daten verändert werden:
Delphi-Quellcode:
Leider wird aber nichts getriggert, wenn ich die Company.Edit ausführe. Dhaer die Frage: Ist das überhaupt der richtige Weg, wo liegt der Fehler, geht das auch anders?
//Die Deklarationen
type TValueChange = procedure of object; TCompany = Class Private ... Public OnChange : TValueChange; ... procedure Edit(CName : String; CNFltPa : Integer); ... end; //Eine der Prozeduren, die das OnChange auslösen sollen procedure TCompany.Edit(CName : String; CNFltPa : integer); begin FName := CName; FNFltPa := CNFltPa; if Assigned(OnChange) then OnChange; end; //Und in der Main die Zuweisung procedure TForm1.CreateCompany(CName : String; CNFltPa : integer); begin Company := TCompany.Create(cName, cNfltPa); Company.OnChange := @Unsaved; end; procedure TForm1.Unsaved; begin DataChanged := true; UpdateForm; end; Es gibt relativ viele Möglichkeiten, etwas an den Daten zu ändern, daher möchte ich "Form1.Unsaved" nicht an jeder dieser Stellen in der Main aufrufen. Da dies mein erstes großes Projekt mit Pascal/Delphi ist, ist mein Repertoir noch nicht besonders groß, daher bin ich um jeden Tip dankbar. |
AW: OnChange o.ä. für Speicheraufforderung
Ist prinzipiell schon der richtige Weg. Normalerweise wird das OO konform leicht anders umgesetzt:
Delphi-Quellcode:
TCompany = class
private FOnChange: TNotifyEvent; public property OnChange read FOnChange write FOnChange; end; .. if Assigned(FOnChange) then FOnChange;
Delphi-Quellcode:
Sollte eigentlich funktionieren. Sehe zwar in deinem Code auch keinen Fehler, aber vielleicht hat Delphi da ja irgendwo eine Macke, wenn du es nicht korrekt über eine property machst.
TForm1 = class(TForm)
.. private procedure OnChange(Sender: TObject); end; .. MyCompany.OnCange := OnChange; |
AW: OnChange o.ä. für Speicheraufforderung
Da im Threadtitel FreePascal steht, vermute ich, es geht um Lazarus. Den folgenden Code habe ich gerade eben unter Lazarus 1.1 ausprobiert (komplette Unit):
Delphi-Quellcode:
So sollte das vermutlich in etwa aussehen, bei mir hat das wie erwartet funktioniert. Die "Exits" hat Lazarus BTW selbst eingefügt, ich habe es dabei belassen, falls jemand meckern möchte *g*.
unit Unit1;
{$mode objfpc}{$H+} interface uses Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, StdCtrls; type { TTestClass } TTestClass = class private FName: string; FFirstname: string; FOnChanged: TNotifyEvent; FOnSaved: TNotifyEvent; procedure Change; procedure SetName(AValue: string); procedure SetFirstname(AValue: string); public procedure Save; property Name: string read FName write SetName; property Firstname: string read FFirstname write SetFirstname; property OnChanged: TNotifyEvent read FOnChanged write FOnChanged; property OnSaved: TNotifyEvent read FOnSaved write FOnSaved; end; { TForm1 } TForm1 = class(TForm) Button1: TButton; Button2: TButton; Button3: TButton; procedure Button1Click(Sender: TObject); procedure Button2Click(Sender: TObject); procedure Button3Click(Sender: TObject); procedure FormCreate(Sender: TObject); procedure FormDestroy(Sender: TObject); private { private declarations } FTest: TTestClass; procedure DoOnTestChanged(Sender: TObject); procedure DoOnTestSaved(Sender: TObject); public { public declarations } end; var Form1: TForm1; implementation { TForm1 } procedure TForm1.FormCreate(Sender: TObject); begin FTest := TTestClass.Create; FTest.OnChanged := @DoOnTestChanged; FTest.OnSaved := @DoOnTestSaved; end; procedure TForm1.Button1Click(Sender: TObject); begin FTest.Name := 'Hanswurst'; end; procedure TForm1.Button2Click(Sender: TObject); begin FTest.Firstname := 'Pumuckl'; end; procedure TForm1.Button3Click(Sender: TObject); begin FTest.Save; end; procedure TForm1.FormDestroy(Sender: TObject); begin FTest.Free; end; procedure TForm1.DoOnTestChanged(Sender: TObject); begin Caption := Name + '*'; end; procedure TForm1.DoOnTestSaved(Sender: TObject); begin Caption := Name; end; {$R *.lfm} { TTestClass } procedure TTestClass.Change; begin if Assigned(FOnChanged) then FOnChanged(self); end; procedure TTestClass.SetName(AValue: string); begin if FName=AValue then Exit; FName:=AValue; Change; end; procedure TTestClass.SetFirstname(AValue: string); begin if FFirstname=AValue then Exit; FFirstname:=AValue; Change; end; procedure TTestClass.Save; begin if Assigned(FOnSaved) then FOnSaved(self); end; end. |
AW: OnChange o.ä. für Speicheraufforderung
Zitat:
Delphi-Quellcode:
Company.OnChange := Unsaved;
|
AW: OnChange o.ä. für Speicheraufforderung
Das mag Lazarus im objfpc-Mode aber gar nicht.
|
AW: OnChange o.ä. für Speicheraufforderung
Zitat:
|
AW: OnChange o.ä. für Speicheraufforderung
Nunja, deshalb steht das @ ja auch in meinem obigen Code :zwinker:
|
AW: OnChange o.ä. für Speicheraufforderung
Funktioniert, vielen Dank!
|
Alle Zeitangaben in WEZ +1. Es ist jetzt 12:40 Uhr. |
Powered by vBulletin® Copyright ©2000 - 2025, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz