Charformat nach CFM_SUPERSCRIPT wieder normal setzten?

[user64629]

Hallo Forum,
ich verwender in meinem Programm die Funktion CFM_SUPERSCRIPT um Text hochzustellen. Doch wie krieg ich danach den Text wieder normal?
Unter http://msdn.microsoft.com/de-de/libr...(v=VS.85).aspx finde ich nur: "To turn off a formatting attribute, set the appropriate value in dwMask but do not set the corresponding value in dwEffects. For example, to turn off italics, set CFM_ITALIC but do not set CFE_ITALIC."
Doch das scheint nicht zu klappen...
Hier mal mein Code:

Delphi-Quellcode:

var Formatierung: TCharFormat2;

procedure TEditor.HochgestelltExecute(Sender: TObject);
begin
 Formatierung.cbSize := SizeOf(Formatierung);
 Formatierung.dwMask := SendMessage(Text.Handle, EM_GETCHARFORMAT, SCF_SELECTION, 0);
 Formatierung.dwMask := CFM_SuperScript;
 if Formatierung.dwMask = CFM_SuperScript
    then Formatierung.dwEffects := CFE_SuperScript;
 SendMessage(Text.Handle, EM_SETCHARFORMAT, SCF_SELECTION, DWORD(@Formatierung));
end;

Wenn ich die Microsoft Hilfe richtig verstanden habe (Englisch ist nicht gerade mein bestes Fach...) frage ich von dem Markierten Text die Eigenschaften .dwMask ab und wenn CFM_SuperScript vorhanden ist, müsste das doch danach gelöscht werden und wenn es nicht vorhanden ist wird es gesetzt oder??? Hab erst vor ein paar Stunde die SendMessage Eigenschaften kennengelernt :-D

Danke für die Hilfe schonmal ;-)

Edit:
Da keiner eine Antwort weiß hab ich auf http://forum.delphi-treff.de/showthr...795#post219795 die gleiche Frage nochmal gepostet.

[user64629]

Okay ich hab mal ein wenig rumgespielt, dabei kam dann das raus:

Delphi-Quellcode:

var Formatierung: TCharFormat2;
 
procedure TEditor.HochgestelltExecute(Sender: TObject);
begin
 Formatierung.cbSize := SizeOf(Formatierung);
 Formatierung.dwMask := SendMessage(Text.Handle, EM_GETCHARFORMAT, SCF_SELECTION, 0);
 if Formatierung.dwMask = CFM_SuperScript
    then Formatierung.dwMask := CFM_SuperScript
    else begin
          Formatierung.dwMask := CFM_SuperScript;
          Formatierung.dwEffects := CFE_SuperScript;
         end;
SendMessage(Text.Handle, EM_SETCHARFORMAT, SCF_SELECTION, DWORD(@Formatierung));
end;

Doch bei der Abfrage

Delphi-Quellcode:

 if Formatierung.dwMask = CFM_SuperScript

Wird immer nur die Else-Anweisung behandelt. Das müsste doch bedeuten, dass in der Anweisung davor

Delphi-Quellcode:

 Formatierung.dwMask := SendMessage(Text.Handle, EM_GETCHARFORMAT, SCF_SELECTION, 0);

der enstprechende Wert der selektierten Textes garnicht als Rückgabewert geliefert wird oder?

[himitsu]

Delphi-Quellcode:

// setzen
Formatierung.dwMask := CFM_SUPERSCRIPT und eventuell noch Anderes;
Formatierung.dwEffects := alles Erlaubte, inklusive CFM_SUPERSCRIPT;

// löschen
Formatierung.dwMask := eventuell noch Anderes, aber kein CFM_SUPERSCRIPT;
Formatierung.dwEffects := alles Erlaubte ohne CFM_SUPERSCRIPT;

Wenn sonst nichts anderes gesetzt ist, dann

Delphi-Quellcode:

// setzen
Formatierung.dwMask := CFM_SUPERSCRIPT;
Formatierung.dwEffects := CFM_SUPERSCRIPT;

// löschen
Formatierung.dwMask := 0;
Formatierung.dwEffects := 0;
// oder
Formatierung.dwMask := 0;
Formatierung.dwEffects := not CFM_SUPERSCRIPT;

[edit]
ich glaub ich hab's falsch verstanden ... ist wohl eher so :gruebel:

Delphi-Quellcode:

// setzen
Formatierung.dwMask := CFM_SUPERSCRIPT;
Formatierung.dwEffects := CFM_SUPERSCRIPT;

// löschen
Formatierung.dwMask := CFM_SUPERSCRIPT;
Formatierung.dwEffects := 0;

// setzen oder löschen
Formatierung.dwMask := CFM_SUPERSCRIPT;
if superscript then 
  Formatierung.dwEffects := CFM_SUPERSCRIPT
else
  Formatierung.dwEffects := 0;

also Mask = der/die Wert(e), welche(r) gesetzt werden soll(en)
und Effects = der neue Wert

[DeddyH]

Vielleicht so?

Delphi-Quellcode:

procedure TFormTest.Hochstellen(Sender: TObject);
var
  Formatierung: TCharFormat2;
begin
  //RichEdit1.SelectAll; war nur zum Testen
  Formatierung.cbSize := SizeOf(Formatierung);
  SendMessage(RichEdit1.Handle, EM_GETCHARFORMAT, SCF_SELECTION,
    integer(@Formatierung));
  Formatierung.dwMask := Formatierung.dwMask or CFM_SUPERSCRIPT;
  Formatierung.dwEffects := Formatierung.dwEffects or CFE_SUPERSCRIPT;
  SendMessage(RichEdit1.Handle, EM_SETCHARFORMAT, SCF_SELECTION,
    integer(@Formatierung));
