Semitransparente Fenster mittels (Update-)LayeredWindow

[patti]

Hi,

häng hier gerade an einem kleinen Problem. Ich will semitransparente Fenster zeichnen. Dazu setze ich zunächst mein Fenster "Layered":

Delphi-Quellcode:

SetWindowLong(Handle, GWL_EXSTYLE, GetWindowLong(Handle, GWL_EXSTYLE) or WS_EX_LAYERED);
SetWindowPos(Handle, HWND_TOPMOST, 0, 0, 0, 0, SWP_NOMOVE or SWP_NOSIZE); // und OnTop

Ich erzeuge im OnCreate ein Bitmap mit 32-bit-Farbtiefe:

Delphi-Quellcode:

bgBMP := TBitmap.Create;
//
bgBMP.PixelFormat := pf32bit;

Und in der Routine "PaintBMP" geh ich per Scanline das Bitmap durch, färbe jedes Pixel rot und setze den Alpha-Blend-Wert jedes Pixels in Abhängigkeit von der y-Position:

Delphi-Quellcode:

procedure TfrmMain.PaintBMP;
var pBMP : PRGBLine;
var x,y  : integer;
begin
     //--
     bgBMP.Width  := 256;
     bgBMP.Height := 256;
     //
     for y := 0 to 255 do
     begin
          pBMP := bgBMP.ScanLine[y];
          //
          for x := 0 to 255 do
          begin
               pBMP[x].rgbRed      := 255;
               pBMP[x].rgbGreen    := 0;
               pBMP[x].rgbBlue     := 0;
               pBMP[x].rgbReserved := 255-y;
          end;
     end;
     //
     Display;
end;

Es ergibt sich also in diesem Beispiel eine rote Fläche, die nach unten hin "ausfadet" (d.h. der Alpha-Wert nimmt von 255 bis auf 0 ab).

Die Routine "Display" soll dann dieses Bitmap mittels UpdateLayeredWindow auf die Form zeichnen:

Delphi-Quellcode:

procedure TfrmMain.Display;
var blendFunc  : BLENDFUNCTION;
var src   : TPoint;
var Size  : TSize;
begin
     //--
     src := Point(0,0);
     //
     Size.cx := 256;
     Size.cy := 256;
     //
     blendFunc.AlphaFormat         := AC_SRC_ALPHA;
     blendFunc.BlendFlags          := 0;
     blendFunc.BlendOp             := AC_SRC_OVER;
     blendFunc.SourceConstantAlpha := 255;
     //
     UpdateLayeredWindow(Handle, 0, nil, @Size, bgBMP.Canvas.Handle, @src, 0, @blendFunc, ULW_ALPHA);
end;

So weit so gut. Wenn ich das Programm ausführe, scheint im ersten Moment alles zu funktionieren. Das Ergebnis entspricht im ersten Moment genau den Erwartungen (siehe auch Bild im Anhang). Wenn ich im Hintergrund allerdings dunkle Farben habe, dann stimmt das Ergebnis überhaupt nicht mehr, denn dann sind die Transparenzen völlig verkehrt (im Anhang ein Bild mit einfarbig grauem Hintergrund, eigentlich sollte auch hier die rote Fläche von voll sichtbar nach gar nicht sichtbar ausfaden). Bei Schwarz wirkt sich der Effekt noch viel stärker aus, denn da werden alle Pixel in voller Sichtbarkeit in rot dargestellt, ein Verlauf ist dann gar nicht mehr vorhanden.

Entweder steh ich grad sowas von auf dem Schlauch, oder es gibt einen Trick, mit dem man das Problem beheben kann (erneutes Aufrufen der Display-Routine hat beispielsweise nicht helfen können...).

Bin für jede Hilfe dankbar ;)

Patti

[Bummi]

nicht daß ich es ganz verstehen würde aber mit

Delphi-Quellcode:

               pBMP[x].rgbRed := 255 - y;
               pBMP[x].rgbGreen := 0;
               pBMP[x].rgbBlue := 0;
               pBMP[x].rgbReserved := 255-y;

