Frames über deren Namen dynamisch aufrufen

[ensacom]

Hallo, ich benutze folgenden Code um Frames zur Laufzeit in meine Form zu laden

Delphi-Quellcode:

private
    FActiveFrame:TFrame; //zum merken des derzeit aktiven Frames



uses  
  UnitFrameShowInteressenten, UnitFrameAddInteressent, UnitFrameObjekte;




procedure TForm1.Button1Click(Sender: TObject);
begin
  if (not assigned(FActiveFrame)) or not (FActiveFrame is TFrameShowInteressenten) then
  begin
    freeandnil(FActiveFrame);
    FActiveFrame:=TFrameShowInteressenten.Create(self);
    FActiveFrame.Parent:=TabSheet1;
    TabSheet1.Caption := 'Interessenten';
  end;
end;




procedure TForm1.Button2Click(Sender: TObject);
begin
  if (not assigned(FActiveFrame)) or not (FActiveFrame is TFrameObjekte) then
  begin
    freeandnil(FActiveFrame);
    FActiveFrame:=TFrameObjekte.Create(self);
    FActiveFrame.Parent:=TabSheet1;
    TabSheet1.Caption := 'Objekte';
  end;
end;

Kann mir nun einer sagen wie ich das ganze so aufrufen kann, dass ich nur den Namen des Frames angeben brauche?

Danke

[mkinzler]

Da fällt mir nur .FindComponent() in Verbindung mit Typvergleich ein

[ensacom]

Hm und wie macht man das?
Damit kenne ich mich ja mal gar nicht aus.

Kannst Du mir da evenetuell weiterhelfen?

[Uwe Raabe]

Zitat:

Zitat von mkinzler

Da fällt mir nur .FindComponent() in Verbindung mit Typvergleich ein

Da die Frames zur Laufzeit jedesmal neu erzeugt werden, wird FindComponent da gar nichts nützen.

Vielleicht hilft ja folgende Methode:

Delphi-Quellcode:

procedure MakeActiveFrame(AFrameClass: TCustomFrameClass; const ACaption: string);
begin
  if (not assigned(FActiveFrame)) or not (FActiveFrame is AFrameClass) then
  begin
    freeandnil(FActiveFrame);
    FActiveFrame:=AFrameClass.Create(self);
    FActiveFrame.Parent:=TabSheet1;
    TabSheet1.Caption := ACaption;
  end;
end;

Aufruf dann im jeweiligen ButtonClick etwa so:

Delphi-Quellcode:

MakeActiveFrame(TFrameShowInteressenten, 'Interessenten');

bzw.

Delphi-Quellcode:

MakeActiveFrame(TFrameObjekte, 'Objekte');

[SirThornberry]

Da du die Frames dynamisch erzeugst und auch danymisch die Namen vergibst wäre es doch sinnvoller beim erzeugten der Frames diese in eine Liste zu packen.

@Uwe: FindComponent findet auch dynamisch erzeugte Komponenten sofern der Owner beim erzeugen angegeben wurde und dann die Methode FindComponent des Owners aufgerufen wird.

[mkinzler]

Wenn die Form Owner deines Frames ist kannst du diese über den namen seiner Kinder abfragen

Delphi-Quellcode:

if <Form>.FindComponent('<Komponentename'>).ClassName is TFrame then TFrame(<Form>.FindComponent('<Komponentename'>)).<Eigenschaft> ...

[Uwe Raabe]

Zitat:

@Uwe: FindComponent findet auch dynamisch erzeugte Komponenten sofern der Owner beim erzeugen angegeben wurde und dann die Methode FindComponent des Owners aufgerufen wird.

Das ist mir schon klar. Es ist aber immer nur ein einziger Frame instantiiert und den finde ich direkt im Feld FActiveFrame. Sobald er einen neuen Frame aktiviert, wird der alte freigegeben. Und FindComponent findet nun mal keine Objekte, die nicht existieren :wink:

[ensacom]

Also ich erzeuge die Frames nicht dynamisch.
Die sind fix und fertig und sollen dann über eine ComboBox, die die Namen der Frames beinhaltet, geladen werden, wobei
der parent ein Panel auf der Hauptform ist.

Mit der oben gezeigten Procedure komme ich auch nicht weiter.

Delphi-Quellcode:

procedure TfNewInteressent.Button1Click(Sender: TObject);
begin
  if (fNewInteressent.FindComponent('frGewerbeMaskeAngebot').ClassName is TFrame) then
  TFrame(fNewInteressent.FindComponent('frGewerbeMaskeAngebot')).Color := clred;
end;

bekomme ich nur die Meldung "[Fehler] uNewInteressent.pas(494): Operator ist auf diesen Operandentyp nicht anwendbar"

[ensacom]

Also was ich will ist einfach nur, dass ich in den unten fett geschriebenen Stellen den Namen der Frames als String übergeben kann und nicht wie jetzt als TFrame

Delphi-Quellcode:

if (not assigned(FActiveFrame)) or not (FActiveFrame is [b]TfrGewerbeMaskeAngebot[/b]) then
begin
  freeandnil(FActiveFrame);
  FActiveFrame:=[b]TfrGewerbeMaskeAngebot[/b].Create(self);
  FActiveFrame.Parent := pnlFrameParent;
end;

[Hawkeye219]

Hallo,

die Umwandlung eines Strings in eine Klassenreferenz kann mit Hilfe der Funktion GetClass durchgeführt werden. Die Frame-Klassen müssen dazu einmalig mittels RegisterClass registriert werden.

Delphi-Quellcode:

type
  TFrameClass = class of TFrame;
  
function FindFrameClass (const aClassName: string; var aFrameClass: TFrameClass): Boolean;
var
  ClassRef : TPersistentClass;
begin
  ClassRef := GetClass(aClassName);
  Result := Assigned(ClassRef) and ClassRef.InheritsFrom(TFrame);
  if Result then
    aFrameClass := TFrameClass(ClassRef);
end;
  
// Beispiel für den Einsatz der Funktion:  
  
var
  FrameClass : TFrameClass;
begin
  RegisterClass (TFrameShowInteressenten);
  RegisterClass (TFrameObjekte);
  RegisterClass (TfrGewerbeMaskeAngebot);

  if FindFrameClass('TfrGewerbeMaskeAngebot', FrameClass) then
    if (not Assigned(FActiveFrame)) or not (FActiveFrame is FrameClass) then
      begin
        FreeAndNil (FActiveFrame);
        FActiveFrame:= FrameClass.Create(Self);
        FActiveFrame.Parent := pnlFrameParent;
      end;
end;

So oder ähnlich sollte das funktionieren.

Gruß Hawkeye