Oracle Session und Query in Thread?

[mcinternet]

Hallo,

ist es möglich die Oracle Session und Abfrage in einen Thread auszulagern, damit die Applikation während des Zugriffs nicht einfriert?

Bisher habe ich das in thread.execute ausgelagert, war aber leider nicht von Erfolg gekrönt.

Gruss

Mc

[Bernhard Geyer]

Zitat:

Zitat von mcinternet (Beitrag 1185829)

Bisher habe ich das in thread.execute ausgelagert, war aber leider nicht von Erfolg gekrönt.

Definieren Erfolg! Absturz/Anwendung blockiert/...

Startest du denn auch den Thread korrekt? Zeig mal deine Verwendung dieses Threads im Quellcode

[Bummi]

Ich kenne die ODAC's nicht, kann es sein dass mglw. ein benötigtes Coinitialize fehlt?

[mcinternet]

Hier mal der Quelltext

Delphi-Quellcode:

  TMyThread = class(TThread)
     procedure execute; override;
  end;

var
  FrmMain: TFrmMain;

  MThread : TMyThread;

implementation

{$R *.dfm}

procedure TFrmMain.btn_disconnectClick(Sender: TObject);
begin
  OraSession.Disconnect;
  MThread.Terminate;
end;

procedure TFrmMain.But_connectClick(Sender: TObject);
begin
  MThread := TMyThread.Create;
  MThread.FreeOnTerminate := true;
  MThread.execute;
end;

procedure TMyThread.Execute;
begin
   FrmMain.OraSession.Connect;
   FrmMain.fncsleep.ParamByName('i_seconds').AsInteger:=4;   // Funktion die einfach nur x-Sek. nix tut
   FrmMain.fncsleep.Execute;                                 // (Sleep auf Oracle Seite) - Die Form darf dabei nicht einfrieren
end;

Gruss Mc

[Bernhard Geyer]

Du verwendest keinen Thread wenn du die Execute-Methode direkt aufrufst!
Und von einem Thread darfst du auch nicht auf GUI/VCL-Komponenten der Hauptanwendung zugreifen.
Du musst in deinem Thread eine eigene Connect + Query-komponenten erstellen und dann diese im Thread verwenden.

[mcinternet]

Zitat:

Zitat von Bernhard Geyer (Beitrag 1185837)

Du verwendest keinen Thread wenn du die Execute-Methode direkt aufrufst!
Und von einem Thread darfst du auch nicht auf GUI/VCL-Komponenten der Hauptanwendung zugreifen.
Du musst in deinem Thread eine eigene Connect + Query-komponenten erstellen und dann diese im Thread verwenden.

Danke - hatte sich ein Denkfehler zum Thema Threadhandling eingeschlichen!
Problem behoben

Gruss
Mc

[Bummi]

ich kann nur einen möglichen Weg mit ADO zeigen, aber vielleicht hilft es Dir trotzdem

Delphi-Quellcode:

unit TEST_U1;
// Thomas Wassermann
// Nur ein kleines Beispiel
//!!! Threadproperties nur im OnThreadTerm verwenden nicht abgesichert
interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, DB, ADODB, StdCtrls, Grids, DBGrids;

type


  TMyThread=Class(TThread)
    private
      FAC:TAdoConnection;
      FADS:TadoDataset;
      FConnectionString :String;
      FSQL:String;
      FErrorString: String;
      FStream: TStringStream;
    public
    Constructor Create(Const ConnectionString,SQL:String;TermProc:TNotifyEvent);overload;
    Destructor Destroy;override;
    Procedure Execute;override;
    Property Dataset:TAdodataset read Fads;
    Property ErrorString:String read FErrorString ;
    Property ResultStream:TStringStream read FStream;
  End;




  TForm3 = class(TForm)
    Button1: TButton;
    ADS: TADODataSet;
    DataSource1: TDataSource;
    DBGrid1: TDBGrid;
    ADOConnection1: TADOConnection;
    procedure Button1Click(Sender: TObject);
  private
    procedure OnThreadTerm(Sender: TObject);
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;

var
  Form3: TForm3;

implementation
uses ActiveX,ComObj,ADOInt;
{$R *.dfm}


procedure TForm3.OnThreadTerm(Sender: TObject);
var
    Stream: TStringStream;
    RS:Variant;
begin
    if TMyThread(Sender).Dataset.Active then
        begin
          RS := CreateOleObject('ADODB.Recordset');
          RS.Open(TStreamAdapter.Create(TMyThread(Sender).ResultStream) as IUnknown);
          Ads.Recordset := IUnknown(RS) as _Recordset;
        end

    else Showmessage(TMyThread(Sender).ErrorString);
end;

procedure TForm3.Button1Click(Sender: TObject);
begin
   TMyThread.Create('Provider=SQLOLEDB.1;Integrated Security=SSPI;Persist Security Info=False;Initial Catalog=TP2003;Data Source=DEVTESTSERV\SQL2005'
                    ,'Select * from Abfragen'
                    ,OnThreadTerm);
end;

{ TMyThread }

constructor TMyThread.Create(const ConnectionString, SQL: String; TermProc: TNotifyEvent);
begin
   inherited Create(false);
   FreeOnTerminate := true;
   OnTerminate := TermProc;

   FConnectionString := ConnectionString;
   FSQL := SQL;
end;

destructor TMyThread.Destroy;
begin
  FAC.Free;
  FADS.Free;
  Fstream.free;
  Couninitialize;
  inherited;

end;

procedure TMyThread.Execute;
begin
   Coinitialize(nil);
   FAC:=TAdoConnection.Create(Application);
   FAC.LoginPrompt := false;
   FAC.ConnectionString := FConnectionString;
   FADS:=TadoDataset.Create(nil);
   FAds.Connection := FAC;
   FADS.CommandText := FSQL;
   FStream := TStringStream.Create('');
   try
   FAds.Open;
   FAds.Recordset.Save(TStreamAdapter.Create(Fstream) as IUnknown,adPersistXML);
   FStream.Position := 0;
   except
     on E:Exception do FErrorString := E.Message;
   end;

end;



end.