sollte das rauskommen was Du erwartest....

[patti]

Erstmal Danke für deine Antwort und deine Bemühungen ;-) Tatsächlich funktioniert das in diesem Beispiel perfekt, also wenn ich einen Farbverlauf habe (verstehe aber ehrlich gesagt nicht, warum es dann funktioniert, denn nach meinem Verständnis müsste die rote Fläche mit meinem ursprünglichen Code trotzdem ausfaden, da der Alpha-Wert ja irgendwann 0 wird :gruebel: ).
Das mit dem roten Farbverlauf war jedoch nur ein kleiner Test, denn eigentlich will ich später alphatransparente Grafiken darstellen können. Hab jetzt deshalb mal meine Zeichen-Routine zum Testen angepasst:

Delphi-Quellcode:

     for y := 0 to 255 do
     begin
          pBMP := bgBMP.ScanLine[y];
          //
          for x := 0 to 255 do
          begin
               pBMP[x].rgbRed      := 0;
               pBMP[x].rgbGreen    := 255-y;
               pBMP[x].rgbBlue     := 0;
               //
               if (y > 100) and (y < 200) then pBMP[x].rgbReserved := 0
               else pBMP[x].rgbReserved := 255-y;
          end;
     end;

Dann ergibt sich (logischerweise) wieder das ursprüngliche Problem (siehe Bild im Anhang). An was kann denn das liegen? Kann es sein, dass ich die Arbeitsweise von UpdateLayeredWindow falsch verstehe?

[Bummi]

Ich habe ein anderes Vorgehen als Du und bin daher bisher nicht auf dieses Problem gestossen.
Ich bastle gerade eine Komponentensuite für Transparente Anwendungen.
Microdemo unter:
www.bummisoft.de/download/Transtest.zip.

Wenn ich bei meinen GDI+-Malereien schaue was da gemalt wird sieht es so aus als ob z.B. Rot
bei scharzem Hintergurnd, den ich default verwende mit 128 bei Transparenz 128 gemalt wird:

im unteren Beispiel wird Caption auf 128 gesetzt.


wenn ich vorher mit weiß füllen würde bekäme ich 255 für Rot

Delphi-Quellcode:

var
  b:TGPSolidBrush;
  g:TGPGraphics;
  sc:PScanline;
begin
  image1.Canvas.Brush.Color := clBlack;
  image1.Canvas.FillRect(rect(0,0,200,200));
  g := GetGraphics(image1.Canvas);
  b := GetSolidBrush(clRed,128);
  g.FillEllipse(b,10,10,100,100);
  g.Free;
  b.Free;
  sc := Image1.Picture.Bitmap.ScanLine[50];
  Caption := IntToStr (sc[50].R);

end;

[patti]

Ich hab's!

Hab mehr durch Zufall herausgefunden, dass man die RGB-Werte jeweils mit dem Alpha-Wert/255 multiplizieren muss, damit das Ergebnis stimmt:

Delphi-Quellcode:

procedure TfrmMain.PaintBMP;
var pBMP : PRGBLine;
var x,y  : integer;
begin
     //--
     for y := 0 to 255 do
     begin
          pBMP := bgBMP.ScanLine[y];
          //
          for x := 0 to 255 do
          begin
               pBMP[x].rgbReserved := 255-y;
               //
               pBMP[x].rgbRed      := Byte(Round((pBMP[x].rgbRed)*(pBMP[x].rgbReserved / 255)));
               pBMP[x].rgbGreen    := Byte(Round((pBMP[x].rgbGreen)*(pBMP[x].rgbReserved / 255)));
               pBMP[x].rgbBlue     := Byte(Round((pBMP[x].rgbBlue)*(pBMP[x].rgbReserved / 255)));
          end;
     end;
     //
     Display;
end;

Das Ergebnis schaut dann so aus wie im Anhang.

Danke nochmal an Bummi für die Mühe ;-)

Patti