Problem mit TFileStream und Write Read

[NickelM]

Hallo Leute,
Bei meinem Spiel schreibe ich u.a. Strings in eine TFileStream-Datei.
Alles klappt aber immer öfters kommen Problemme mit Read von Strings auf.
Wenn ich PChar nehme klappt des auch net. Das dumme ist bei manchen Strings klappt es bei anderen wiederrum nicht.
Ich flip hier noch aus, weil dass net klappt und ich keine ahnung hab warum :wall: :wall: :wall: :wall: :wall:
Benutze Delphi 5.
hier der Code und ein Paar typen:

Delphi-Quellcode:

//Write-Code
Write(Charakter,SizeOf(TCharakter));  //1
Write(Schwierigkeitsgrad,SizeOf(TSchwierigkeitsgrad));
Charaktername := Charaktername_Feld;
Write(Charaktername,SizeOf(Charaktername));

AktuQuestname := AktuellesQuest.Questname;
Write(AktuQuestname,SizeOf(AktuQuestname));

//Read-Code
Read(Charakter,SizeOf(TCharakter));   //1
Read(Schwierigkeitsgrad,SizeOf(TSchwierigkeitsgrad));
Read(Charaktername,SizeOf(Charaktername));
Charaktername_Feld := Charaktername;
GetCharakterInfo;
Read(AktuQuestname,SizeOf(AktuQuestname));
AktuellesQuest.Questname := AktuQuestname;

Hier die Typen:

Delphi-Quellcode:

TSchwierigkeitsgrad = (sLeicht,sMittel,sSchwer);

  TCharakter = record
  //Name : String;
  Geschicklichkeit : Longword;
  Intelligenz : Longword;
  Handwerk : Longword;
  Kombinationsgabe : Longword;
  Fuhrung : Longword;
  SkillpunkteLeft : Longword;
  ErspielteSkillpunkte : Longword;
  end;

  TAktuellesQuest = record
  Questname : String;
  Questtext :  TStringList;
  Waren : TCollection;
  Erfahrungspunkte : Longword;
  end;

Die anderen sind Lokale Variablen, die bei laden und speichern sind.
Das dumme ist bei Questname hatte es geklappt die ganze Zeit jetzt hab ich noch den String von TCharakter gefüllt gehabt und gespeichert und schon konnte ich es nicht mehr laden den gesammten Record. Bei den anderen hatte ich Variablen gehabt, wass ich da auch jetzt gemachte hatte und es ging nicht. Bei den anderen gings.
Warum???????????? :wall: :wall: :wall: :wall: :wall: :wall:

[Luckie]

Du speicherst ja auch nicht den String, sondern nur einen Zeiger auf einen Speicherbereich, wo dein String steht. Entweder du speiherst noch die Länge des Strings mit ab oder du beschränkst dich auf ShortStrings.

[NickelM]

Wenn ich also die Länge speicher und dann den String lese gehts oder wie????

Delphi-Quellcode:

/Wenn ich beim laden sage:
SetLength(Charaktername_Feld,Große);
Read(Charaktername_Feld,SizeOf(Charaktername_Feld));

Würde das dan so gehen?? Natürlich die Große erst lesen ist klar :zwinker:

[Christian Seehase]

Moin Nickel,

dazu müsstest Du Dir mal den Aufbau der jeweiligen Datentypen zu Gemüte führen:

Name ist ein Pointer (4 Byte) auf den eigentlichen String (wo auch immer der stehen mag).

Wenn Du jetzt also schreibst:

Delphi-Quellcode:

fs.Write(Name,Length(Name));

wird nicht der String, sondern der Pointer auf den String, und alle Bytes dahinter in den Stream geschrieben bis Length(Name) erreicht ist.
Bei Strings und Streams geht es so:

Delphi-Quellcode:

var
  sBuf  : string;
  dwLen : DWORD;
  fs    : TFileStream;

