PopupMenu NUR bei rechtsklick auf TabSheet.Titel ausklappen

[Nalincah]

Ist es möglich bei einer PageControl und einem Tabsheet das PopupMenu so einzustellen das es nur beim Klick auf den Titel des aktuellen Tabsheets aufklappt? (Mit Optionen wie "Speichern" oder "Schließen" Es darf nicht angezeigt werden wenn man auf dem eigentlichen TabSheet ein rechtsklickt macht (z.B. wie in dem HTML-Editor Phase 5)

[toms]

Hi,

Das dürfte wie folgt gehen:

Delphi-Quellcode:

procedure TForm1.PageControl1MouseUp(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
const
  TCM_GETITEMRECT = $130A;
var
  i: Integer;
  r: TRect;
  p: TPoint;
begin
  with (Sender as TPageControl) do
  begin
    for i := 0 to PageCount - 1 do
    begin
      Perform(TCM_GETITEMRECT, i, LPARAM(@r));
      if PtInRect(r, Point(X, Y)) then
      begin
        if i = ActivePage.PageIndex then
        begin
          p := ClientToScreen(Point(X, Y));
          PopupMenu1.Popup(p.X, p.Y);
          Exit;
        end;
      end;
    end;
  end;
end;

(PS : Vielleicht geht's auch einfacher??)

[Nalincah]

Danke. Das Problem ist nur:

Ich benutze das bei dynamisch erstellten Kompos und da hab ich mir das so gedacht:

Delphi-Quellcode:

Sheet[anzSQL].OnMouseUp := ShowPopupMenu(PageControlSQL,mbRight,[],Mouse.CursorPos.X,Mouse.CursorPos.Y);

und dazu die Proc:

Delphi-Quellcode:

procedure TFrameDB.ShowPopupMenu(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
const
  TCM_GETITEMRECT = $130A;
var
  i: Integer;
  r: TRect;
  p: TPoint;
begin
  with (Sender as TPageControl) do
  begin
    for i := 0 to PageCount - 1 do
    begin
      Perform(TCM_GETITEMRECT, i, LPARAM(@r));
      if PtInRect(r, Point(X, Y)) then
      begin
        if i = ActivePage.PageIndex then
        begin
          p := ClientToScreen(Point(X, Y));
          PopupSQL.Popup(p.X, p.Y);
          Exit;
        end; // if i = ActivePage.PageIndex then
      end; // if PtInRect(r, Point(X, Y)) then
    end; // for i := 0 to PageCount - 1 do
  end; // with (Sender as TPageControl) do
end;

Dann sagt der mir aber:

Code:

[Fehler] uFrame.pas(335): Inkompatible Typen: 'TMouseEvent' und 'procedure, untyped pointer or untyped parameter'

Das Versteh ich nicht, da ja

Delphi-Quellcode:

Mouse.CursorPos.X
Mouse.CursorPos.Y

vom Typ Integer ist und die Proc verlangt an der Stelle Integer

[Christian Seehase]

Moin General,

lass mal die Parameter weg, also nur so:

Delphi-Quellcode:

Sheet[anzSQL].OnMouseUp := ShowPopupMenu;

Die Werte für die Parameter werden ja beim Eintreten des Events automatisch gefüllt.

[toms]

Delphi-Quellcode:

Sheet[anzSQL].OnMouseUp := ShowPopupMenu(PageControlSQL,mbRight,[],Mouse.CursorPos.X,Mouse.CursorPos.Y);

Nein, du musst das OnPageControlMouseUp dem PageControl zuweisen.
und zwar so:

Delphi-Quellcode:

private
 procedure MyPageControlMouseUp(Sender: TObject; Button: TMouseButton;
   Shift: TShiftState; X, Y: Integer);

{...}

procedure TForm1.MyPageControlMouseUp(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
begin
  // Code...
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  MYPageControl : TPageControl;
begin
  MYPageControl := TPageControl.Create(Self);
  MYPageControl.OnMouseUp := PageControl1MouseUp;
  //...
end;

[Nalincah]

Ahhh..Dann ist das kein Problem. Das PageControl wird nicht dynamisch erzeugt