OnChange bei jedem Itemindex auslösen

[Ti-Delphin]

Hallo,

das onChange Ereignis einer Combobox kann von hause aus nur manuell ausgelöst werden (s.u. CodeGear Help)

Zitat:

Anmerkung: OnChange tritt nur als Reaktion auf Benutzeraktionen ein.
Wenn die Eigenschaft Text programmgesteuert geändert wird, wird das Ereignis OnChange nicht ausgelöst.

Gibt es eine Möglichkeit wie ich bei einem Programmgesteuerten ItemIndex change automatisch, das OnChange-Ereignis auslösen kann??

Hintergrund: Lese aus einer Text Datei die Itemindex-Werte aus und weise sie den entsprechenden Comboboxen zu.
In Abhängigkeit der Itemindex werden aber andere Comboboxen Ein/Ausgeblendet (durch onChange Prozeduren)....

Danke und Gruß

[mkinzler]

Rufe die Methode direkt auf.

[DeddyH]

Wenn das nicht an 1000 Stellen im Quelltext geschieht, kannst Du doch einfach die OnChange-Methode aufrufen.

Delphi-Quellcode:

ComboBox.ItemIndex := 42;
ComboBoxChange(ComboBox);

[Ti-Delphin]

Hab's auch schon direkt aufgerufen...dachte nur es gäbe eine elegantere Methode dies zu tun :-)

Trotzdem danke für die schnellen Antworten ..

[mleyen]

Klar gibts die:

Delphi-Quellcode:

type
  TCBox2 = class(TComboBox)
  protected
    procedure SetItemIndex(const Value: Integer); override;
  published
    property ItemIndex: Integer read GetItemIndex write SetItemIndex;
  end;

{ TCBox2 }

procedure TCBox2.SetItemIndex(const Value: Integer);
begin
  inherited;
  if Assigned(Self.OnChange) then
    Self.OnChange(Self);
end;

[himitsu]

Zitat:

Zitat von Ti-Delphin (Beitrag 1042988)

Hab's auch schon direkt aufgerufen...dachte nur es gäbe eine elegantere Methode dies zu tun :-)

Delphi-Quellcode:

procedure SetComboBoxItemIndex(ComboBox: TComboBox; NewIndex: Integer);
begin
  ComboBox.ItemIndex := 42;
  if Assigned(ComboBox.OnChange) then
    ComboBox.OnChange(ComboBox); 
end;

Ab D2006 könnte man das auch als Class-Helper für TComboBox/TCustomComboBox bereitstellen.

[DeddyH]

Noch bequemer:

Delphi-Quellcode:

type
  TComboBox = class(StdCtrls.TComboBox)
  protected
    procedure SetItemIndex(const Value: Integer); override;
  published
    property ItemIndex: Integer read GetItemIndex write SetItemIndex;
  end;

  //Hier dann erst die Deklaration des Formulars mit den ComboBoxen

{ TComboBox }

procedure TComboBox.SetItemIndex(const Value: Integer);
begin
  inherited;
  if Assigned(Self.OnChange) then
    Self.OnChange(Self);
end;

Somit entfällt ein Typecast, und das klappt auch unter älteren Delphi-Versionen.

[Ti-Delphin]

:thumb:..genial..sowas meinte ich... so kann man also die Eigenschaften der Objekte zentral erweitern..

[himitsu]

Zitat:

Zitat von Ti-Delphin (Beitrag 1043015)

:thumb:..genial..sowas meinte ich... so kann man also die Eigenschaften der Objekte zentral erweitern..

Es ist mehr ein inoffizieller Hack.

Offiziell sind Class Helper für gewisse Änderungen vorgesehn.


Die VCL nimmt die Deklarationen, welche in der Form-Deklaration anliegen, also wenn man da vorher was ändert/ersetzt/überschreibt, dann gilt es auch da und es werden diese Komponenten mit der überschriebenen Klasse erstellt.

Auch kann man sowas in andere Units auslagern und muß diese Units nur als Letztes in der Usesklausel aufnehmen.