minni while schleife auf geschwindigkeit optimieren

[Cyberstorm]

hi. ich will aus einer html seite alle tags löschen --> alle sachen wie <Table blablabla> usw. löschen.

meine schleife funktioniert soweit aber ist mir zu lahm bei längeren seiten.
wie kann ich den code auf geschwindigkeit optimieren?

Delphi-Quellcode:

var
  first: Integer;
  htmlString: String;
begin
  //htmlStringzuweisen
  first:=1;
  while first > 0 do
    begin
      first:=Pos('<', htmlString);
      Delete(htmlString, first, pos('>', htmlString) - first + 1);
    end;
end;

[Namenloser]

Delphi-Quellcode:

function StripHTMLTags(const HTML: string): string;
var
  TagDepth: integer;
  i: integer;
  ResultIndex: integer;
begin
  TagDepth := 0;
  ResultIndex := 1;
  SetLength(result, length(HTML));
  for i := 1 to length(HTML) do
  begin
    case HTML[i] of
    '<': inc(TagDepth);
    '>': dec(TagDepth); // ggf. hier prüfen, ob der Tag überhaupt schon geöffnet wurde (TagDepth > 0)
    else 
      if TagDepth > 0 then
      begin
        result[ResultIndex] := HTML[i];
        inc(ResultIndex);
      end;
    end;
  end;
  SetLength(result, ResultIndex);
end;

Im Antwortfenster aus dem Kopf getippt - ich kann daher nicht garantieren, dass es funktioniert. Der Ansatz ist einfach, einen String mit der gleichen Länge wie dem ursprungsstring zu erstellen (länger kann das Ergebnis ja nicht sein). Anschließend wird jedes Zeichen in einer Schleife in den Ergebnisstring übertragen, wenn nicht ein oder mehrere Tags geöffnet sind. Am Ende wird der String noch zu recht gestutzt.

Das ist aber nur eine einfache Methode, die man besser nicht auf allzu invaliden HTML-Code loslassen sollte. Wenn man auf Nummer sicher gehen will/muss, sollte man besser einen Parser verwenden.

[Cyberstorm]

vielen dank.

der code ist um einiges schneller!

[himitsu]

nur mal ein kleiner Hinweis zum ursprünglichem Code:

bei z.B. diesem String "abc>def<xyz>" wär dein Code schön in einer Endlosschleife gelandet ;)
statt dem Pos im Delete hättest du eher 'nen PosEx verwenden sollen. :stupid:

[Cyberstorm]

Zitat:

Zitat von himitsu

nur mal ein kleiner Hinweis zum ursprünglichem Code:

bei z.B. diesem String "abc>def<xyz>" wär dein Code schön in einer Endlosschleife gelandet ;)
statt dem Pos im Delete hättest du eher 'nen PosEx verwenden sollen. :stupid:

wohl wahr, danke.


in dem code wahr noch ein kleiner fehler.
"SetLength(result, ResultIndex);" <-- da mussnoch 1 vom ResultIndex abgezogen werden, da ja nach dem letzten zeichen nochmal inkrementiert wird.

hier nochmal korrigiert:

Delphi-Quellcode:

function StripHTMLTags(const HTML: String): String;
var
  TagDepth, i, ResultIndex: Integer;
begin
  TagDepth:=0;
  ResultIndex:=1;
  SetLength(result, length(HTML));
  for i:=1 to length(HTML) do
    begin
        case HTML[i] of
          '<': inc(TagDepth);
          '>': if TagDepth > 0 then dec(TagDepth);
          else if TagDepth = 0 then
            begin
              result[ResultIndex]:=HTML[i];
              inc(ResultIndex);
            end;
        end;
    end;
  SetLength(result, ResultIndex - 1);
end;

[Namenloser]

Ich merke gerade, dass man sich das ganze Inkrementieren und Dekrementieren eigentlich sparen kann. Eine Boolean-Variable würde es auch tun, denn in einem Tag kann ja ein zweiter nicht anfangen (es sei denn der Code ist echt vermurkst Frontpage). Stattdessen sollte man lieber auf sowas achten:

Code:

<a b='[color=#ff0000]>[/color]'>

Für die entsprechende Behandlung dieses Problems wird dann aber doch wieder ein Zähler nötig sein (oder ein Stack, auf dem man die Zeichen ablegt?).

[mr_emre_d]

mini
-.-