begin
  // Schreiben
  sBuf  := 'Irgendwas';
  dwLen := Length(sBuf);
  fs := TFileStream.Create(....,....);
  try
    // Erst die Länge
    fs.Write(dwLen,SizeOf(dwLen)); // Besser SizeOf als direkt 4, falls man den Typ ändert
    // Dann den eigentlichen Inhalt
    fs.Write(sBuf[1],dwLen);
  finally
    fs.Free;
  end;
  // Lesen
  fs := TFileStream.Create(....,....);
  try
    // Erst die Länge
    fs.Read(dwLen,SizeOf(dwLen));
    // Jetzt muss erst mal der Lesebuffer initialisiert werden
    sBuf := StringOfChar(#00,dwLen); // oder SetLength(sBuf,dwLen), aber dann ist der Speicher nicht initalisiert
    fs.Read(sBuf[1],dwLen);
  finally
    fs.Free;
  end;
end;

Solche Bestandteile wie QuestText (TStringList) oder Waren (TCollection) ist es ähnlich.
Auch das sind nur Pointer. Was Du das speicherst hat also nichts mit den Daten zu tun, die Du eigentlich Speichern willst.
Bei einer StringList ist das schon vorgesehen (Methode SaveToFile bzw. LoadFromFile), bei der Collection musst Du Dir das wohl selber zusammenbauen.

[NickelM]

Oha.....
Das ist ja kompliziert aber danke Christian.
Und was ist mit ShortStrings?? Ist das da anders???

[freak4fun]

Delphi-Quellcode:

fs.Write(sBuf[1],dwLen);

Wieso steht an dieser Stelle "sBuf[1]"? Das verstehe ich nicht.

[Christian Seehase]

Moin NickelM,

Zitat:

Zitat von NickelM

Und was ist mit ShortStrings?? Ist das da anders???

Ja, diese sind immer 256 Byte gross (1 Byte Länge, Index 0, der Rest enthält den eigentlichen Wert).
Einen ShortString kann man direkt Speichern, auch einen Record der einen ShortString enthält, wobei der nicht genutzte Bereich des Strings (255-Length(ShortString)) mit den Daten gefüllt ist, die gerade zufällig im Speicher stehen. (wenn man Pech hat ein Anmeldename mit Passwort im Klartext ;-)). Man sollte bei Speichern von ShortStrings, vor allem in Records, also etwas aufpassen.

Delphi-Quellcode:

// ShortString
fs.Write(s,Length(s)+1); // +1, da als erstes das Längenbyte steht, dann erst der String
fs.Write(s,SizeOf(s));   // Hier werden alle 256 Byte gespeichert
// Record mit ShortString
fs.Write(r,SizeOf(r)); // hier ist das Längenbyte bereits enthalten

@Christian:
durch das [1] wird die erste Stelle des eigentlichen Strings angegeben, damit dann ab dieser Stelle in den Stream geschrieben wird.
Man könnte auch [5] nehmen, wenn einen erst der String ab der 5. Stelle interessiert.

[freak4fun]

Zitat:

Zitat von Christian Seehase

durch das [1] wird die erste Stelle des eigentlichen Strings angegeben, damit dann ab dieser Stelle in den Stream geschrieben wird.
Man könnte auch [5] nehmen, wenn einen erst der String ab der 5. Stelle interessiert.

Wenn ich da statt Buf[1] Buf hinschreibe und das ist ein String, welche Adresse steht dann da? Ist Buf dann nicht ein Zeiger auf den ersten Buchstaben? :gruebel:

[SirThornberry]

Eventuell ist Buf dann ein Zeiger auf den ersten Buchstaben. Aber du willst ja nicht den Zeiger und das was dahinter im speicher steht speichern sondern es soll das gespeichert werden worauf der Zeiger zeigt bzw. das erste Zeichen und das was dahinter im Speicher folgt (die folgenden Zeichen)

[Christian Seehase]

Moin Christian,

nein, wenn Du den Index weglässt, wird der Pointer geschrieben, den die StringVariable enthält, sowie eben alles, was zufällig dahinter im Speicher steht.

Beispiel

Delphi-Quellcode:

// Länge meint hier den Wert, den SizeOf zurückliefern würde
var             // Adresse: Länge: Inhalt
  s : string;   // 4712     4      Unbekannt
  w : word;     // 4716     2      Unbekannt
                // 4718     2      Unbekannt (nicht genutzt, weil, i.d.R. Alignment 4)
  i : integer;  // 4720     4      Unbekannt


begin
  s := 'TESTWERT';  // Adresse: 4712 / Länge: 4 Inhalt: $401F0000 (8000 dezimal)
                    // Adresse: 7992 / Länge: 4 Inhalt: $01000000 (Referenzzähler, 1 dezimal)
                    // Adresse: 7996 / Länge: 4 Inhalt: $08000000 (Länge des Strings, 8 dezimal)
                    // damit ein String in C-Funktionen direkt genutzt werden kann, legt
                    // der Compiler automatisch eine binäre 0 als Endekennung dahinter
                    // Adresse: 8000 / Länge: 4 Inhalt: TESTWERT#00
  w := 50;          // Adresse: 4716 / Länge: 2 Inhalt: $3200 (50 dezimal)
                    // Adresse: 4718 / Länge: 2 Inhalt: unbekannt
  i := 1000;        // Adresse: 4720 / Länge: 4 Inhalt: $E8030000 (1000 dezimal)

// Wenn man jetzt
fs.Write(s,Length(s));
// schreiben würde, würde in der Datei folgendes stehen (Hexadezimal)
// Annahme: Die Variablen würden so im Speicher stehen, wie oben
//          angegeben, was aber nicht der Fall sein muss.
//          Diese Annahme dient hier nur der Verdeutlichung.
//
// 401F00003200????
// Es werden also die Adresse des Strings, sowie der Wert von w in die Datei geschrieben.
// Der Wert der verbleibenden zwei Bytes ist unbekannt

// Bei
fs.Write(i,SizeOf(i));
// wird E8030000 in der Datei stehen, bei
fs.Write(w,SizeOf(w));
// ist es dann 3200.
end;