CreateMutex läßt mehrfachstart zu...

[Cyberaxx]

Hallo,

mal wieder ein Problemchen und finde dazu leider keine Lösung.

Sitze gerade an einem kleinen Tool weches wenn es gestartet wird eine Übersicht anzeigt.
Wird das Programm mit Parameter /OPEN gestartet soll ein kleines Fenster aufgehen in welches man einen Namen Eintragen kann. Es soll in einer Datenbank speichern wie lange jemand telefoniert hat.

Es funktioniert ohne Parameter schon einmal sehr gut. Wird das Programm gestartet und es existiert bereits eine Instanz, so wird diese in den Vordergrung geholt.

Als Mutex hierfür verwende ich ExctractFileName(Application.ExeName) - "Callist.exe"
Wenn das Programm gestartet wird mit einem Parameter so wird als Mutex bzw sollte als Mutex "Callist.exe#CMD" erstellt werden.
Sollte nun wiederum das Programm mit dem Parameter /OPEN geöffnet werden, soll die Instanz geschlossen werden. Danach eine neue erzeugt werden.
Wird das Programm mit dem Parameter /CLOSE geöffnet so soll nur die Instanz geschlossen werden.

Da es mit dem zweiten Mutex nicht geklappt hat, habe ich ebenfalls nur "Callist.exe" als Mutex verwendet.
Die exe habe ich in ein anderes Verzeichnis kopiert und gestartet ohne parameter. Starte ich aus Delphi heraus noch einmal die exe, bekommt sie den Focus. Klappt also...
Wenn ich allerdings aus Delphi heraus mit dem Parameter /OPEN starte, wird ein neuer Mtex erstellt mit dem Namen "Callist.exe" und einfach eine neue Instanz gestartet, das verstehe ich nicht...

Delphi-Quellcode:

procedure Instance();
  var
    Mutex: THandle;
    Window: THandle;
    MutexName: string;
    WindowTime: TDateTime;
begin
  WindowTime := Now; // Start der Instanz merken
  MutexName := ExtractFileName(ParamStr(0)); // Callist.exe
  if ParamCount = 0 then begin
    Mutex := CreateMutex(nil, True, PChar(MutexName));
    if (Mutex <> 0) and (GetLastError <> ERROR_ALREADY_EXISTS) then begin
      Application.Initialize;
      Application.Title := APPLICATION_TITLE;
      Application.MainFormOnTaskbar := True;
      Application.CreateForm(TMain, Main);
      Application.Run;
    end
    else begin
      Window := FindWindow(nil, APPLICATION_TITLE);
      if Window <> 0 then begin
        Windows.ShowWindow(Window, SW_Normal);
        Windows.SetForegroundWindow(Window);
      end;
    end;
  end // bis hierhin klappt alles
  else begin
    if UpperCase(ParamStr(1)) = '/OPEN' then begin
      Mutex := CreateMutex(nil, True, PChar(MutexName)); // Mutex Name hat sich nicht geändert, dennoch kein Fehler...
      if (Mutex = 0) and (GetLastError = ERROR_ALREADY_EXISTS) then begin
        Window := FindWindow(nil, APPLICATION_TITLE);
        if Window <> 0 then
          SendMessage(Window, WM_CLOSE, 0, 0);
        repeat
          Sleep(200);
          Window := FindWindow(nil, APPLICATION_TITLE);
        until Window = 0;
      end;
      CreateNewCallApp;
    end
    else if UpperCase(ParamStr(1)) = '/CLOSE' then begin
      SendMessage(Window, WM_CLOSE, 0, 0);
    end;
  end;
end;

begin
  Instance();
end.

Ich weiß nicht wo da der Fehler liegt, hat jemand dazu einen Rat?

[Cyberaxx]

Hm habe gerade auf MSDN gelesen das er erstellt oder geöffent wird.

Wird also wenn bereits eine Instanz läuft das Handle des Mutex immer zurück gegeben und ich muss mich nur auf den GetLastError verlassen?

Habs nun umgestellt. Dachte ich könnte mir einmal das CreateNewCallApp; sparen.
Naja so wird man schlauer.

Die frage bleibt allerdings noch offen. Kann ich mir denn immer sicher gehen so wie ichs dort habe?
Bei einem Beitrag aus der CodeLib wird ja nur auf GetLastError geprüft.

[Zacherl]

Naja prinzipiell gibt es folgende Möglichkeiten:

• CreateMutex schlägt fehl (Result = 0; bedingt durch fehlende Rechte, etc)
• CreateMutex gibt ein Handle zurück und GetLastError ist <> ERROR_ALREADY_EXISTS
• CreateMutex gibt ein Handle zurück und GetLastError ist = ERROR_ALREADY_EXISTS

Ich würde den Check auf hMutex = 0 und GetLastError = ERROR_ALREADY_EXISTS nicht in die selben Abfrage einbauen.

Delphi-Quellcode:

procedure TForm1.MutexCheck;
var
  hMutex: THandle;
begin
  hMutex := CreateMutex(nil, true, 'MutexName');
  if (hMutex = 0) then
  begin
    // kritischer Fehler beim Erzeugen / Öffnen des Mutex
  end else
  begin
    if (GetLastError = ERROR_ALREADY_EXISTS) then
    begin
      // bestehende Instanz kontaktieren
      // ist hier dein Parameter = /OPEN, brauchst du eigentlich nur die alte
      // Instanz schließen. Dadurch, dass du an dieser Stelle schon ein
      // Handle des Mutex geöffnet hast, "müsste" die aktuelle Instanz dann
      // automatisch zur "CallApp" werden.

      // an dieser Stelle könnte man wohl auch noch ein CloseHandle(hMutex)
      // einbauen, fals der Parameter NICHT /OPEN ist
    end else
    begin
      // dies ist die erste Instanz
    end;
  end;
end;

[Cyberaxx]

Danke für die schnelle Antwort.

Ich bin bis ich danach gegoogelt habe immer davon ausgegangen das CreateMutex fehl schlägt wenn er bereits existiert, denn der Mutex kann ja nicht neu erstellt werden.
So schnell wird man schlauer :)

[Zacherl]

Ist mir damals mal mit Events passiert, aber denke mal bei nem Mutex wird das ähnlich ablaufen: Wenn ein UAC elevated Prozess mit Adminrechten einen Mutex mit SecurityAttributes = nil erstellt und man dann mit einem nicht elevated Prozess versucht den Mutex zu öffnen (oder neu zu erstellen), schlägt das ganze mit ERROR_ACCESS_DENIED oder sowas in der Art fehl. In dem Falle ist dann auch das Handle gleich Null.

[rothy]

Im Zusammenhang mit dem Windows Gross/Kleischreibungs-Wischiwaschi bzgl.
Dateinamen bin ich gerade noch in eine andere Falle getappt.

Falls man z.B. eine Verknüfung auf ein Programm aBBa.exe hat, die Datei aber
AbbA.exe heisst, ist Application.ExeName anders wenn das Programm über
die Verküpfung gestartet wird. Das kann vermutlich auch bei Verwendung von
ParamStr(0) vorkommen.

Mutexe sind aber case-sensitiv, ...
-->
MutexName := UpperCase(MutexName); //evtuell empfehlenswert