end;

procedure TFormTest.Aufheben(Sender: TObject);
var
  Formatierung: TCharFormat2;
begin
  //RichEdit1.SelectAll; war nur zum Testen
  Formatierung.cbSize := SizeOf(Formatierung);
  SendMessage(RichEdit1.Handle, EM_GETCHARFORMAT, SCF_SELECTION,
    integer(@Formatierung));
  Formatierung.dwMask := Formatierung.dwMask or CFM_SUPERSCRIPT;
  Formatierung.dwEffects := Formatierung.dwEffects and not CFE_SUPERSCRIPT;
  SendMessage(RichEdit1.Handle, EM_SETCHARFORMAT, SCF_SELECTION,
    integer(@Formatierung));
end;

[user64629]

Okay ich hab einiges probiert, aber es scheint einfach nicht zu klappen. Nochmal zum Verständnis: Ich will einen Button der den Text hochstellt, beziehungsweise wenn er hochgestellt ist soll er ihn wieder normal setzen.
Aber die Abfrage oder der Text hochgestellt ist scheint nicht zu klappen...
Ich hab schon mehreres probiert:

Delphi-Quellcode:

var Formatierung: TCharFormat2;

procedure TEditor.HochgestelltExecute(Sender: TObject);
begin
 Formatierung.cbSize := SizeOf(Formatierung);
 Formatierung.dwMask := SendMessage(Text.Handle, EM_GETCHARFORMAT, SCF_SELECTION, 0);
 Formatierung.dwMask := Formatierung.dwMask or CFM_SUPERSCRIPT;
 if Formatierung.dwMask = CFM_SUPERSCRIPT
    then Formatierung.dwEffects := Formatierung.dwEffects or CFE_SUPERSCRIPT
    else Formatierung.dwEffects := Formatierung.dwEffects and not CFE_SUPERSCRIPT;
 SendMessage(Text.Handle, EM_SETCHARFORMAT, SCF_SELECTION, DWORD(@Formatierung));
end;

oder

Delphi-Quellcode:

var Formatierung: TCharFormat2;

procedure TEditor.HochgestelltExecute(Sender: TObject);
begin
 Formatierung.cbSize := SizeOf(Formatierung);
 Formatierung.dwMask := SendMessage(Text.Handle, EM_GETCHARFORMAT, SCF_SELECTION, 0);
 if Formatierung.dwMask = CFM_SUPERSCRIPT
    then begin
          Formatierung.dwEffects := Formatierung.dwEffects and not CFE_SUPERSCRIPT;
          Formatierung.dwMask := Formatierung.dwMask and not CFM_SUPERSCRIPT;
         end
    else begin
          Formatierung.dwEffects := Formatierung.dwEffects or CFE_SUPERSCRIPT;
          Formatierung.dwMask := Formatierung.dwMask or CFM_SUPERSCRIPT;
         end;
 SendMessage(Text.Handle, EM_SETCHARFORMAT, SCF_SELECTION, DWORD(@Formatierung));
end;

Bei der Anweisung

Delphi-Quellcode:

Formatierung.dwMask := SendMessage(Text.Handle, EM_GETCHARFORMAT, SCF_SELECTION, 0);

scheint einfach nicht der richtige Rückgabewert zu kommen. Woran könnte das liegen?

[DeddyH]

Das liegt daran, dass Du falsch auswertest und anscheinend unsere Posts nicht liest.

[user64629]

Wärest du so nett mir zu sagen wie ich es richtig auswerte? Oder mir zu sagen in welcher Zeile deines Posts das steht? Ich komm jetzt irgendwie nicht drauf wo das Problem liegt...

[DeddyH]

Ich habe nun eine allgemeinere Lösung erstellt. Ich hoffe, die Kommentare sind verständlich.

Delphi-Quellcode:

function ToggleSuperscript(RE: TRichEdit): Boolean;
var
  Formatierung: TCharFormat2;
begin
  if not Assigned(RE) then
    raise Exception.Create('Given RichEdit is not Assigned.');
  (* cbSize-Feld von TCharFormat2 muss vor Abfragen/Setzen befüllt werden *)  
  Formatierung.cbSize := SizeOf(Formatierung);
  (* Aktuelle Formatierung ermitteln *)
  SendMessage(RE.Handle, EM_GETCHARFORMAT, SCF_SELECTION,
    integer(@Formatierung));
  (* Falls der selektierte Text nur teilweise hochgestellt ist, enthält
     das dwMask-Feld das CFM_SUPERSCRIPT-Flag NICHT, daher setzen wir es 
     vorsichtshalber. *)
  Formatierung.dwMask := Formatierung.dwMask or CFM_SUPERSCRIPT;
  (* Nun negieren wir den ermittelten Wert... *)
  Formatierung.dwEffects := Formatierung.dwEffects xor CFE_SUPERSCRIPT;
  (* ...und setzen die neue Formatierung. Kommt 0 zurück, hat das nicht 
     funktioniert. Man kann die Funktion auch noch dahingehend ausbauen,
     dass sie den Fehlercode zurückgibt, dann eben DWORD statt Boolean. *)
  Result := SendMessage(RE.Handle, EM_SETCHARFORMAT, SCF_SELECTION,
    integer(@Formatierung)) <> 0;
end;

[user64629]

Oh Gott, ist ja viel einfacher mit xor :-D Danke für die Hilfe, jetzt klappt es :-) Daran hatte ich nicht gedacht ;-)

[DeddyH]

Dann gib doch bitte im Delphi-Treff Bescheid, dass das Problem gelöst ist, bevor sich da noch jemand unnötigerweise den Kopf zerbricht.