Propertyeditor für "Path"

[stahli]

Ich habe eine Komponente mit einer Eigenschaft Path (String).
Wie kann ich am leichtesten einen passenden Propertyeditor zur Path-Auswahl zuweisen?

Muss ich den selbst erstellen (ich weiß, wie das geht) oder gibt es nicht doch eine fertige Variante, die das realisiert?
Ein Test mit dem Typ TFileName brachte noch nichts.

Ich hatte gehofft, es gäbe z.B. TPathName mit zugeordnetem Eigenschaftseditor.

[DeddyH]

Darf man nach dem Sinn fragen? Der Pfad kann doch auf jedem Rechner anders sein, falls es um irgendwelche Systempfade gehen sollte.

[stahli]

Ich weise einen Pfad zu, der zur Designtime verwendet wird.
Um das komfortabler zu machen, möchte ich ein Auswahlformular (Propertyeditor) zuweisen.
Ich kann das ohne weiteres selbst machen, hatte aber gedacht, für eine Pfadauswahl müsste es eine fertige Lösung geben...!?

[geskill]

Huhu habe gerade bisschen in den Komponenten gestöbert und TIBDatabaseINI macht genau das was du suchst denke ich. Komisch ist aber, dass intern die property FileName als String deklariert ist oO.

EDIT: sehe gerade du brauchst NUR den Pfad. Hmm ich glaub dann hilft dir dies nicht so viel.

[stahli]

Ja, genau so meinte ich das. Und nur für den Pfad.
Falls niemand eine Idee hat, muss ich es eben mal selbst machen. Ist ja nicht schwer, aber die Arbeit würde ich mir trotzdem gern sparen.

Edit: @geskill
Einen Eigenschaftseditor kann man für einen Typ, eine Klasse und/oder einen Eigenschaftsnamen zuweisen.
Es kann also ein Editor für eine Property Namens FileName der Klasse TMyClass zugewiesen werden, auch wenn die Eiugenschaft ein einfacher String ist.
Oder man kann einen Editor an den Typ TPathName binden, der dann für alle Eigenschaften aller Klassen zugewiesen wird, wenn sie von diesem Typ sind.

[stahli]

*push*
(falls doch noch jemand eine Idee hat)

[Stevie]

Folgende Unit in ein Designtime Package und du hast für die InitialDir property des TOpenDialog einen Ordnerauswahldialog.

Delphi-Quellcode:

unit PropertyPathEditor;

interface

uses
  DesignEditors,
  DesignIntf;

type
  TPathProperty = class(TStringProperty)
  public
    function GetAttributes: TPropertyAttributes; override;
    procedure Edit; override;
  end;

procedure Register;

implementation

uses
  Dialogs,
  FileCtrl;

procedure Register;
begin
  RegisterPropertyEditor(TypeInfo(string), TOpenDialog, 'InitialDir', TPathProperty);
end;

{ TPathProperty }

procedure TPathProperty.Edit;
var
  LPath: string;
begin
  LPath := GetValue();
  if SelectDirectory('', '', LPath, [sdNewFolder, sdNewUI, sdValidateDir]) then
  begin
    SetValue(LPath);
  end;
end;

function TPathProperty.GetAttributes: TPropertyAttributes;
begin
  Result := inherited GetAttributes + [paDialog];
end;

end.

[stahli]

Ok danke.
Ich dachte, ich hätte einen Typ (ähnlich TPathName) übersehen, für den dies standardmäßig registriert ist...

[Stevie]

Zitat:

Zitat von stahli (Beitrag 1117180)

Ok danke.
Ich dachte, ich hätte einen Typ (ähnlich TPathName) übersehen, für den dies standardmäßig registriert ist...

Kannste selber machen.

Delphi-Quellcode:

type
  TPathName = type string;

....

procedure Register;
begin
  RegisterPropertyEditor(TypeInfo(TPathName), nil, '', TPathProperty);
end;

Sollte auch kein Problem sein, den Code im Edit so zu ändern, dass ein relativer Pfad gespeichert wird, so dass zum Beispiel ein anderer Entwickler oder du selber auf einem anderen Rechner oder in einem anderen Projektverzeichnis immernoch damit arbeiten können.