Code vereinfachen (obj as Tbutton)

[R2009]

Hi,
ich möchte auf all diese Objekte zugreifen ohne die vielen ifs:
Alle haben das Property caption gemeinsam.
Hat jemand eine Idee wie man das vereinfachen kann?
Am liebsten wäre mir obj.caption:='tralala'.

Delphi-Quellcode:

    (sender as tform).GetTabOrderList(List);
    //detect all controls.
    For n:=0 to list.Count-1 do
      begin
        obj:=list.Items[n];
        If (obj is Tbutton) then
           begin
            (obj as Tbutton).caption:='huhu';
           end;
        If (obj is Tradiobutton) then
           begin
             (obj as Tradiobutton).caption:='huhu';
           end;
        If (obj is Tcheckbox) then
           begin
             (obj as Tcheckbox).caption:='huhu';
           end;
       end;

Grüsse
Rainer

[himitsu]

Dann schau einfach in welchem gemeinsamen Vorfahr das Property Caption eingeführt/veröffentlicht wurde und nutze dann diesen.

[DeddyH]

Versuch mal

Delphi-Quellcode:

if obj is TControl then
  TControl(obj).Caption := 'Blabla';

Ohne Gewähr

[Amateurprofi]

versehentlich abgeschickt.....

[R2009]

Hi himits, hi DeddyH,

glaubt ihr wirklich ich hätte diesen Thread geöffnet wenn ich das nicht schon ausprobiert hätte?

Hat jemand eine sinnvolle andere Idee?

Grüsse
Rainer

[DeddyH]

Und wieso sagst Du uns das nicht? Dann schau mal hier.

[himitsu]

Code:

TButton      > TCustomButton   > TButtonControl > TWinControl > TControl > ...
TRadioButton                   > TButtonControl > TWinControl > TControl > ...
TCheckBox    > TCustomCheckBox > TButtonControl > TWinControl > TControl > ...

Caption wurde in TControl eingeführt, aber noch nicht veröffentlich (protected).
Veröffentlicht (public/published) wurde es erst in den Endtypen.

Da alle Typen den selben Vorfahren haben, wo diese Option eingeführt wurde, kann man nun irgendeinen Typen nehmen, wo es veröffentlicht wurde, da dieses Property, bzw. sein Speicherplatz/Zugriff sich nicht verändert

Delphi-Quellcode:

If (obj is TButton) or (obj is TRadioButton) or (obj is TCheckBox) then
  TButton(obj).Caption := 'huhu';

Der nächste gemeinsame Vorfahr wär TCustomButton:

Delphi-Quellcode:

If obj is TCustomButton then
  TButton(obj).Caption := 'huhu';

Folgendes würde jetzt für alle Typen, welche von TControl abgeleitet wurden die Caption ändern.

Delphi-Quellcode:

If obj is TControl then
  TButton(obj).Caption := 'huhu';

Hab hier intern einfach TButton genommen, da es TCustomButton logisch am Nächsten steht und schön kurz ist.

Delphi-Quellcode:

Type TCustomButtonCaptionAccesss = Class(TCustomButton)
  Public // oder Protected, wenn diese Deklaration in der gleichen Unit deklariert
    Property Caption;                    // wird, wo man auch drauf zugreifen will
  End;

If obj is TCustomButton then
  TCustomButtonCaptionAccesss(obj).Caption := 'huhu';

[uligerhardt]

Zitat:

Zitat von DeddyH

Versuch mal

Delphi-Quellcode:

if obj is TControl then
  TControl(obj).Caption := 'Blabla';

Ohne Gewähr

Fast. So geht's:

Delphi-Quellcode:

type
  THack_Control = class(TControl);

procedure Test(obj: TObject);
begin
  if obj is TControl then
    THack_Control(obj).Caption := 'Blabla';
end;

[uligerhardt]

Zitat:

Zitat von R2009

glaubt ihr wirklich ich hätte diesen Thread geöffnet wenn ich das nicht schon ausprobiert hätte?

Woher sollen wir das wissen? :gruebel: